Correctly insert terms even with scoping (I hope)
[darcs-mirror-polyfix.git] / Expr.hs
1 {-# LANGUAGE PatternGuards, DeriveDataTypeable   #-}
2 module Expr where
3
4 import Data.List
5 import Data.Maybe
6 import ParseType
7
8 -- import Debug.Trace
9
10 import Data.Generics hiding (typeOf)
11 import Data.Generics.Schemes
12
13 data TypedExpr = TypedExpr
14         { unTypeExpr    :: Expr
15         , typeOf        :: Typ
16         } deriving (Eq, Typeable, Data)
17
18 typedLeft, typedRight :: Expr -> Typ -> TypedExpr
19 typedLeft  e t = TypedExpr e (instType False t)
20 typedRight e t = TypedExpr e (instType True t)
21
22 data EVar = F
23           | FromTypVar Int
24           | FromParam Int Bool
25             deriving (Eq, Typeable, Data)
26
27 data Expr
28         = Var EVar
29         | App Expr Expr
30         | Conc [Expr] -- Conc [] is Id
31         | Lambda Expr Expr
32         | Pair Expr Expr
33         | Map
34         | Const Expr
35         | ELeft Expr
36         | ERight Expr
37         | CaseUnit Expr Expr
38         | EitherMap
39         | HeadMap
40         | EUnit
41         | Singleton Expr
42         | Zero
43         | Bottom
44             deriving (Eq, Typeable, Data)
45
46 data LambdaBE = CurriedEquals Typ
47               | LambdaBE TypedExpr TypedExpr BoolExpr
48             deriving (Eq, Typeable, Data)
49
50 data BoolExpr 
51         = Equal Expr Expr
52         | And [BoolExpr] -- And [] is True
53         | AllZipWith LambdaBE Expr Expr
54         | AndEither  LambdaBE LambdaBE Expr Expr
55         | Condition [TypedExpr] BoolExpr BoolExpr
56         | UnpackPair TypedExpr TypedExpr TypedExpr BoolExpr
57         | TypeVarInst Bool Int BoolExpr
58             deriving (Eq, Typeable, Data)
59
60 -- Smart constructors
61
62 -- | Try eta reduction
63 equal :: TypedExpr -> TypedExpr -> BoolExpr
64 equal te1 te2 | typeOf te1 /= typeOf te2 = error "Type mismatch in equal"
65               | otherwise                = equal' (unTypeExpr te1) (unTypeExpr te2)
66
67 equal' :: Expr -> Expr -> BoolExpr
68 equal' e1 e2  | (Just (lf,lv)) <- isFunctionApplication e1
69               , (Just (rf,rv)) <- isFunctionApplication e2
70               , lv == rv 
71               , False
72                                          = equal' lf rf
73               -- This makes it return True...
74               | e1 == e2                 = beTrue
75               | otherwise                = Equal e1 e2
76
77 -- | If e is of the type (app f1 (app f2 .. (app fn x)..)),
78 --   return Just (f1 . f2. ... . fn, x)
79 isFunctionApplication :: Expr -> Maybe (Expr, Expr)
80 isFunctionApplication (App f e') | (Just (inner,v)) <- isFunctionApplication e'
81                                  = Just (conc f inner, v)
82                                  | otherwise
83                                  = Just (f, e')
84 isFunctionApplication _          = Nothing
85
86
87 -- | If both bound variables are just functions, we can replace this
88 --   by a comparison
89 unpackPair :: TypedExpr -> TypedExpr -> TypedExpr -> BoolExpr -> BoolExpr
90 unpackPair v1 v2 te be | Just subst1 <- findReplacer v1 be
91                        , Just subst2 <- findReplacer v2 be
92                        = subst1. subst2 $ (pair v1 v2 `equal` te) `aand` be
93
94 -- | If the whole tuple is a function, we can replace this
95 --   by a comparison
96 unpackPair v1 v2 te be | Just subst <- findReplacer (pair v1 v2) be
97                        = subst $ (pair v1 v2 `equal` te) `aand` be
98
99 -- | Nothing to optimize
100 unpackPair v1 v2 te be = UnpackPair v1 v2 te be
101
102 pair :: TypedExpr -> TypedExpr -> TypedExpr
103 pair (TypedExpr e1 t1) (TypedExpr e2 t2) = TypedExpr (Pair e1 e2) (TPair t1 t2)
104
105 lambdaBE :: TypedExpr -> TypedExpr -> BoolExpr -> LambdaBE
106 lambdaBE v1 v2 rel | typeOf v1 == typeOf v2 
107                    , rel == v1 `equal` v2    = CurriedEquals (typeOf v1)
108                    | otherwise               = LambdaBE v1 v2 rel
109
110 andEither :: LambdaBE -> LambdaBE -> TypedExpr -> TypedExpr -> BoolExpr
111 andEither (CurriedEquals _) (CurriedEquals _) e1 e2 = e1 `equal` e2
112 andEither lbe1 lbe2 e1 e2 | Just f1 <- arg1IsFunc lbe1
113                           , Just f2 <- arg1IsFunc lbe2
114                           = e1 `equal` eitherE f1 f2 e2
115                           | Just f1 <- arg2IsFunc lbe1
116                           , Just f2 <- arg2IsFunc lbe2
117                           = eitherE f1 f2 e1 `equal` e2
118                           | otherwise
119                           = andEither' lbe1 lbe2 (unTypeExpr e1) (unTypeExpr e2)
120
121 andEither' :: LambdaBE -> LambdaBE -> Expr -> Expr -> BoolExpr
122 andEither' (LambdaBE v1 v2 rel) _ (ELeft e1) (ELeft e2)
123        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
124 andEither' _ (LambdaBE v1 v2 rel) (ERight e1) (ERight e2)
125        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
126 andEither' lbe1 lbe2 e1 e2
127        = AndEither lbe1 lbe2 e1 e2
128
129
130 arg1IsFunc :: LambdaBE -> Maybe TypedExpr
131 arg1IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
132 arg1IsFunc (LambdaBE v1 v2 rel) | Just v1' <- defFor v1 rel
133                                 = Just (lambda v2 v1')
134                                 | otherwise = Nothing
135
136 arg2IsFunc :: LambdaBE -> Maybe TypedExpr
137 arg2IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
138 arg2IsFunc (LambdaBE v1 v2 rel) | Just v2' <- defFor v2 rel
139                                 = Just (lambda v1 v2')
140                                 | otherwise = Nothing
141
142 allZipWith :: TypedExpr -> TypedExpr -> BoolExpr -> TypedExpr -> TypedExpr -> BoolExpr
143 allZipWith v1 v2 rel e1 e2 | Just v1' <- defFor v1 rel =
144                                 e1 `equal` amap (lambda v2 v1') e2
145                            | Just v2' <- defFor v2 rel =
146                                 amap (lambda v1 v2') e1 `equal` e2
147                            | otherwise =
148                                 AllZipWith (LambdaBE v1 v2 rel) (unTypeExpr e1) (unTypeExpr e2)
149
150 eitherE :: TypedExpr -> TypedExpr -> TypedExpr -> TypedExpr
151 eitherE f1 f2 e | Arrow lt1 lt2 <- typeOf f1
152                 , Arrow rt1 rt2 <- typeOf f2
153                 , TEither lt rt <- typeOf e
154                 , lt1 == lt
155                 , rt1 == rt
156         = let tEither = TypedExpr EitherMap (Arrow (typeOf f1) (Arrow (typeOf f2) (Arrow (typeOf e) (TEither lt2 rt2))))
157           in  app (app (app tEither f1) f2) e
158                 | otherwise = error $ "Type error in eitherE\n" ++ show (f1, f2, e)
159
160 amap :: TypedExpr -> TypedExpr -> TypedExpr
161 amap tf tl | Arrow t1 t2 <- typeOf tf
162            , List t      <- typeOf tl
163            , t1 == t
164            = let tMap = TypedExpr Map (Arrow (Arrow t1 t2) (Arrow (List t1) (List t2)))
165              in app (app tMap tf) tl
166            | otherwise = error "Type error in map"
167
168 aand :: BoolExpr -> BoolExpr -> BoolExpr
169 aand (And xs) (And ys) = And (xs  ++ ys)
170 aand (And xs) y        = And (xs  ++ [y])
171 aand x        (And ys) = And ([x] ++ ys)
172 aand x        y        = And ([x,y])
173
174 beTrue :: BoolExpr
175 beTrue = And []
176
177 -- | Optimize a forall condition
178 condition :: [TypedExpr] -> BoolExpr -> BoolExpr -> BoolExpr
179 -- empty condition
180 condition [] cond concl   | cond == beTrue
181                           = concl
182 -- float out conditions on the right
183 condition vars cond (Condition vars' cond' concl')
184                           = condition (vars ++ vars') (cond `aand` cond') concl'
185
186 -- Try to find variables that are functions of other variables, and remove them
187 condition vars cond concl | True -- set to false to disable
188                           , ((vars',cond',concl'):_) <- mapMaybe try vars
189                           = condition vars' cond' concl'
190               -- A variable which can be replaced
191   where try v | Just subst <- findReplacer v cond
192               = -- trace ("Tested " ++ show v ++ ", can be replaced") $
193                 Just (delete v vars, subst cond, subst concl)
194  
195               -- A variable with can be removed
196               | not (unTypeExpr v `occursIn` cond || unTypeExpr v `occursIn` concl)
197               = -- trace ("Tested " ++ show v ++ ", can be reased") $
198                 Just (delete v vars, cond, concl)
199
200               -- Nothing to do with this variable
201               | otherwise
202               = -- trace ("Tested " ++ show v ++ " without success") $
203                 Nothing
204
205 -- Nothing left to optizmize
206 condition vars cond concl = Condition vars cond concl
207
208
209 caseUnit Bottom e = Bottom
210 caseUnit EUnit e  = e
211 caseUnit v e      = CaseUnit v e
212
213 -- | Replaces a Term in a BoolExpr
214 replaceTermBE :: Expr -> Expr -> BoolExpr -> BoolExpr
215 replaceTermBE d r = go
216   where go (e1 `Equal` e2) | d == e1 && r == e2 = beTrue
217                            | d == e2 && r == e1 = beTrue
218                            | otherwise          = go' e1 `equal'` go' e2
219         go (And es)        = foldr aand beTrue (map go es)
220         go (AllZipWith lbe e1 e2) 
221                            = AllZipWith (goL lbe) (go' e1) (go' e2)
222         go (AndEither lbe1 lbe2 e1 e2)
223                            = andEither' (goL lbe1) (goL lbe2) (go' e1) (go' e2)
224         go c@(Condition vs cond concl) -- shadowed definition
225                            | d `elem` map unTypeExpr vs 
226                            = c
227         go (Condition vs cond concl)
228                            = condition vs (go cond) (go concl)
229         go (UnpackPair v1 v2 e be)
230                            = unpackPair v1 v2 (goT e) (go be)
231         go (TypeVarInst _ _ _) = error "TypeVarInst not expected here"
232
233         go' = replaceExpr d r
234
235         goT te = te { unTypeExpr = go' (unTypeExpr te) }
236
237         goL (CurriedEquals t)   = (CurriedEquals t)
238         goL (LambdaBE v1 v2 be) = lambdaBE v1 v2 (go be)
239
240
241 replaceExpr :: Expr -> Expr -> Expr -> Expr
242 replaceExpr d r = go
243   where go e | e == d    = r
244         go (App e1 e2)   = app' (go e1) (go e2)
245         go (Conc es)     = foldr conc (Conc []) (map go es)
246         go (Lambda v e)  = lambda' v (go e)
247         go (Pair e1 e2)  = Pair (go e1) (go e2)
248         go (Const e)     = Const (go e)
249         go (CaseUnit v e)= caseUnit (go v) (go e)
250         go e             = e
251
252
253 -- | Is inside the term a definition for the variable?
254 findReplacer :: TypedExpr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
255 findReplacer tv be = findReplacer' (unTypeExpr tv) be
256         
257 -- | Find a definition, and return a substitution
258 findReplacer' :: Expr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
259 -- For combined types, look up the components
260 findReplacer' (Pair x y) e | Just (delX) <- findReplacer' x e
261                            , Just (delY) <- findReplacer' y e
262                     = Just (delX . delY)
263 -- Find the definition
264 findReplacer' e (e1 `Equal` e2) | e == e1    = Just (replaceTermBE e e2)
265                                 | e == e2    = Just (replaceTermBE e e1)
266 findReplacer' e (And es)        = listToMaybe (mapMaybe (findReplacer' e) es)
267                                   -- assuming no two definitions can exist
268 findReplacer' _ _               = Nothing
269
270 -- | Is inside the term a definition for the variable?
271 defFor :: TypedExpr -> BoolExpr -> Maybe (TypedExpr)
272 defFor tv be | Just (e') <- defFor' (unTypeExpr tv) be
273                          = Just (TypedExpr e' (typeOf tv))
274              | otherwise = Nothing
275         
276 -- | Find a definition, and return it along the definition remover
277 defFor' :: Expr -> BoolExpr -> Maybe (Expr)
278 defFor' e (e1 `Equal` e2) | e == e1                 = Just (e2)
279                           | e == e2                 = Just (e1)
280 defFor' e (And es)        | [d]  <- mapMaybe (defFor' e) es -- exactly one definition
281                                                     = Just d
282 defFor' _ _                                         = Nothing
283
284 app :: TypedExpr -> TypedExpr -> TypedExpr
285 app te1 te2 | Arrow t1 t2 <- typeOf te1
286             , t3          <- typeOf te2 
287             , t1 == t3 
288             = TypedExpr (app' (unTypeExpr te1) (unTypeExpr te2)) t2
289 app te1 te2 | otherwise                          = error $ "Type mismatch in app: " ++
290                                                            show te1 ++ " " ++ show te2
291
292 app' :: Expr -> Expr -> Expr
293 app' (App HeadMap f) Bottom                 = Bottom
294 app' (App HeadMap f) (Singleton e)          = app' f e
295 app' (App (App EitherMap f1) f2) Bottom     = Bottom
296 app' (App (App EitherMap f1) f2) (ELeft v)  = app' f1 v
297 app' (App (App EitherMap f1) f2) (ERight v) = app' f2 v
298 app' Bottom    _   = Bottom    -- _|_ x = _|_
299 app' (Lambda v e1) (e2) = replaceExpr v e2 e1 -- lambda application
300 app' Map (Conc []) = Conc []   -- map id = id
301 app' (Const e) _   = e         -- const x y = x
302 app' (Conc []) v   = v         -- id x   = x
303 app' f v           = App f v
304
305 lambda :: TypedExpr -> TypedExpr -> TypedExpr
306 lambda tv e = TypedExpr (lambda' (unTypeExpr tv) (unTypeExpr e))
307                         (Arrow (typeOf tv) (typeOf e))
308
309 lambda' :: Expr -> Expr -> Expr
310 lambda' v e  | e == EUnit           = Const EUnit
311               | (Just e') <- isApplOn v e
312               , not (v `occursIn` e')
313                                      = e'
314               | v == e   = Conc []
315               | otherwise            = Lambda v e
316
317 conc :: Expr -> Expr -> Expr
318 conc (Lambda v (CaseUnit v' e)) (Conc ((Const EUnit):r))
319                                 | v == v' = conc (Const e) (Conc r)
320 conc (Lambda v (CaseUnit v' e)) (Const EUnit) | v == v' = Const e
321 conc (Conc xs) (Conc ys)        = Conc (xs  ++ ys)
322 conc (Conc xs)  y               = Conc (xs  ++ [y])
323 conc x         (Conc ys)        = Conc ([x] ++ ys)
324 conc x          y               = Conc ([x,y])
325
326
327 -- Specialization of g'
328
329 specialize :: BoolExpr -> BoolExpr
330 specialize (TypeVarInst strict i be') = 
331                 replaceTermBE (Var (FromTypVar i)) (if strict then Conc [] else Const EUnit) .
332                 everywhere (mkT $ go) $
333                 be
334         where be = specialize be'
335               go (TypInst i' _) | i' == i = TUnit
336               go tv                       = tv                 
337 -- No need to go further once we are through the quantors
338 specialize be = be
339
340 -- Helpers
341
342 isApplOn :: Expr -> Expr -> Maybe Expr
343 isApplOn e e'         | e == e'                       = Nothing
344 isApplOn e (App f e') | e == e'                       = Just (Conc [f])
345 isApplOn e (App f e') | (Just inner) <- isApplOn e e' = Just (conc f inner)
346 isApplOn _ _                                          = Nothing
347
348 occursIn :: (Typeable a, Data a1, Eq a) => a -> a1 -> Bool
349 e `occursIn` e'       = not (null (listify (==e) e'))
350
351 isTuple :: Typ -> Bool
352 isTuple (TPair _ _) = True
353 isTuple _           = False
354
355
356 -- showing
357
358 -- Precedences:
359 -- 10 fun app
360 --  9 (.)
361 --  8 ==
362 --  7 ==>
363 --  6 forall
364
365 instance Show EVar where
366         show F               = "f"
367         show (FromTypVar i)  = "g" ++ show i
368         show (FromParam i b) = "x" ++ show i ++ if b then "'" else ""
369
370
371 instance Show Expr where
372         showsPrec _ (Var v)     = showsPrec 11 v
373         showsPrec d (App e1 e2) = showParen (d>10) $
374                 showsPrec 10 e1 . showChar ' ' . showsPrec 11 e2
375         showsPrec _ (Conc [])   = showString "id"
376         showsPrec d (Conc [e])  = showsPrec d e
377         showsPrec d (Conc es)   = showParen (d>9) $
378                 showIntercalate (showString " . ") (map (showsPrec 10) es)
379         showsPrec _ (Lambda v e)  = showParen True $ 
380                                     showString "\\" .
381                                     showsPrec 11 v .
382                                     showString " -> ".
383                                     showsPrec 0 e 
384         showsPrec _ (Pair e1 e2) = showParen True $ 
385                                    showsPrec 0 e1 .
386                                    showString "," .
387                                    showsPrec 0 e2
388         showsPrec _ Zero          = showString "0"
389         showsPrec _ EUnit         = showString "()"
390         showsPrec _ (Singleton e) = showString "[" . showsPrec 0 e . showString "]"
391         showsPrec _ Map           = showString "map"
392         showsPrec d (ELeft e)     = showParen (d>10) $ 
393                                         showString "Left ".
394                                         showsPrec 11 e
395         showsPrec d (ERight e)    = showParen (d>10) $ 
396                                         showString "Right ".
397                                         showsPrec 11 e
398         showsPrec d (Const e)     = showParen (d>10) $ showString "const ".showsPrec 11 e
399         showsPrec d (CaseUnit t1 t2) = showParen (d>5) $
400                                         showString "case " .
401                                         showsPrec 0 t1 .
402                                         showString " of () ->  " .
403                                         showsPrec 11 t2
404         showsPrec _ EitherMap     = showString "eitherMap"
405         showsPrec _ HeadMap       = showString "headMap"
406         showsPrec _ Bottom        = showString "_|_"
407
408 showIntercalate :: ShowS -> [ShowS] -> ShowS
409 showIntercalate _ []  = id
410 showIntercalate _ [x] = x
411 showIntercalate i (x:xs) = x . i . showIntercalate i xs
412
413 instance Show TypedExpr where
414         showsPrec d (TypedExpr e t) = 
415                 showParen (d>10) $
416                         showsPrec 0 e .
417                         showString " :: " .
418                         showString (showTypePrec 0 t)
419
420 instance Show LambdaBE where
421         show (CurriedEquals _) = 
422                         "(==)"
423         show (LambdaBE v1 v2 be) = 
424                         "(" ++
425                         "\\" ++
426                         showsPrec 11 (unTypeExpr v1) "" ++
427                         " " ++
428                         showsPrec 11 (unTypeExpr v2) "" ++
429                         " -> " ++
430                         show be ++
431                         ")"
432
433 instance Show BoolExpr where
434         show (Equal e1 e2) = showsPrec 9 e1 $
435                              showString " == " $
436                              showsPrec 9 e2 ""
437         show (And [])      = "True"
438         show (And bes)     = intercalate " && " $ map show bes
439         show (AllZipWith lbe e1 e2) =
440                         "allZipWith " ++
441                         show lbe ++
442                         " " ++
443                         showsPrec 11 e1 "" ++
444                         " " ++
445                         showsPrec 11 e2 ""
446         show (AndEither lbe1 lbe2 e1 e2) =
447                         "andEither " ++
448                         show lbe1 ++
449                         " " ++
450                         show lbe2 ++
451                         " " ++
452                         showsPrec 11 e1 "" ++
453                         " " ++
454                         showsPrec 11 e2 ""
455         show (Condition tvars be1 be2) = 
456                         "forall " ++
457                         intercalate ", " (map show tvars) ++
458                         ".\n" ++
459                         (if be1 /= beTrue then indent 2 (show be1) ++ "==>\n" else "") ++
460                         indent 2 (show be2)
461         show (UnpackPair v1 v2 e be) = 
462                         "let (" ++
463                         showsPrec 0 v1 "" ++
464                         "," ++
465                         showsPrec 0 v2 "" ++
466                         ") = " ++
467                         showsPrec 0 e "" ++
468                         " in\n" ++
469                         indent 2 (show be)
470         show (TypeVarInst strict i be) = 
471                         "forall types t" ++
472                         show (2*i-1) ++
473                         ", t" ++
474                         show (2*i) ++
475                         ", " ++
476                         (if strict then "strict " else "(strict) ") ++
477                         "functions g" ++
478                         show i ++
479                         " :: t" ++
480                         show (2*i-1) ++
481                         " -> t" ++
482                         show (2*i) ++ 
483                         ".\n" ++
484                         indent 2 (show be)
485
486 indent :: Int -> String -> String
487 indent n = unlines . map (replicate n ' ' ++) . lines
488
489 showTypePrec :: Int -> Typ -> String
490 showTypePrec _ Int                          = "Int" 
491 showTypePrec _ (TVar (TypVar i))            = "a"++show i
492 showTypePrec _ (TVar (TypInst i b)) | not b = "t" ++  show (2*i-1)
493                                     |     b = "t" ++  show (2*i)
494 showTypePrec _ (TVar (TUnit))               = "()"
495 showTypePrec d (Arrow t1 t2)                = paren (d>9) $ 
496                                                 showTypePrec 10 t1 ++
497                                                 " -> " ++
498                                                 showTypePrec 9 t2 
499 showTypePrec _ (List t)                     = "[" ++ showTypePrec 0 t ++ "]"
500 showTypePrec _ (TEither t1 t2)              = "Either " ++ showTypePrec 11 t1 ++ 
501                                                     " " ++ showTypePrec 11 t2
502 showTypePrec _ (TPair t1 t2)                = "(" ++ showTypePrec 0 t1 ++
503                                               "," ++ showTypePrec 0 t2 ++ ")"
504 showTypePrec _ t                            = error $ "Did not expect to show " ++ show t
505
506 paren :: Bool -> String -> String
507 paren b p   =  if b then "(" ++ p ++ ")" else p