13764c3a629cb5e3b49c7116c4a10ceaf0147c9d
[darcs-mirror-polyfix.git] / Expr.hs
1 {-# LANGUAGE PatternGuards, DeriveDataTypeable   #-}
2 module Expr where
3
4 import Data.List
5 import Data.Maybe
6 import ParseType
7
8 -- import Debug.Trace
9
10 import Data.Generics hiding (typeOf)
11 import Data.Generics.Schemes
12
13 data TypedExpr = TypedExpr
14         { unTypeExpr    :: Expr
15         , typeOf        :: Typ
16         } deriving (Eq, Typeable, Data)
17
18 typedLeft, typedRight :: Expr -> Typ -> TypedExpr
19 typedLeft  e t = TypedExpr e (instType False t)
20 typedRight e t = TypedExpr e (instType True t)
21
22 data EVar = F
23           | FromTypVar Int
24           | FromParam Int Bool
25             deriving (Eq, Typeable, Data)
26
27 data Expr
28         = Var EVar
29         | App Expr Expr
30         | Conc [Expr] -- Conc [] is Id
31         | Lambda Expr Expr
32         | Pair Expr Expr
33         | Map
34         | Const Expr
35         | ELeft Expr
36         | ERight Expr
37         | CaseUnit Expr Expr
38         | EitherMap
39         | EUnit
40         | Bottom
41             deriving (Eq, Typeable, Data)
42
43 data LambdaBE = CurriedEquals Typ
44               | LambdaBE TypedExpr TypedExpr BoolExpr
45             deriving (Eq, Typeable, Data)
46
47 data BoolExpr 
48         = Equal Expr Expr
49         | And [BoolExpr] -- And [] is True
50         | AllZipWith LambdaBE Expr Expr
51         | AndEither  LambdaBE LambdaBE Expr Expr
52         | Condition [TypedExpr] BoolExpr BoolExpr
53         | UnpackPair TypedExpr TypedExpr TypedExpr BoolExpr
54         | TypeVarInst Bool Int BoolExpr
55             deriving (Eq, Typeable, Data)
56
57 -- Smart constructors
58
59 -- | Try eta reduction
60 equal :: TypedExpr -> TypedExpr -> BoolExpr
61 equal te1 te2 | typeOf te1 /= typeOf te2 = error "Type mismatch in equal"
62               | otherwise                = equal' (unTypeExpr te1) (unTypeExpr te2)
63
64 equal' :: Expr -> Expr -> BoolExpr
65 equal' e1 e2  | (Just (lf,lv)) <- isFunctionApplication e1
66               , (Just (rf,rv)) <- isFunctionApplication e2
67               , lv == rv 
68               , False
69                                          = equal' lf rf
70               -- This makes it return True...
71               | e1 == e2                 = beTrue
72               | otherwise                = Equal e1 e2
73
74 -- | If e is of the type (app f1 (app f2 .. (app fn x)..)),
75 --   return Just (f1 . f2. ... . fn, x)
76 isFunctionApplication :: Expr -> Maybe (Expr, Expr)
77 isFunctionApplication (App f e') | (Just (inner,v)) <- isFunctionApplication e'
78                                  = Just (conc f inner, v)
79                                  | otherwise
80                                  = Just (f, e')
81 isFunctionApplication _          = Nothing
82
83
84 -- | If both bound variables are just functions, we can replace this
85 --   by a comparison
86 unpackPair :: TypedExpr -> TypedExpr -> TypedExpr -> BoolExpr -> BoolExpr
87 unpackPair v1 v2 te be | Just subst1 <- findReplacer v1 be
88                        , Just subst2 <- findReplacer v2 be
89                        = subst1. subst2 $ (pair v1 v2 `equal` te) `aand` be
90
91 -- | If the whole tuple is a function, we can replace this
92 --   by a comparison
93 unpackPair v1 v2 te be | Just subst <- findReplacer (pair v1 v2) be
94                        = subst $ (pair v1 v2 `equal` te) `aand` be
95
96 -- | Nothing to optimize
97 unpackPair v1 v2 te be = UnpackPair v1 v2 te be
98
99 pair :: TypedExpr -> TypedExpr -> TypedExpr
100 pair (TypedExpr e1 t1) (TypedExpr e2 t2) = TypedExpr (Pair e1 e2) (TPair t1 t2)
101
102 lambdaBE :: TypedExpr -> TypedExpr -> BoolExpr -> LambdaBE
103 lambdaBE v1 v2 rel | typeOf v1 == typeOf v2 
104                    , rel == v1 `equal` v2    = CurriedEquals (typeOf v1)
105                    | otherwise               = LambdaBE v1 v2 rel
106
107 andEither :: LambdaBE -> LambdaBE -> TypedExpr -> TypedExpr -> BoolExpr
108 andEither (CurriedEquals _) (CurriedEquals _) e1 e2 = e1 `equal` e2
109 andEither lbe1 lbe2 e1 e2 | Just f1 <- arg1IsFunc lbe1
110                           , Just f2 <- arg1IsFunc lbe2
111                           = e1 `equal` eitherE f1 f2 e2
112                           | Just f1 <- arg2IsFunc lbe1
113                           , Just f2 <- arg2IsFunc lbe2
114                           = eitherE f1 f2 e1 `equal` e2
115                           | otherwise
116                           = andEither' lbe1 lbe2 (unTypeExpr e1) (unTypeExpr e2)
117
118 andEither' :: LambdaBE -> LambdaBE -> Expr -> Expr -> BoolExpr
119 andEither' (LambdaBE v1 v2 rel) _ (ELeft e1) (ELeft e2)
120        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
121 andEither' _ (LambdaBE v1 v2 rel) (ERight e1) (ERight e2)
122        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
123 andEither' lbe1 lbe2 e1 e2
124        = AndEither lbe1 lbe2 e1 e2
125
126
127 arg1IsFunc :: LambdaBE -> Maybe TypedExpr
128 arg1IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
129 arg1IsFunc (LambdaBE v1 v2 rel) | Just v1' <- defFor v1 rel
130                                 = Just (lambda v2 v1')
131                                 | otherwise = Nothing
132
133 arg2IsFunc :: LambdaBE -> Maybe TypedExpr
134 arg2IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
135 arg2IsFunc (LambdaBE v1 v2 rel) | Just v2' <- defFor v2 rel
136                                 = Just (lambda v1 v2')
137                                 | otherwise = Nothing
138
139 allZipWith :: TypedExpr -> TypedExpr -> BoolExpr -> TypedExpr -> TypedExpr -> BoolExpr
140 allZipWith v1 v2 rel e1 e2 | Just v1' <- defFor v1 rel =
141                                 e1 `equal` amap (lambda v2 v1') e2
142                            | Just v2' <- defFor v2 rel =
143                                 amap (lambda v1 v2') e1 `equal` e2
144                            | otherwise =
145                                 AllZipWith (LambdaBE v1 v2 rel) (unTypeExpr e1) (unTypeExpr e2)
146
147 eitherE :: TypedExpr -> TypedExpr -> TypedExpr -> TypedExpr
148 eitherE f1 f2 e | Arrow lt1 lt2 <- typeOf f1
149                 , Arrow rt1 rt2 <- typeOf f2
150                 , TEither lt rt <- typeOf e
151                 , lt1 == lt
152                 , rt1 == rt
153         = let tEither = TypedExpr EitherMap (Arrow (typeOf f1) (Arrow (typeOf f2) (Arrow (typeOf e) (TEither lt2 rt2))))
154           in  app (app (app tEither f1) f2) e
155                 | otherwise = error $ "Type error in eitherE\n" ++ show (f1, f2, e)
156
157 amap :: TypedExpr -> TypedExpr -> TypedExpr
158 amap tf tl | Arrow t1 t2 <- typeOf tf
159            , List t      <- typeOf tl
160            , t1 == t
161            = let tMap = TypedExpr Map (Arrow (Arrow t1 t2) (Arrow (List t1) (List t2)))
162              in app (app tMap tf) tl
163            | otherwise = error "Type error in map"
164
165 aand :: BoolExpr -> BoolExpr -> BoolExpr
166 aand (And xs) (And ys) = And (xs  ++ ys)
167 aand (And xs) y        = And (xs  ++ [y])
168 aand x        (And ys) = And ([x] ++ ys)
169 aand x        y        = And ([x,y])
170
171 beTrue :: BoolExpr
172 beTrue = And []
173
174 -- | Optimize a forall condition
175 condition :: [TypedExpr] -> BoolExpr -> BoolExpr -> BoolExpr
176 -- empty condition
177 condition [] cond concl   | cond == beTrue
178                           = concl
179 -- float out conditions on the right
180 condition vars cond (Condition vars' cond' concl')
181                           = condition (vars ++ vars') (cond `aand` cond') concl'
182
183 -- Try to find variables that are functions of other variables, and remove them
184 condition vars cond concl | True -- set to false to disable
185                           , ((vars',cond',concl'):_) <- mapMaybe try vars
186                           = condition vars' cond' concl'
187               -- A variable which can be replaced
188   where try v | Just subst <- findReplacer v cond
189               = -- trace ("Tested " ++ show v ++ ", can be replaced") $
190                 Just (delete v vars, subst cond, subst concl)
191  
192               -- A variable with can be removed
193               | not (unTypeExpr v `occursIn` cond || unTypeExpr v `occursIn` concl)
194               = -- trace ("Tested " ++ show v ++ ", can be reased") $
195                 Just (delete v vars, cond, concl)
196
197               -- Nothing to do with this variable
198               | otherwise
199               = -- trace ("Tested " ++ show v ++ " without success") $
200                 Nothing
201
202 -- Nothing left to optizmize
203 condition vars cond concl = Condition vars cond concl
204
205
206 caseUnit Bottom e = Bottom
207 caseUnit EUnit e  = e
208 caseUnit v e      = CaseUnit v e
209
210 -- | Replaces a Term in a BoolExpr
211 replaceTermBE :: Expr -> Expr -> BoolExpr -> BoolExpr
212 replaceTermBE d r = go
213   where go (e1 `Equal` e2) | d == e1 && r == e2 = beTrue
214                            | d == e2 && r == e1 = beTrue
215                            | otherwise          = go' e1 `equal'` go' e2
216         go (And es)        = foldr aand beTrue (map go es)
217         go (AllZipWith lbe e1 e2) 
218                            = AllZipWith (goL lbe) (go' e1) (go' e2)
219         go (AndEither lbe1 lbe2 e1 e2)
220                            = andEither' (goL lbe1) (goL lbe2) (go' e1) (go' e2)
221         go (Condition vs cond concl)
222                            = condition vs (go cond) (go concl)
223         go (UnpackPair v1 v2 e be)
224                            = unpackPair v1 v2 (goT e) (go be)
225         go (TypeVarInst _ _ _) = error "TypeVarInst not expected here"
226
227         go' = replaceExpr d r
228
229         goT te = te { unTypeExpr = go' (unTypeExpr te) }
230
231         goL (CurriedEquals t)   = (CurriedEquals t)
232         goL (LambdaBE v1 v2 be) = lambdaBE v1 v2 (go be)
233
234
235 replaceExpr :: Expr -> Expr -> Expr -> Expr
236 replaceExpr d r = go
237   where go e | e == d    = r
238         go (App e1 e2)   = app' (go e1) (go e2)
239         go (Conc es)     = foldr conc (Conc []) (map go es)
240         go (Lambda v e)  = lambda' v (go e)
241         go (Pair e1 e2)  = Pair (go e1) (go e2)
242         go (Const e)     = Const (go e)
243         go (CaseUnit v e)= caseUnit (go v) (go e)
244         go e             = e
245
246
247 -- | Is inside the term a definition for the variable?
248 findReplacer :: TypedExpr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
249 findReplacer tv be = findReplacer' (unTypeExpr tv) be
250         
251 -- | Find a definition, and return a substitution
252 findReplacer' :: Expr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
253 -- For combined types, look up the components
254 findReplacer' (Pair x y) e | Just (delX) <- findReplacer' x e
255                            , Just (delY) <- findReplacer' y e
256                     = Just (delX . delY)
257 -- Find the definition
258 findReplacer' e (e1 `Equal` e2) | e == e1    = Just (replaceTermBE e e2)
259                                 | e == e2    = Just (replaceTermBE e e1)
260 findReplacer' e (And es)        = listToMaybe (mapMaybe (findReplacer' e) es)
261                                   -- assuming no two definitions can exist
262 findReplacer' _ _               = Nothing
263
264 -- | Is inside the term a definition for the variable?
265 defFor :: TypedExpr -> BoolExpr -> Maybe (TypedExpr)
266 defFor tv be | Just (e') <- defFor' (unTypeExpr tv) be
267                          = Just (TypedExpr e' (typeOf tv))
268              | otherwise = Nothing
269         
270 -- | Find a definition, and return it along the definition remover
271 defFor' :: Expr -> BoolExpr -> Maybe (Expr)
272 defFor' e (e1 `Equal` e2) | e == e1                 = Just (e2)
273                           | e == e2                 = Just (e1)
274 defFor' e (And es)        | [d]  <- mapMaybe (defFor' e) es -- exactly one definition
275                                                     = Just d
276 defFor' _ _                                         = Nothing
277
278 app :: TypedExpr -> TypedExpr -> TypedExpr
279 app te1 te2 | Arrow t1 t2 <- typeOf te1
280             , t3          <- typeOf te2 
281             , t1 == t3 
282             = TypedExpr (app' (unTypeExpr te1) (unTypeExpr te2)) t2
283 app te1 te2 | otherwise                          = error $ "Type mismatch in app: " ++
284                                                            show te1 ++ " " ++ show te2
285
286 app' :: Expr -> Expr -> Expr
287 app' (App (App EitherMap f1) f2) Bottom     = Bottom
288 app' (App (App EitherMap f1) f2) (ELeft v)  = app' f1 v
289 app' (App (App EitherMap f1) f2) (ERight v) = app' f2 v
290 app' Bottom    _   = Bottom    -- _|_ x = _|_
291 app' (Lambda v e1) (e2) = replaceExpr v e2 e1 -- lambda application
292 app' Map (Conc []) = Conc []   -- map id = id
293 app' (Const e) _   = e         -- const x y = x
294 app' (Conc []) v   = v         -- id x   = x
295 app' f v           = App f v
296
297 lambda :: TypedExpr -> TypedExpr -> TypedExpr
298 lambda tv e = TypedExpr (lambda' (unTypeExpr tv) (unTypeExpr e))
299                         (Arrow (typeOf tv) (typeOf e))
300
301 lambda' :: Expr -> Expr -> Expr
302 lambda' v e  | e == EUnit           = Const EUnit
303               | (Just e') <- isApplOn v e
304               , not (v `occursIn` e')
305                                      = e'
306               | v == e   = Conc []
307               | otherwise            = Lambda v e
308
309 conc :: Expr -> Expr -> Expr
310 conc (Lambda v (CaseUnit v' e)) (Conc ((Const EUnit):r))
311                                 | v == v' = conc (Const e) (Conc r)
312 conc (Lambda v (CaseUnit v' e)) (Const EUnit) | v == v' = Const e
313 conc (Conc xs) (Conc ys)        = Conc (xs  ++ ys)
314 conc (Conc xs)  y               = Conc (xs  ++ [y])
315 conc x         (Conc ys)        = Conc ([x] ++ ys)
316 conc x          y               = Conc ([x,y])
317
318
319 -- Specialization of g'
320
321 specialize :: BoolExpr -> BoolExpr
322 specialize (TypeVarInst strict i be') = 
323                 replaceTermBE (Var (FromTypVar i)) (if strict then Conc [] else Const EUnit) .
324                 everywhere (mkT $ go) $
325                 be
326         where be = specialize be'
327               go (TypInst i' _) | i' == i = TUnit
328               go tv                       = tv                 
329 -- No need to go further once we are through the quantors
330 specialize be = be
331
332 -- Helpers
333
334 isApplOn :: Expr -> Expr -> Maybe Expr
335 isApplOn e e'         | e == e'                       = Nothing
336 isApplOn e (App f e') | e == e'                       = Just (Conc [f])
337 isApplOn e (App f e') | (Just inner) <- isApplOn e e' = Just (conc f inner)
338 isApplOn _ _                                          = Nothing
339
340 occursIn :: (Typeable a, Data a1, Eq a) => a -> a1 -> Bool
341 e `occursIn` e'       = not (null (listify (==e) e'))
342
343 isTuple :: Typ -> Bool
344 isTuple (TPair _ _) = True
345 isTuple _           = False
346
347
348 -- showing
349
350 -- Precedences:
351 -- 10 fun app
352 --  9 (.)
353 --  8 ==
354 --  7 ==>
355 --  6 forall
356
357 instance Show EVar where
358         show F               = "f"
359         show (FromTypVar i)  = "g" ++ show i
360         show (FromParam i b) = "x" ++ show i ++ if b then "'" else ""
361
362
363 instance Show Expr where
364         showsPrec _ (Var v)     = showsPrec 11 v
365         showsPrec d (App e1 e2) = showParen (d>10) $
366                 showsPrec 10 e1 . showChar ' ' . showsPrec 11 e2
367         showsPrec _ (Conc [])   = showString "id"
368         showsPrec d (Conc [e])  = showsPrec d e
369         showsPrec d (Conc es)   = showParen (d>9) $
370                 showIntercalate (showString " . ") (map (showsPrec 10) es)
371         showsPrec _ (Lambda v e)  = showParen True $ 
372                                     showString "\\" .
373                                     showsPrec 11 v .
374                                     showString " -> ".
375                                     showsPrec 0 e 
376         showsPrec _ (Pair e1 e2) = showParen True $ 
377                                    showsPrec 0 e1 .
378                                    showString "," .
379                                    showsPrec 0 e2
380         showsPrec _ EUnit         = showString "()"
381         showsPrec _ Map           = showString "map"
382         showsPrec d (ELeft e)     = showParen (d>10) $ 
383                                         showString "Left ".
384                                         showsPrec 11 e
385         showsPrec d (ERight e)    = showParen (d>10) $ 
386                                         showString "Right ".
387                                         showsPrec 11 e
388         showsPrec d (Const e)     = showParen (d>10) $ showString "const ".showsPrec 11 e
389         showsPrec d (CaseUnit t1 t2) = showParen (d>5) $
390                                         showString "case " .
391                                         showsPrec 0 t1 .
392                                         showString " of () ->  " .
393                                         showsPrec 11 t2
394         showsPrec _ EitherMap     = showString "eitherMap"
395         showsPrec _ Bottom        = showString "_|_"
396
397 showIntercalate :: ShowS -> [ShowS] -> ShowS
398 showIntercalate _ []  = id
399 showIntercalate _ [x] = x
400 showIntercalate i (x:xs) = x . i . showIntercalate i xs
401
402 instance Show TypedExpr where
403         showsPrec d (TypedExpr e t) = 
404                 showParen (d>10) $
405                         showsPrec 0 e .
406                         showString " :: " .
407                         showString (showTypePrec 0 t)
408
409 instance Show LambdaBE where
410         show (CurriedEquals _) = 
411                         "(==)"
412         show (LambdaBE v1 v2 be) = 
413                         "(" ++
414                         "\\" ++
415                         showsPrec 11 (unTypeExpr v1) "" ++
416                         " " ++
417                         showsPrec 11 (unTypeExpr v2) "" ++
418                         " -> " ++
419                         show be ++
420                         ")"
421
422 instance Show BoolExpr where
423         show (Equal e1 e2) = showsPrec 9 e1 $
424                              showString " == " $
425                              showsPrec 9 e2 ""
426         show (And [])      = "True"
427         show (And bes)     = intercalate " && " $ map show bes
428         show (AllZipWith lbe e1 e2) =
429                         "allZipWith " ++
430                         show lbe ++
431                         " " ++
432                         showsPrec 11 e1 "" ++
433                         " " ++
434                         showsPrec 11 e2 ""
435         show (AndEither lbe1 lbe2 e1 e2) =
436                         "andEither " ++
437                         show lbe1 ++
438                         " " ++
439                         show lbe2 ++
440                         " " ++
441                         showsPrec 11 e1 "" ++
442                         " " ++
443                         showsPrec 11 e2 ""
444         show (Condition tvars be1 be2) = 
445                         "forall " ++
446                         intercalate ", " (map show tvars) ++
447                         ".\n" ++
448                         (if be1 /= beTrue then indent 2 (show be1) ++ "==>\n" else "") ++
449                         indent 2 (show be2)
450         show (UnpackPair v1 v2 e be) = 
451                         "let (" ++
452                         showsPrec 0 v1 "" ++
453                         "," ++
454                         showsPrec 0 v2 "" ++
455                         ") = " ++
456                         showsPrec 0 e "" ++
457                         " in\n" ++
458                         indent 2 (show be)
459         show (TypeVarInst strict i be) = 
460                         "forall types t" ++
461                         show (2*i-1) ++
462                         ", t" ++
463                         show (2*i) ++
464                         ", " ++
465                         (if strict then "strict " else "(strict) ") ++
466                         "functions g" ++
467                         show i ++
468                         " :: t" ++
469                         show (2*i-1) ++
470                         " -> t" ++
471                         show (2*i) ++ 
472                         ".\n" ++
473                         indent 2 (show be)
474
475 indent :: Int -> String -> String
476 indent n = unlines . map (replicate n ' ' ++) . lines
477
478 showTypePrec :: Int -> Typ -> String
479 showTypePrec _ Int                          = "Int" 
480 showTypePrec _ (TVar (TypVar i))            = "a"++show i
481 showTypePrec _ (TVar (TypInst i b)) | not b = "t" ++  show (2*i-1)
482                                     |     b = "t" ++  show (2*i)
483 showTypePrec _ (TVar (TUnit))               = "()"
484 showTypePrec d (Arrow t1 t2)                = paren (d>9) $ 
485                                                 showTypePrec 10 t1 ++
486                                                 " -> " ++
487                                                 showTypePrec 9 t2 
488 showTypePrec _ (List t)                     = "[" ++ showTypePrec 0 t ++ "]"
489 showTypePrec _ (TEither t1 t2)              = "Either " ++ showTypePrec 11 t1 ++ 
490                                                     " " ++ showTypePrec 11 t2
491 showTypePrec _ (TPair t1 t2)                = "(" ++ showTypePrec 0 t1 ++
492                                               "," ++ showTypePrec 0 t2 ++ ")"
493 showTypePrec _ t                            = error $ "Did not expect to show " ++ show t
494
495 paren :: Bool -> String -> String
496 paren b p   =  if b then "(" ++ p ++ ")" else p