c551e5e59883e77042a9c8ee08fda748968d0358
[darcs-mirror-isa-launchbury.git] / Launchbury / FTreeCardinality.thy
1 theory FTreeCardinality
2 imports CardinalityAnalysis "FTree-HOLCF" CallFutureCardinality AnalBinds
3 begin
4
5 locale FutureAnalysis =
6  fixes Fexp :: "exp \<Rightarrow> Arity \<rightarrow> var ftree"
7 begin
8   sublocale Fexp!: ExpAnalysis Fexp.
9   abbreviation "FBinds == Fexp.AnalBinds"
10 end
11
12 locale FutureAnalysisCarrier = FutureAnalysis +
13   assumes carrier_Fexp: "carrier (Fexp e\<cdot>a) \<subseteq> fv e"
14
15 locale FutureAnalysisCorrect = FutureAnalysisCarrier +
16   assumes Fexp_App: "many_calls x \<otimes>\<otimes> (Fexp e)\<cdot>(inc\<cdot>a) \<sqsubseteq> Fexp (App e x)\<cdot>a"
17   assumes Fexp_Lam: "without y (Fexp e\<cdot>(pred\<cdot>n)) \<sqsubseteq> Fexp (Lam [y]. e) \<cdot> n"
18   assumes Fexp_subst: "Fexp (e[y::=x])\<cdot>a \<sqsubseteq> many_calls x \<otimes>\<otimes> without y ((Fexp e)\<cdot>a)"
19   assumes Fexp_Var: "single v \<sqsubseteq> Fexp (Var v)\<cdot>a"
20   assumes Fun_repeatable: "isLam e \<Longrightarrow> repeatable (Fexp e\<cdot>0)"
21
22 locale FutureAnalysisCardinalityHeap = 
23   FutureAnalysisCorrect + CorrectArityAnalysisLet' + 
24   fixes Fheap :: "heap \<Rightarrow> exp \<Rightarrow> Arity \<rightarrow> var ftree"
25   (* assumes Fheap_eqvt: "\<pi> \<bullet> Fheap = Fheap" *)
26   assumes carrier_Fheap: "carrier (Fheap \<Gamma> e\<cdot>a) = edom (Aheap \<Gamma> e\<cdot>a)"
27   assumes Fheap_thunk: "x \<in> thunks \<Gamma> \<Longrightarrow> p \<in> paths (Fheap \<Gamma> e\<cdot>a) \<Longrightarrow> \<not> one_call_in_path x p \<Longrightarrow> (Aheap \<Gamma> e\<cdot>a) x = up\<cdot>0"
28   assumes Fheap_substitute: "ftree_restr (domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a)) \<sqsubseteq> Fheap \<Delta> e\<cdot>a"
29   assumes Fexp_Let: "ftree_restr (- domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a))  (thunks \<Delta>) (Fexp e\<cdot>a)) \<sqsubseteq> Fexp (Terms.Let \<Delta> e)\<cdot>a"
30
31 context FutureAnalysis
32 begin
33
34 fun unstack :: "stack \<Rightarrow> exp \<Rightarrow> exp" where
35   "unstack [] e = e"
36 | "unstack (Upd x # S) e = unstack S e"
37 | "unstack (Arg x # S) e = unstack S (App e x)"
38 | "unstack (Dummy x # S) e = unstack S e"
39
40 fun Fstack :: "stack \<Rightarrow> var ftree"
41   where "Fstack [] = \<bottom>"
42   | "Fstack (Upd x # S) = Fstack S"
43   | "Fstack (Arg x # S) = many_calls x \<otimes>\<otimes> Fstack S"
44   | "Fstack (Dummy x # S) = Fstack S"
45
46 lemma carrier_Fstack[simp]: "carrier (Fstack S) = ap S"
47   by (induction S rule: Fstack.induct) (auto simp add: empty_is_bottom[symmetric])
48
49 fun prognosis :: "AEnv \<Rightarrow> Arity \<Rightarrow> conf \<Rightarrow> var \<Rightarrow> two"
50    where "prognosis ae a (\<Gamma>, e, S) = pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)))"
51 end
52
53
54 lemma pathsCard_paths_nxt:  "pathsCard (paths (nxt f x)) \<sqsubseteq> record_call x\<cdot>(pathsCard (paths f))"
55   apply transfer
56   apply (rule pathsCard_below)
57   apply auto
58   apply (erule below_trans[OF _ monofun_cfun_arg[OF paths_Card_above], rotated]) back
59   apply (auto intro: fun_belowI simp add: record_call_simp two_pred_two_add_once)
60   done
61
62 lemma pathsCards_none: "pathsCard (paths t) x = none \<Longrightarrow> x \<notin> carrier t"
63   by transfer (auto dest: pathCards_noneD)
64
65 lemma const_on_edom_disj: "const_on f S empty \<longleftrightarrow> edom f \<inter> S = {}"
66   by (auto simp add: empty_is_bottom edom_def)
67
68 context FutureAnalysisCarrier
69 begin
70   lemma carrier_FBinds: "carrier ((FBinds \<Gamma>\<cdot>ae) x) \<subseteq> fv \<Gamma>"
71   apply (simp add: Fexp.AnalBinds_lookup)
72   apply (auto split: option.split simp add: empty_is_bottom[symmetric] )
73   apply (case_tac "ae x")
74   apply (auto simp add: empty_is_bottom[symmetric] dest!: set_mp[OF carrier_Fexp])
75   by (metis (poly_guards_query) contra_subsetD domA_from_set map_of_fv_subset map_of_is_SomeD option.sel)
76
77 end
78
79
80
81
82 context FutureAnalysisCorrect
83 begin
84
85   sublocale CardinalityPrognosisCorrect prognosis
86   proof
87     fix \<Gamma> :: heap and ae ae' :: AEnv and u e S
88     assume "ae f|` domA \<Gamma> = ae' f|` domA \<Gamma>"
89     from Fexp.AnalBinds_cong[OF this]
90     show "prognosis ae u (\<Gamma>, e, S) = prognosis ae' u (\<Gamma>, e, S)" by simp
91   next
92     fix ae a \<Gamma> e S
93     show "const_on (prognosis ae a (\<Gamma>, e, S)) (ap S) many"
94     proof
95       fix x
96       assume "x \<in> ap S"
97       hence "[x,x] \<in> paths (Fstack S)"
98         by (induction S rule: Fstack.induct)
99            (auto 4 4 intro: set_mp[OF both_contains_arg1] set_mp[OF both_contains_arg2] paths_Cons_nxt)
100       hence "[x,x] \<in> paths (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)"
101         by (rule set_mp[OF both_contains_arg2])
102       hence "[x,x] \<in> paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))" 
103         by (rule set_mp[OF substitute_contains_arg])
104       hence "pathCard [x,x] x \<sqsubseteq> pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))) x"
105         by (metis fun_belowD paths_Card_above)
106       also have "pathCard [x,x] x = many"  by (auto simp add: pathCard_def)
107       finally
108       show "prognosis ae a (\<Gamma>, e, S) x = many"
109         by (auto intro: below_antisym)
110     qed
111   next
112     fix ae a \<Gamma> e x S
113     have "Fexp e\<cdot>(inc\<cdot>a)  \<otimes>\<otimes> many_calls x \<otimes>\<otimes> Fstack S = many_calls x  \<otimes>\<otimes> (Fexp e)\<cdot>(inc\<cdot>a) \<otimes>\<otimes> Fstack S"
114       by (metis both_assoc both_comm)
115     thus "prognosis ae (inc\<cdot>a) (\<Gamma>, e, Arg x # S) \<sqsubseteq> prognosis ae a (\<Gamma>, App e x, S)"
116       by simp (intro pathsCard_mono' paths_mono substitute_mono2' both_mono1' Fexp_App)
117   next
118     fix ae a \<Gamma> e y x S
119     have "Fexp e[y::=x]\<cdot>(pred\<cdot>a) \<sqsubseteq> many_calls x  \<otimes>\<otimes> Fexp (Lam [y]. e)\<cdot>a"
120       by (rule below_trans[OF Fexp_subst both_mono2'[OF Fexp_Lam]])
121     moreover have "Fexp (Lam [y]. e)\<cdot>a \<otimes>\<otimes> many_calls x \<otimes>\<otimes> Fstack S = many_calls x  \<otimes>\<otimes> Fexp (Lam [y]. e)\<cdot>a \<otimes>\<otimes> Fstack S"
122       by (metis both_assoc both_comm)
123     ultimately  
124     show "prognosis ae (pred\<cdot>a) (\<Gamma>, e[y::=x], S) \<sqsubseteq> prognosis ae a (\<Gamma>, Lam [y]. e, Arg x # S)"
125       by simp (intro pathsCard_mono' paths_mono substitute_mono2' both_mono1')
126   next
127     fix \<Gamma> :: heap and e :: exp and x :: var and ae :: AEnv and u a S
128     assume "map_of \<Gamma> x = Some e"
129     assume "ae x = up\<cdot>u"
130
131     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S))) = pathsCard (paths (nxt (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) x))"
132       by simp
133     also
134     have "\<dots> \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))))"
135       by (rule pathsCard_paths_nxt)
136     also
137     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> Fexp e\<cdot>u)))))"
138       by (metis both_comm)
139     also
140     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)))))"
141       using `map_of \<Gamma> x = Some e` `ae x = up\<cdot>u` by (simp add: Fexp.AnalBinds_lookup)
142     also
143     assume "isLam e"
144     hence "x \<notin> thunks \<Gamma>" using `map_of \<Gamma> x = Some e` by (metis thunksE)
145     hence "FBinds \<Gamma>\<cdot>ae = f_nxt (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) x" by (auto simp add: f_nxt_def)
146     hence "and_then x (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (and_then x (Fstack S))"
147       by (simp add: substitute_and_then)
148     also
149     have "and_then x (Fstack S) \<sqsubseteq> FTree.single x \<otimes>\<otimes> Fstack S" by (rule and_then_both_single')
150     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF this]]]
151     also
152     have "FTree.single x \<sqsubseteq> Fexp (Var x)\<cdot>a" by (rule Fexp_Var)
153     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF both_mono1'[OF this]]]]
154     finally
155     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp (Var x)\<cdot>a  \<otimes>\<otimes> Fstack S))))" 
156       by this simp_all
157     thus "prognosis ae u (\<Gamma>, e, S) \<sqsubseteq> record_call x\<cdot>(prognosis ae a (\<Gamma>, Var x, S))" by simp
158   next
159     fix \<Gamma> :: heap and e :: exp and x :: var and ae :: AEnv and u a S
160     assume "map_of \<Gamma> x = Some e"
161     assume "ae x = up\<cdot>u"
162     assume "\<not> isLam e"
163     hence "x \<in> thunks \<Gamma>" using `map_of \<Gamma> x = Some e` by (metis thunksI)
164     hence [simp]: "f_nxt (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) x = FBinds (delete x \<Gamma>)\<cdot>ae" 
165       by (auto simp add: f_nxt_def Fexp.AnalBinds_delete_to_fun_upd empty_is_bottom)
166
167     have "pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks (delete x \<Gamma>)) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S)))
168        =  pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u \<otimes>\<otimes> Fstack S)))"
169        by (rule arg_cong[OF substitute_cong_T]) (auto simp add: empty_is_bottom)
170     also have "\<dots>  = pathsCard (paths (nxt (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S))) x))"
171       by simp
172     also
173     have "\<dots> \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))))"
174       by (rule pathsCard_paths_nxt)
175     also
176     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> Fexp e\<cdot>u)))))"
177       by (metis both_comm)
178     also
179     have "\<dots> = record_call x\<cdot>(pathsCard (paths (and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S  \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)))))"
180       using `map_of \<Gamma> x = Some e` `ae x = up\<cdot>u` by (simp add: Fexp.AnalBinds_lookup)
181     also
182     have "and_then x (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks \<Gamma>) (Fstack S \<otimes>\<otimes> (FBinds \<Gamma>\<cdot>ae) x)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (and_then x (Fstack S))"
183       by (simp add: substitute_and_then)
184     also
185     have "and_then x (Fstack S) \<sqsubseteq> FTree.single x \<otimes>\<otimes> Fstack S" by (rule and_then_both_single')
186     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF this]]]
187     also
188     have "FTree.single x \<sqsubseteq> Fexp (Var x)\<cdot>a" by (rule Fexp_Var)
189     note pathsCard_mono'[OF paths_mono[OF substitute_mono2'[OF both_mono1'[OF this]]]]
190     finally
191     have "pathsCard (paths (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (thunks (delete x \<Gamma>)) (Fexp e\<cdot>u  \<otimes>\<otimes> Fstack S)))
192        \<sqsubseteq> record_call x\<cdot>(pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (Fexp (Var x)\<cdot>a  \<otimes>\<otimes> Fstack S))))" 
193       by this simp_all
194     thus "prognosis ae u (delete x \<Gamma>, e, Upd x # S) \<sqsubseteq> record_call x\<cdot>(prognosis ae a (\<Gamma>, Var x, S))" by simp
195   next
196     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and  x :: var and  S
197     assume "isLam e"
198     hence "repeatable (Fexp e\<cdot>0)" by (rule Fun_repeatable)
199
200     assume [simp]: "x \<notin> domA \<Gamma>"
201
202     have [simp]: "thunks ((x, e) # \<Gamma>) = thunks \<Gamma>" 
203       using `isLam e`
204       by (auto simp add: thunks_Cons dest: set_mp[OF thunks_domA])
205
206     have "fup\<cdot>(Fexp e)\<cdot>(ae x) \<sqsubseteq> Fexp e\<cdot>0" by (metis fup2 monofun_cfun_arg up_zero_top)
207     hence "substitute ((FBinds \<Gamma>\<cdot>ae)(x := fup\<cdot>(Fexp e)\<cdot>(ae x))) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S) \<sqsubseteq> substitute ((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0)) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S)"
208       by (intro substitute_mono1' fun_upd_mono below_refl)
209     also have "\<dots> = substitute (((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0))(x := empty)) (thunks \<Gamma>) (Fexp e\<cdot>0 \<otimes>\<otimes> Fstack S)"
210       using `repeatable (Fexp e\<cdot>0)` by (rule substitute_remove_anyways, simp)
211     also have "((FBinds \<Gamma>\<cdot>ae)(x := Fexp e\<cdot>0))(x := empty) = FBinds \<Gamma>\<cdot>ae"
212       by (simp add: fun_upd_idem Fexp.AnalBinds_not_there empty_is_bottom)
213     finally
214     show "prognosis ae 0 ((x, e) # \<Gamma>, e, S) \<sqsubseteq> prognosis ae 0 (\<Gamma>, e, Upd x # S)"
215       by (simp, intro pathsCard_mono' paths_mono)
216   next
217     fix \<Gamma> \<Delta> :: heap and e :: exp and ae :: AEnv and u S
218     assume "map_of \<Gamma> = map_of \<Delta>"
219     hence "FBinds \<Gamma> = FBinds \<Delta>" and "thunks \<Gamma> = thunks \<Delta>" by (auto intro!: cfun_eqI  thunks_cong simp add: Fexp.AnalBinds_lookup)
220     thus "prognosis ae u (\<Gamma>, e, S) = prognosis ae u (\<Delta>, e, S)"  by simp
221   next
222     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and u S x
223
224     show "prognosis ae u (delete x \<Gamma>, e, S) \<sqsubseteq> prognosis ae u (\<Gamma>, e, S)"
225       by (simp add: substitute_T_delete empty_is_bottom)
226          (intro pathsCard_mono' paths_mono substitute_mono1' Fexp.AnalBinds_delete_below)
227   next
228     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and u S x
229     show "prognosis ae u (\<Gamma>, e, S) \<sqsubseteq> prognosis ae u (\<Gamma>, e, Upd x # S)" by simp
230   next
231     fix \<Gamma> :: heap and e :: exp and ae :: AEnv and a S x
232     assume "ae x = \<bottom>"
233     (*
234     assume "prognosis ae a (delete x \<Gamma>, e, S) x = none"
235     hence "x \<notin> carrier (substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))" 
236       by (simp add: pathsCards_none)
237     hence "substitute (FBinds \<Gamma>\<cdot>ae) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S) = substitute (FBinds (delete x \<Gamma>)\<cdot>ae) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)"
238       by (auto intro: substitute_cong[symmetric] simp add: Fexp.AnalBinds_lookup delete_conv')
239      *)
240     hence "FBinds (delete x \<Gamma>)\<cdot>ae = FBinds \<Gamma>\<cdot>ae" by (rule Fexp.AnalBinds_delete_bot)
241     moreover
242     hence "((FBinds \<Gamma>\<cdot>ae) x) = \<bottom>" by (metis Fexp.AnalBinds_delete_lookup)
243     ultimately
244     show "prognosis ae a (\<Gamma>, e, S) \<sqsubseteq> prognosis ae a (delete x \<Gamma>, e, S)"
245       by (simp add: substitute_T_delete empty_is_bottom)
246   qed
247 end
248
249 context FutureAnalysisCardinalityHeap
250 begin
251
252   definition cHeap where
253     "cHeap \<Gamma> e = (\<Lambda> a. pathsCard (paths (Fheap \<Gamma> e\<cdot>a)))"
254
255   lemma cHeap_simp: "(cHeap \<Gamma> e)\<cdot>a = pathsCard (paths (Fheap \<Gamma> e\<cdot>a))"
256     unfolding cHeap_def  by (rule beta_cfun) (intro cont2cont)
257   
258   (*
259   lemma cHeap_eqvt: "\<pi> \<bullet> (cHeap \<Gamma> e) = cHeap (\<pi> \<bullet> \<Gamma>) (\<pi> \<bullet> e)"
260     unfolding cHeap_def
261     apply perm_simp
262     apply (simp add: Fheap_eqvt)
263     apply (rule Abs_cfun_eqvt)
264     apply (intro cont2cont)
265     done
266   *)
267
268   sublocale CardinalityHeap Aexp Aheap cHeap
269   proof
270   (*
271     note cHeap_eqvt[eqvt]
272     fix \<pi> show "\<pi> \<bullet> cHeap = cHeap" by perm_simp rule
273   next
274   *)
275     fix x \<Gamma> e a
276     assume "x \<in> thunks \<Gamma>"
277     moreover
278     assume "many \<sqsubseteq> (cHeap \<Gamma> e\<cdot>a) x"
279     hence "many \<sqsubseteq> pathsCard (paths (Fheap \<Gamma> e \<cdot>a)) x" unfolding cHeap_def by simp
280     hence "\<exists>p\<in> (paths (Fheap \<Gamma> e\<cdot>a)). \<not> (one_call_in_path x p)" unfolding pathsCard_def
281       by (auto split: if_splits)
282     ultimately
283     show "(Aheap \<Gamma> e\<cdot>a) x = up\<cdot>0"
284       by (metis Fheap_thunk)
285   next
286     fix \<Gamma> e a
287     show "edom (cHeap \<Gamma> e\<cdot>a) = edom (Aheap \<Gamma> e\<cdot>a)"
288     by (simp add: cHeap_def Union_paths_carrier carrier_Fheap)
289   qed
290
291   sublocale CardinalityPrognosisCorrectLet prognosis Aexp Aheap cHeap
292   proof
293     fix \<Delta> \<Gamma> :: heap and e :: exp and S :: stack and  ae :: AEnv and a :: Arity
294     assume "atom ` domA \<Delta> \<sharp>* \<Gamma>"
295     assume "atom ` domA \<Delta> \<sharp>* S"
296     assume "edom ae \<subseteq> domA \<Gamma> \<union> upds S"
297
298     have "domA \<Delta> \<inter> edom ae = {}"
299       using fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`] fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`] 
300             `edom ae \<subseteq> domA \<Gamma> \<union> upds S` ups_fv_subset[of S]
301       by auto
302
303     have const_on1:  "\<And> x. const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (carrier ((FBinds \<Gamma>\<cdot>ae) x)) empty"
304       unfolding const_on_edom_disj using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
305       by (auto dest!: set_mp[OF carrier_FBinds] set_mp[OF Fexp.edom_AnalBinds])
306     have const_on2:  "const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (carrier (Fstack S)) empty"
307       unfolding const_on_edom_disj using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`]
308       by (auto dest!: set_mp[OF carrier_FBinds] set_mp[OF Fexp.edom_AnalBinds] set_mp[OF ap_fv_subset ])
309     have  const_on3: "const_on (FBinds \<Gamma>\<cdot>ae) (- (- domA \<Delta>)) FTree.empty"
310       and const_on4: "const_on (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (domA \<Gamma>) FTree.empty"
311       unfolding const_on_edom_disj using fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
312       by (auto dest!:  set_mp[OF Fexp.edom_AnalBinds])
313
314     have disj1: "\<And> x. carrier ((FBinds \<Gamma>\<cdot>ae) x) \<inter> domA \<Delta> = {}"
315       using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`]
316       by (auto dest: set_mp[OF carrier_FBinds])
317     hence disj1': "\<And> x. carrier ((FBinds \<Gamma>\<cdot>ae) x) \<subseteq> - domA \<Delta>" by auto
318     have disj2: "\<And> x. carrier (Fstack S) \<inter> domA \<Delta> = {}"
319       using fresh_distinct_fv[OF `atom \` domA \<Delta> \<sharp>* S`] ap_fv_subset[of S] by auto
320     hence disj2': "carrier (Fstack S) \<subseteq> - domA \<Delta>" by auto
321     
322
323     {
324     fix x
325     have "(FBinds (\<Delta> @ \<Gamma>)\<cdot>(ae \<squnion> Aheap \<Delta> e\<cdot>a)) x = (FBinds \<Gamma>\<cdot>ae) x \<otimes>\<otimes> (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) x"
326     proof (cases "x \<in> domA \<Delta>")
327       case True
328       have "map_of \<Gamma> x = None" using True fresh_distinct[OF `atom \` domA \<Delta> \<sharp>* \<Gamma>`] by (metis disjoint_iff_not_equal domA_def map_of_eq_None_iff)
329       moreover
330       have "ae x = \<bottom>" using True `domA \<Delta> \<inter> edom ae = {}` by auto
331       ultimately
332       show ?thesis using True 
333           by (auto simp add: Fexp.AnalBinds_lookup empty_is_bottom[symmetric] cong: option.case_cong)
334     next
335       case False
336       have "map_of \<Delta> x = None" using False by (metis domA_def map_of_eq_None_iff)
337       moreover
338       have "(Aheap \<Delta> e\<cdot>a) x = \<bottom>" using False using edom_Aheap by (metis contra_subsetD edomIff)
339       ultimately
340       show ?thesis using False
341          by (auto simp add: Fexp.AnalBinds_lookup empty_is_bottom[symmetric] cong: option.case_cong)
342     qed
343     }
344     note FBinds = ext[OF this]
345
346     {
347     have "pathsCard (paths (substitute (FBinds (\<Delta> @ \<Gamma>)\<cdot>(Aheap \<Delta> e\<cdot>a \<squnion> ae)) (thunks (\<Delta> @ \<Gamma>)) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S)))
348       = pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks (\<Delta> @ \<Gamma>)) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a))  (thunks (\<Delta> @ \<Gamma>))  (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S))))"
349        by (simp add: substitute_substitute[OF const_on1] FBinds)
350     also have "substitute (FBinds \<Gamma>\<cdot>ae) (thunks (\<Delta> @ \<Gamma>)) = substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>)"
351       apply (rule substitute_cong_T)
352       using const_on3
353       by (auto dest: set_mp[OF thunks_domA])
354     also have "substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks (\<Delta> @ \<Gamma>)) = substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>)"
355       apply (rule substitute_cong_T)
356       using const_on4
357       by (auto dest: set_mp[OF thunks_domA])
358     also have "substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a \<otimes>\<otimes> Fstack S) = substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S" 
359       by (rule substitute_only_empty_both[OF const_on2])
360     also note calculation
361     }
362     note eq_imp_below[OF this]
363     also
364     note env_restr_split[where S = "domA \<Delta>"]
365     also
366     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S))) f|` domA \<Delta> 
367         = pathsCard (paths (ftree_restr (domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a))))"
368           by (simp add: filter_paths_conv_free_restr ftree_restr_both ftree_rest_substitute[OF disj1]  ftree_restr_is_empty[OF disj2])
369     also
370     have "ftree_restr (domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a)) \<sqsubseteq> Fheap \<Delta> e\<cdot>a"  by (rule Fheap_substitute)
371     also
372     have "pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a) \<otimes>\<otimes> Fstack S))) f|` (- domA \<Delta>) =
373           pathsCard (paths (substitute (FBinds \<Gamma>\<cdot>ae) (thunks \<Gamma>) (ftree_restr (- domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a)) (thunks \<Delta>) (Fexp e\<cdot>a)) \<otimes>\<otimes> Fstack S)))"
374           by (simp add: filter_paths_conv_free_restr2 ftree_rest_substitute2[OF disj1' const_on3] ftree_restr_both  ftree_restr_noop[OF disj2'])
375     also have "ftree_restr (- domA \<Delta>) (substitute (FBinds \<Delta>\<cdot>(Aheap \<Delta> e\<cdot>a))  (thunks \<Delta>)  (Fexp e\<cdot>a)) \<sqsubseteq> Fexp (Terms.Let \<Delta> e)\<cdot>a" by (rule Fexp_Let)
376     finally
377     show "prognosis (Aheap \<Delta> e\<cdot>a \<squnion> ae) a (\<Delta> @ \<Gamma>, e, S) \<sqsubseteq> cHeap \<Delta> e\<cdot>a \<squnion> prognosis ae a (\<Gamma>, Terms.Let \<Delta> e, S)"
378       by (simp add: cHeap_def del: fun_meet_simp) 
379   qed
380 end
381
382 end