1b7370145ed684b8e85847de24d33eed991230ae
[darcs-mirror-isa-launchbury.git] / Launchbury / FTreeCardinality.thy
1 theory FTreeCardinality
2 imports FTreeAnalysisSpec CardinalityAnalysis CallFutureCardinality
3 begin
4
5 hide_const Multiset.single
6
7 context FTreeAnalysis
8 begin
9
10 fun unstack :: "stack \<Rightarrow> exp \<Rightarrow> exp" where
11   "unstack [] e = e"
12 | "unstack (Upd x # S) e = unstack S e"
13 | "unstack (Arg x # S) e = unstack S (App e x)"
14 | "unstack (Dummy x # S) e = unstack S e"
15
16 fun Fstack :: "stack \<Rightarrow> var ftree"
17   where "Fstack [] = \<bottom>"
18   | "Fstack (Upd x # S) = Fstack S"
19   | "Fstack (Arg x # S) = many_calls x \<otimes>\<otimes> Fstack S"
20   | "Fstack (Dummy x # S) = Fstack S"
21
22 lemma carrier_Fstack[simp]: "carrier (Fstack S) = ap S"
23   by (induction S rule: Fstack.induct) (auto simp add: empty_is_bottom[symmetric])
24
25 fun prognosis :: "AEnv \<Rightarrow> Arity \<Rightarrow> conf \<Rightarrow> var \<Rightarrow> two"
26    where "prognosis ae a (\<Gamma>, e, S) = pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)))"
27 end
28
29
30 lemma pathsCard_paths_nxt:  "pathsCard (paths (nxt f x)) \<sqsubseteq> record_call x\<cdot>(pathsCard (paths f))"
31   apply transfer
32   apply (rule pathsCard_below)
33   apply auto
34   apply (erule below_trans[OF _ monofun_cfun_arg[OF paths_Card_above], rotated]) back
35   apply (auto intro: fun_belowI simp add: record_call_simp two_pred_two_add_once)
36   done
37
38 lemma pathsCards_none: "pathsCard (paths t) x = none \<Longrightarrow> x \<notin> carrier t"
39   by transfer (auto dest: pathCards_noneD)
40
41 lemma const_on_edom_disj: "const_on f S empty \<longleftrightarrow> edom f \<inter> S = {}"
42   by (auto simp add: empty_is_bottom edom_def)
43
44 context FTreeAnalysisCarrier
45 begin
46   lemma carrier_FBinds: "carrier ((FBinds \<Gamma>\<cdot>ae) x) \<subseteq> fv \<Gamma>"
47   apply (simp add: Fexp.AnalBinds_lookup)
48   apply (auto split: option.split simp add: empty_is_bottom[symmetric] )
49   apply (case_tac "ae x")
50   apply (auto simp add: empty_is_bottom[symmetric] carrier_Fexp dest!: set_mp[OF Aexp_edom])
51   by (metis (poly_guards_query) contra_subsetD domA_from_set map_of_fv_subset map_of_is_SomeD option.sel)
52 end
53
54
55
56
57 context FTreeAnalysisCorrect
58 begin
59
60   sublocale CardinalityPrognosisCorrect prognosis
61   proof
62     fix \<Gamma> :: heap and ae ae' :: AEnv and u e S
63     assume "ae f|` domA \<Gamma> = ae' f|` domA \<Gamma>"
64     from Fexp.AnalBinds_cong[OF this]
65     show "prognosis ae u (\<Gamma>, e, S) = prognosis ae' u (\<Gamma>, e, S)" by simp
66   next
67     fix ae a \<Gamma> e S
68     show "const_on (prognosis ae a (\<Gamma>, e, S)) (ap S) many"
69     proof
70       fix x
71       assume "x \<in> ap S"
72       hence "[x,x] \<in> paths (Fstack S)"
73         by (induction S rule: Fstack.induct)
74            (auto 4 4 intro: set_mp[OF both_contains_arg1] set_mp[OF both_contains_arg2] paths_Cons_nxt)
75       hence "[x,x] \<in> paths (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)"
76         by (rule set_mp[OF both_contains_arg2])
77       hence "[x,x] \<in> paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))" 
78         by (rule set_mp[OF substitute_contains_arg])
79       hence "pathCard [x,x] x \<sqsubseteq> pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))) x"
80         by (metis fun_belowD paths_Card_above)
81       also have "pathCard [x,x] x = many"  by (auto simp add: pathCard_def)
82       finally
83       show "prognosis ae a (\<Gamma>, e, S) x = many"
84         by (auto intro: below_antisym)
85     qed
86   next
87     fix ae a \<Gamma> e x S
88     have "Fexp e\<cdot>(inc\<cdot>a)  \<otimes>\<otimes> many_calls x \<otimes>\<otimes> Fstack S = many_calls x  \<otimes>\<otimes> (Fexp e)\<cdot>(inc\<cdot>a) \<otimes>\<otimes> Fstack S"
89       by (metis both_assoc both_comm)
90     thus "prognosis ae (inc\<cdot>a) (\<Gamma>, e, Arg x # S) \<sqsubseteq> prognosis ae a (\<Gamma>, App e x, S)"
91       by simp (intro pathsCard_mono' paths_mono substitute_mono2' both_mono1' Fexp_App)
92   next
93     fix ae a \<Gamma> e y x S
94     have "Fexp e[y::=x]\<cdot>(pred\<cdot>a) \<sqsubseteq> many_calls x  \<otimes>\<otimes> Fexp (Lam [y]. e)\<cdot>a"
95       by (rule below_trans[OF Fexp_subst both_mono2'[OF Fexp_Lam]])
96     moreover have "Fexp (Lam [y]. e)\<cdot>a \<otimes>\<otimes> many_calls x \<otimes>\<otimes> Fstack S = many_calls x  \<otimes>\<otimes> Fexp (Lam [y]. e)\<cdot>a \<otimes>\<otimes> Fstack S"
97       by (metis both_assoc both_comm)
98     ultimately  
99     show "prognosis ae (pred\<cdot>a) (\<Gamma>, e[y::=x], S) \<sqsubseteq> prognosis ae a (\<Gamma>, Lam [y]. e, Arg x # S)"
100       by simp (intro pathsCard_mono' paths_mono substitute_mono2' both_mono1')
101   next
102     fix \<Gamma> :: heap and e :: exp and x :: var and ae :: AEnv and u a S
103     assume "map_of \<Gamma> x = Some e"
104     assume "ae x = up\<cdot>u"
105
106     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S))) = pathsCard (paths (nxt (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) x))"
107       by simp
108     also
109     have "\<dots> \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))))"
110       by (rule pathsCard_paths_nxt)
111     also
112     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> Fexp e\<cdot>u)))))"
113       by (metis both_comm)
114     also
115     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)))))"
116       using `map_of \<Gamma> x = Some e` `ae x = up\<cdot>u` by (simp add: Fexp.AnalBinds_lookup)
117     also
118     assume "isLam e"
119     hence "x \<notin> thunks \<Gamma>" using `map_of \<Gamma> x = Some e` by (metis thunksE)
120     hence "FBinds \<Gamma>\<cdot>ae = f_nxt (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) x" by (auto simp add: f_nxt_def)
121     hence "and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (and_then x (Fstack S))"
122       by (simp add: substitute_and_then)
123     also
124     have "and_then x (Fstack S) \<sqsubseteq> FTree.single x \<otimes>\<otimes> Fstack S" by (rule and_then_both_single')
125     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF this]]]
126     also
127     have "FTree.single x \<sqsubseteq> Fexp (Var x)\<cdot>a" by (rule Fexp_Var)
128     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF both_mono1'[OF this]]]]
129     finally
130     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp (Var x)\<cdot>a  \<otimes>\<otimes> Fstack S))))" 
131       by this simp_all
132     thus "prognosis ae u (\<Gamma>, e, S) \<sqsubseteq> record_call x\<cdot>(prognosis ae a (\<Gamma>, Var x, S))" by simp
133   next
134     fix \<Gamma> :: heap and e :: exp and x :: var and ae :: AEnv and u a S
135     assume "map_of \<Gamma> x = Some e"
136     assume "ae x = up\<cdot>u"
137     assume "\<not> isLam e"
138     hence "x \<in> thunks \<Gamma>" using `map_of \<Gamma> x = Some e` by (metis thunksI)
139     hence [simp]: "f_nxt (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) x = FBinds (delete x \<Gamma>)\<cdot>ae" 
140       by (auto simp add: f_nxt_def Fexp.AnalBinds_delete_to_fun_upd empty_is_bottom)
141
142     have "pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks (delete x \<Gamma>)) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S)))
143        =  pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S)))"
144        by (rule arg_cong[OF substitute_cong_T]) (auto simp add: empty_is_bottom)
145     also have "\<dots>  = pathsCard (paths (nxt (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) x))"
146       by simp
147     also
148     have "\<dots> \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))))"
149       by (rule pathsCard_paths_nxt)
150     also
151     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> Fexp e\<cdot>u)))))"
152       by (metis both_comm)
153     also
154     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)))))"
155       using `map_of \<Gamma> x = Some e` `ae x = up\<cdot>u` by (simp add: Fexp.AnalBinds_lookup)
156     also
157     have "and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (and_then x (Fstack S))"
158       by (simp add: substitute_and_then)
159     also
160     have "and_then x (Fstack S) \<sqsubseteq> FTree.single x \<otimes>\<otimes> Fstack S" by (rule and_then_both_single')
161     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF this]]]
162     also
163     have "FTree.single x \<sqsubseteq> Fexp (Var x)\<cdot>a" by (rule Fexp_Var)
164     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF both_mono1'[OF this]]]]
165     finally
166     have "pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks (delete x \<Gamma>)) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))
167        \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp (Var x)\<cdot>a  \<otimes>\<otimes> Fstack S))))" 
168       by this simp_all
169     thus "prognosis ae u (delete x \<Gamma>, e, Upd x # S) \<sqsubseteq> record_call x\<cdot>(prognosis ae a (\<Gamma>, Var x, S))" by simp
170   next
171     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and  x :: var and  S
172     assume "isLam e"
173     hence "repeatable (Fexp e\<cdot>0)" by (rule Fun_repeatable)
174
175     assume [simp]: "x \<notin> domA \<Gamma>"
176
177     have [simp]: "thunks ((x, e) # \<Gamma>) = thunks \<Gamma>" 
178       using `isLam e`
179       by (auto simp add: thunks_Cons dest: set_mp[OF thunks_domA])
180
181     have "fup\<cdot>(Fexp e)\<cdot>(ae x) \<sqsubseteq> Fexp e\<cdot>0" by (metis fup2 monofun_cfun_arg up_zero_top)
182     hence "substitute ((FBinds \<Gamma>\<cdot>ae)(x := fup\<cdot>(Fexp e)\<cdot>(ae x))) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S) \<sqsubseteq> substitute ((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0)) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S)"
183       by (intro substitute_mono1' fun_upd_mono below_refl)
184     also have "\<dots> = substitute (((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0))(x := empty)) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S)"
185       using `repeatable (Fexp e\<cdot>0)` by (rule substitute_remove_anyways, simp)
186     also have "((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0))(x := empty) = FBinds \<Gamma>\<cdot>ae"
187       by (simp add: fun_upd_idem Fexp.AnalBinds_not_there empty_is_bottom)
188     finally
189     show "prognosis ae 0 ((x, e) # \<Gamma>, e, S) \<sqsubseteq> prognosis ae 0 (\<Gamma>, e, Upd x # S)"
190       by (simp, intro pathsCard_mono' paths_mono)
191   next
192     fix \<Gamma> \<Delta> :: heap and e :: exp and ae :: AEnv and u S
193     assume "map_of \<Gamma> = map_of \<Delta>"
194     hence "FBinds \<Gamma> = FBinds \<Delta>" and "thunks \<Gamma> = thunks \<Delta>" by (auto intro!: cfun_eqI  thunks_cong simp add: Fexp.AnalBinds_lookup)
195     thus "prognosis ae u (\<Gamma>, e, S) = prognosis ae u (\<Delta>, e, S)"  by simp
196   next
197     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and u S x
198
199     show "prognosis ae u (delete x \<Gamma>, e, S) \<sqsubseteq> prognosis ae u (\<Gamma>, e, S)"
200       by (simp add: substitute_T_delete empty_is_bottom)
201          (intro pathsCard_mono' paths_mono substitute_mono1' Fexp.AnalBinds_delete_below)
202   next
203     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and u S x
204     show "prognosis ae u (\<Gamma>, e, S) \<sqsubseteq> prognosis ae u (\<Gamma>, e, Upd x # S)" by simp
205   next
206   fix \<Gamma> :: heap and e :: exp and ae :: AEnv and a S x
207   assume "ae x = \<bottom>"
208
209   hence "FBinds (delete x \<Gamma>)\<cdot>ae = FBinds \<Gamma>\<cdot>ae" by (rule Fexp.AnalBinds_delete_bot)
210   moreover
211   hence "((FBinds \<Gamma>\<cdot>ae) x) = \<bottom>" by (metis Fexp.AnalBinds_delete_lookup)
212   ultimately
213   show "prognosis ae a (\<Gamma>, e, S) \<sqsubseteq> prognosis ae a (delete x \<Gamma>, e, S)"
214     by (simp add: substitute_T_delete empty_is_bottom)
215   next
216     fix ae a \<Gamma> x S
217     have "once \<sqsubseteq> (pathCard [x]) x" by (simp add: two_add_simp)
218     also have "pathCard [x] \<sqsubseteq> pathsCard ({[],[x]})"
219       by (rule paths_Card_above) simp
220     also have "\<dots> = pathsCard (paths (single x))" by simp
221     also have "single x \<sqsubseteq> (Fexp (Var x)\<cdot>a)" by (rule Fexp_Var)
222     also have "\<dots> \<sqsubseteq> Fexp (Var x)\<cdot>a \<otimes>\<otimes> Fstack S" by (rule both_above_arg1)
223     also have "\<dots> \<sqsubseteq> substitute  (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp (Var x)\<cdot>a \<otimes>\<otimes> Fstack S)" by (rule substitute_above_arg)
224     also have "pathsCard (paths \<dots>) x =  prognosis ae a (\<Gamma>, Var x, S) x" by simp
225     finally
226     show "once \<sqsubseteq> prognosis ae a (\<Gamma>, Var x, S) x"
227       by this (rule cont2cont_fun, intro cont2cont)+
228   qed
229 end
230
231 context FTreeAnalysisCardinalityHeap
232 begin
233
234   definition cHeap where
235     "cHeap \<Gamma> e = (\<Lambda> a. pathsCard (paths (Fheap \<Gamma> e\<cdot>a)))"
236
237   lemma cHeap_simp: "(cHeap \<Gamma> e)\<cdot>a = pathsCard (paths (Fheap \<Gamma> e\<cdot>a))"
238     unfolding cHeap_def  by (rule beta_cfun) (intro cont2cont)
239   
240   (*
241   lemma cHeap_eqvt: "\<pi> \<bullet> (cHeap \<Gamma> e) = cHeap (\<pi> \<bullet> \<Gamma>) (\<pi> \<bullet> e)"
242     unfolding cHeap_def
243     apply perm_simp
244     apply (simp add: Fheap_eqvt)
245     apply (rule Abs_cfun_eqvt)
246     apply (intro cont2cont)
247     done
248   *)
249
250   sublocale CardinalityHeap Aexp Aheap cHeap
251   proof
252   (*
253     note cHeap_eqvt[eqvt]
254     fix \<pi> show "\<pi> \<bullet> cHeap = cHeap" by perm_simp rule
255   next
256   *)
257     fix x \<Gamma> e a
258     assume "x \<in> thunks \<Gamma>"
259     moreover
260     assume "many \<sqsubseteq> (cHeap \<Gamma> e\<cdot>a) x"
261     hence "many \<sqsubseteq> pathsCard (paths (Fheap \<Gamma> e \<cdot>a)) x" unfolding cHeap_def by simp
262     hence "\<exists>p\<in> (paths (Fheap \<Gamma> e\<cdot>a)). \<not> (one_call_in_path x p)" unfolding pathsCard_def
263       by (auto split: if_splits)
264     ultimately
265     show "(Aheap \<Gamma> e\<cdot>a) x = up\<cdot>0"
266       by (metis Fheap_thunk)
267   next
268     fix \<Gamma> e a
269     show "edom (cHeap \<Gamma> e\<cdot>a) = edom (Aheap \<Gamma> e\<cdot>a)"
270     by (simp add: cHeap_def Union_paths_carrier carrier_Fheap)
271   qed
272
273   sublocale CardinalityPrognosisEdom prognosis Aexp Aheap
274   proof
275     fix ae a \<Gamma> e S
276     show "edom (prognosis ae a (\<Gamma>, e, S)) \<subseteq> fv \<Gamma> \<union> fv e \<union> fv S"
277       apply (simp add: Union_paths_carrier)
278       apply (rule carrier_substitute_below)
279       apply (auto simp add: carrier_Fexp dest: set_mp[OF Aexp_edom] set_mp[OF ap_fv_subset] set_mp[OF carrier_FBinds])
280       done
281   qed
282   
283   sublocale CardinalityPrognosisCorrectLet prognosis Aexp Aheap cHeap
284   proof
285     fix \<Delta> \<Gamma> :: heap and e :: exp and S :: stack and  ae :: AEnv and a :: Arity
286     assume "atom ` domA \<Delta> \<sharp>* \<Gamma>"
287     assume "atom ` domA \<Delta> \<sharp>* S"
288     assume "edom ae \<subseteq> domA \<Gamma> \<union> upds S"
289
290     have "domA \<Delta> \<inter> edom ae = {}"
291       using fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`] fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`] 
292             `edom ae \<subseteq> domA \<Gamma> \<union> upds S` ups_fv_subset[of S]
293       by auto
294
295     have const_on1:  "\<And> x. const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (carrier ((FBinds \<Gamma>\<cdot>ae) x)) empty"
296       unfolding const_on_edom_disj using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
297       by (auto dest!: set_mp[OF carrier_FBinds] set_mp[OF Fexp.edom_AnalBinds])
298     have const_on2:  "const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (carrier (Fstack S)) empty"
299       unfolding const_on_edom_disj using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`]
300       by (auto dest!: set_mp[OF carrier_FBinds] set_mp[OF Fexp.edom_AnalBinds] set_mp[OF ap_fv_subset ])
301     have  const_on3: "const_on (FBinds \<Gamma>\<cdot>ae) (- (- domA \<Delta>)) FTree.empty"
302       and const_on4: "const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (domA \<Gamma>) FTree.empty"
303       unfolding const_on_edom_disj using fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
304       by (auto dest!:  set_mp[OF Fexp.edom_AnalBinds])
305
306     have disj1: "\<And> x. carrier ((FBinds \<Gamma>\<cdot>ae) x) \<inter> domA \<Delta> = {}"
307       using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
308       by (auto dest: set_mp[OF carrier_FBinds])
309     hence disj1': "\<And> x. carrier ((FBinds \<Gamma>\<cdot>ae) x) \<subseteq> - domA \<Delta>" by auto
310     have disj2: "\<And> x. carrier (Fstack S) \<inter> domA \<Delta> = {}"
311       using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`] ap_fv_subset[of S] by auto
312     hence disj2': "carrier (Fstack S) \<subseteq> - domA \<Delta>" by auto
313     
314
315     {
316     fix x
317     have "(FBinds (\<Delta> @ \<Gamma>)\<cdot>(ae \<squnion> Aheap \<Delta> e\<cdot>a)) x = (FBinds \<Gamma>\<cdot>ae) x \<otimes>\<otimes> (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) x"
318     proof (cases "x \<in> domA \<Delta>")
319       case True
320       have "map_of \<Gamma> x = None" using True fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`] by (metis disjoint_iff_not_equal domA_def map_of_eq_None_iff)
321       moreover
322       have "ae x = \<bottom>" using True `domA \<Delta> \<inter> edom ae = {}` by auto
323       ultimately
324       show ?thesis using True 
325           by (auto simp add: Fexp.AnalBinds_lookup empty_is_bottom[symmetric] cong: option.case_cong)
326     next
327       case False
328       have "map_of \<Delta> x = None" using False by (metis domA_def map_of_eq_None_iff)
329       moreover
330       have "(Aheap \<Delta> e\<cdot>a) x = \<bottom>" using False using edom_Aheap by (metis contra_subsetD edomIff)
331       ultimately
332       show ?thesis using False
333          by (auto simp add: Fexp.AnalBinds_lookup empty_is_bottom[symmetric] cong: option.case_cong)
334     qed
335     }
336     note FBinds = ext[OF this]
337
338     {
339     have "pathsCard (paths (substitute (FBinds (\<Delta> @ \<Gamma>)\<cdot>(Aheap \<Delta> e\<cdot>a \<squnion> ae)) (thunks (\<Delta> @ \<Gamma>)) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)))
340       = pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks (\<Delta> @ \<Gamma>)) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a))  (thunks (\<Delta> @ \<Gamma>))  (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))))"
341        by (simp add: substitute_substitute[OF const_on1] FBinds)
342     also have "substitute (FBinds \<Gamma>\<cdot>ae) (thunks (\<Delta> @ \<Gamma>)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>)"
343       apply (rule substitute_cong_T)
344       using const_on3
345       by (auto dest: set_mp[OF thunks_domA])
346     also have "substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks (\<Delta> @ \<Gamma>)) = substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>)"
347       apply (rule substitute_cong_T)
348       using const_on4
349       by (auto dest: set_mp[OF thunks_domA])
350     also have "substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S) = substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S" 
351       by (rule substitute_only_empty_both[OF const_on2])
352     also note calculation
353     }
354     note eq_imp_below[OF this]
355     also
356     note env_restr_split[where S = "domA \<Delta>"]
357     also
358     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S))) f|` domA \<Delta> 
359         = pathsCard (paths (ftree_restr (domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a))))"
360           by (simp add: filter_paths_conv_free_restr ftree_restr_both ftree_rest_substitute[OF disj1]  ftree_restr_is_empty[OF disj2])
361     also
362     have "ftree_restr (domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a)) \<sqsubseteq> Fheap \<Delta> e\<cdot>a"  by (rule Fheap_substitute)
363     also
364     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S))) f|` (- domA \<Delta>) =
365           pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (ftree_restr (- domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a)) \<otimes>\<otimes> Fstack S)))"
366           by (simp add: filter_paths_conv_free_restr2 ftree_rest_substitute2[OF disj1' const_on3] ftree_restr_both  ftree_restr_noop[OF disj2'])
367     also have "ftree_restr (- domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a))  (thunks \<Delta>)  (Fexp e\<cdot>a)) \<sqsubseteq> Fexp (Terms.Let \<Delta> e)\<cdot>a" by (rule Fexp_Let)
368     finally
369     show "prognosis (Aheap \<Delta> e\<cdot>a \<squnion> ae) a (\<Delta> @ \<Gamma>, e, S) \<sqsubseteq> cHeap \<Delta> e\<cdot>a \<squnion> prognosis ae a (\<Gamma>, Terms.Let \<Delta> e, S)"
370       by (simp add: cHeap_def del: fun_meet_simp) 
371   qed
372 end
373
374 end