6d76000dcf965b82afabcd8f40990ebef4ef37c6
[darcs-mirror-polyfix.git] / Expr.hs
1 {-# LANGUAGE PatternGuards, DeriveDataTypeable   #-}
2 module Expr where
3
4 import Data.List
5 import Data.Maybe
6 import ParseType
7
8 -- import Debug.Trace
9
10 import Data.Generics hiding (typeOf)
11 import Data.Generics.Schemes
12
13 data TypedExpr = TypedExpr
14         { unTypeExpr    :: Expr
15         , typeOf        :: Typ
16         } deriving (Eq, Typeable, Data)
17
18 typedLeft, typedRight :: Expr -> Typ -> TypedExpr
19 typedLeft  e t = TypedExpr e (instType False t)
20 typedRight e t = TypedExpr e (instType True t)
21
22 data EVar = F
23           | FromTypVar Int
24           | FromParam Int Bool
25             deriving (Eq, Typeable, Data)
26
27 data Expr
28         = Var EVar
29         | App Expr Expr
30         | Conc [Expr] -- Conc [] is Id
31         | Lambda TypedExpr Expr
32         | Pair Expr Expr
33         | Map
34         | Const Expr
35         | ELeft Expr
36         | ERight Expr
37         | CaseUnit Expr Expr
38         | EitherMap
39         | EUnit
40         | Bottom
41             deriving (Eq, Typeable, Data)
42
43 data LambdaBE = CurriedEquals Typ
44               | LambdaBE TypedExpr TypedExpr BoolExpr
45             deriving (Eq, Typeable, Data)
46
47 data BoolExpr 
48         = Equal Expr Expr
49         | And [BoolExpr] -- And [] is True
50         | AllZipWith LambdaBE Expr Expr
51         | AndEither  LambdaBE LambdaBE Expr Expr
52         | Condition [TypedExpr] BoolExpr BoolExpr
53         | UnpackPair TypedExpr TypedExpr TypedExpr BoolExpr
54         | TypeVarInst Bool Int BoolExpr
55             deriving (Eq, Typeable, Data)
56
57 -- Smart constructors
58
59 -- | Try eta reduction
60 equal :: TypedExpr -> TypedExpr -> BoolExpr
61 equal te1 te2 | typeOf te1 /= typeOf te2 = error "Type mismatch in equal"
62               | otherwise                = equal' (unTypeExpr te1) (unTypeExpr te2)
63
64 equal' :: Expr -> Expr -> BoolExpr
65 equal' e1 e2  | (Just (lf,lv)) <- isFunctionApplication e1
66               , (Just (rf,rv)) <- isFunctionApplication e2
67               , lv == rv 
68               , False
69                                          = equal' lf rf
70               -- This makes it return True...
71               | e1 == e2                 = beTrue
72               | otherwise                = Equal e1 e2
73
74 -- | If e is of the type (app f1 (app f2 .. (app fn x)..)),
75 --   return Just (f1 . f2. ... . fn, x)
76 isFunctionApplication :: Expr -> Maybe (Expr, Expr)
77 isFunctionApplication (App f e') | (Just (inner,v)) <- isFunctionApplication e'
78                                  = Just (conc f inner, v)
79                                  | otherwise
80                                  = Just (f, e')
81 isFunctionApplication _          = Nothing
82
83
84 -- | If both bound variables are just functions, we can replace this
85 --   by a comparison
86 unpackPair :: TypedExpr -> TypedExpr -> TypedExpr -> BoolExpr -> BoolExpr
87 unpackPair v1 v2 te be | Just subst1 <- findReplacer v1 be
88                        , Just subst2 <- findReplacer v2 be
89                        = subst1. subst2 $ (pair v1 v2 `equal` te) `aand` be
90
91 -- | If the whole tuple is a function, we can replace this
92 --   by a comparison
93 unpackPair v1 v2 te be | Just subst <- findReplacer (pair v1 v2) be
94                        = subst $ (pair v1 v2 `equal` te) `aand` be
95
96 -- | Nothing to optimize
97 unpackPair v1 v2 te be = UnpackPair v1 v2 te be
98
99 pair :: TypedExpr -> TypedExpr -> TypedExpr
100 pair (TypedExpr e1 t1) (TypedExpr e2 t2) = TypedExpr (Pair e1 e2) (TPair t1 t2)
101
102 lambdaBE :: TypedExpr -> TypedExpr -> BoolExpr -> LambdaBE
103 lambdaBE v1 v2 rel | typeOf v1 == typeOf v2 
104                    , rel == v1 `equal` v2    = CurriedEquals (typeOf v1)
105                    | otherwise               = LambdaBE v1 v2 rel
106
107 andEither :: LambdaBE -> LambdaBE -> TypedExpr -> TypedExpr -> BoolExpr
108 andEither (CurriedEquals _) (CurriedEquals _) e1 e2 = e1 `equal` e2
109 andEither lbe1 lbe2 e1 e2 | Just f1 <- arg1IsFunc lbe1
110                           , Just f2 <- arg1IsFunc lbe2
111                           = e1 `equal` eitherE f1 f2 e2
112                           | Just f1 <- arg2IsFunc lbe1
113                           , Just f2 <- arg2IsFunc lbe2
114                           = eitherE f1 f2 e1 `equal` e2
115                           | otherwise
116                           = AndEither lbe1 lbe2 (unTypeExpr e1) (unTypeExpr e2)
117
118 arg1IsFunc :: LambdaBE -> Maybe TypedExpr
119 arg1IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
120 arg1IsFunc (LambdaBE v1 v2 rel) | Just v1' <- defFor v1 rel
121                                 = Just (lambda v2 v1')
122                                 | otherwise = Nothing
123
124 arg2IsFunc :: LambdaBE -> Maybe TypedExpr
125 arg2IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
126 arg2IsFunc (LambdaBE v1 v2 rel) | Just v2' <- defFor v2 rel
127                                 = Just (lambda v1 v2')
128                                 | otherwise = Nothing
129
130 allZipWith :: TypedExpr -> TypedExpr -> BoolExpr -> TypedExpr -> TypedExpr -> BoolExpr
131 allZipWith v1 v2 rel e1 e2 | Just v1' <- defFor v1 rel =
132                                 e1 `equal` amap (lambda v2 v1') e2
133                            | Just v2' <- defFor v2 rel =
134                                 amap (lambda v1 v2') e1 `equal` e2
135                            | otherwise =
136                                 AllZipWith (LambdaBE v1 v2 rel) (unTypeExpr e1) (unTypeExpr e2)
137
138 eitherE :: TypedExpr -> TypedExpr -> TypedExpr -> TypedExpr
139 eitherE f1 f2 e | Arrow lt1 lt2 <- typeOf f1
140                 , Arrow rt1 rt2 <- typeOf f2
141                 , TEither lt rt <- typeOf e
142                 , lt1 == lt
143                 , rt1 == rt
144         = let tEither = TypedExpr EitherMap (Arrow (typeOf f1) (Arrow (typeOf f2) (Arrow (typeOf e) (TEither lt2 rt2))))
145           in  app (app (app tEither f1) f2) e
146                 | otherwise = error $ "Type error in eitherE\n" ++ show (f1, f2, e)
147
148 amap :: TypedExpr -> TypedExpr -> TypedExpr
149 amap tf tl | Arrow t1 t2 <- typeOf tf
150            , List t      <- typeOf tl
151            , t1 == t
152            = let tMap = TypedExpr Map (Arrow (Arrow t1 t2) (Arrow (List t1) (List t2)))
153              in app (app tMap tf) tl
154            | otherwise = error "Type error in map"
155
156 aand :: BoolExpr -> BoolExpr -> BoolExpr
157 aand (And xs) (And ys) = And (xs  ++ ys)
158 aand (And xs) y        = And (xs  ++ [y])
159 aand x        (And ys) = And ([x] ++ ys)
160 aand x        y        = And ([x,y])
161
162 beTrue :: BoolExpr
163 beTrue = And []
164
165 -- | Optimize a forall condition
166 condition :: [TypedExpr] -> BoolExpr -> BoolExpr -> BoolExpr
167 -- empty condition
168 condition [] cond concl   | cond == beTrue
169                           = concl
170 -- float out conditions on the right
171 condition vars cond (Condition vars' cond' concl')
172                           = condition (vars ++ vars') (cond `aand` cond') concl'
173
174 -- Try to find variables that are functions of other variables, and remove them
175 condition vars cond concl | True -- set to false to disable
176                           , ((vars',cond',concl'):_) <- mapMaybe try vars
177                           = condition vars' cond' concl'
178               -- A variable which can be replaced
179   where try v | Just subst <- findReplacer v cond
180               = -- trace ("Tested " ++ show v ++ ", can be replaced") $
181                 Just (delete v vars, subst cond, subst concl)
182  
183               -- A variable with can be removed
184               | not (unTypeExpr v `occursIn` cond || unTypeExpr v `occursIn` concl)
185               = -- trace ("Tested " ++ show v ++ ", can be reased") $
186                 Just (delete v vars, cond, concl)
187
188               -- Nothing to do with this variable
189               | otherwise
190               = -- trace ("Tested " ++ show v ++ " without success") $
191                 Nothing
192
193 -- Nothing left to optizmize
194 condition vars cond concl = Condition vars cond concl
195
196
197 caseUnit Bottom e = Bottom
198 caseUnit EUnit e  = e
199 caseUnit v e      = CaseUnit v e
200
201 -- | Replaces a Term in a BoolExpr
202 replaceTermBE :: Expr -> Expr -> BoolExpr -> BoolExpr
203 replaceTermBE d r = go
204   where go (e1 `Equal` e2) | d == e1 && r == e2 = beTrue
205                            | d == e2 && r == e1 = beTrue
206                            | otherwise          = go' e1 `equal'` go' e2
207         go (And es)        = foldr aand beTrue (map go es)
208         go (AllZipWith lbe e1 e2) 
209                            = AllZipWith (goL lbe) (go' e1) (go' e2)
210         go (AndEither lbe1 lbe2 e1 e2)
211                            = AndEither (goL lbe1) (goL lbe2) (go' e1) (go' e2)
212         go (Condition vs cond concl)
213                            = condition vs (go cond) (go concl)
214         go (UnpackPair v1 v2 e be)
215                            = unpackPair v1 v2 (goT e) (go be)
216         go (TypeVarInst _ _ _) = error "TypeVarInst not expected here"
217
218         go' = replaceExpr d r
219
220         goT te = te { unTypeExpr = go' (unTypeExpr te) }
221
222         goL (CurriedEquals t)   = (CurriedEquals t)
223         goL (LambdaBE v1 v2 be) = lambdaBE v1 v2 (go be)
224
225
226 replaceExpr :: Expr -> Expr -> Expr -> Expr
227 replaceExpr d r = go
228   where go e | e == d    = r
229         go (App e1 e2)   = app' (go e1) (go e2)
230         go (Conc es)     = foldr conc (Conc []) (map go es)
231         go (Lambda te e) = lambda' te (go e)
232         go (Pair e1 e2)  = Pair (go e1) (go e2)
233         go (Const e)     = Const (go e)
234         go (CaseUnit v e) = caseUnit (go v) (go e)
235         go e             = e
236
237
238 -- | Is inside the term a definition for the variable?
239 findReplacer :: TypedExpr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
240 findReplacer tv be = findReplacer' (unTypeExpr tv) be
241         
242 -- | Find a definition, and return a substitution
243 findReplacer' :: Expr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
244 -- For combined types, look up the components
245 findReplacer' (Pair x y) e | Just (delX) <- findReplacer' x e
246                            , Just (delY) <- findReplacer' y e
247                     = Just (delX . delY)
248 -- Find the definition
249 findReplacer' e (e1 `Equal` e2) | e == e1    = Just (replaceTermBE e e2)
250                                 | e == e2    = Just (replaceTermBE e e1)
251 findReplacer' e (And es)        = listToMaybe (mapMaybe (findReplacer' e) es)
252                                   -- assuming no two definitions can exist
253 findReplacer' _ _               = Nothing
254
255 -- | Is inside the term a definition for the variable?
256 defFor :: TypedExpr -> BoolExpr -> Maybe (TypedExpr)
257 defFor tv be | Just (e') <- defFor' (unTypeExpr tv) be
258                          = Just (TypedExpr e' (typeOf tv))
259              | otherwise = Nothing
260         
261 -- | Find a definition, and return it along the definition remover
262 defFor' :: Expr -> BoolExpr -> Maybe (Expr)
263 defFor' e (e1 `Equal` e2) | e == e1                 = Just (e2)
264                           | e == e2                 = Just (e1)
265 defFor' e (And es)        | [d]  <- mapMaybe (defFor' e) es -- exactly one definition
266                                                     = Just d
267 defFor' _ _                                         = Nothing
268
269 app :: TypedExpr -> TypedExpr -> TypedExpr
270 app te1 te2 | Arrow t1 t2 <- typeOf te1
271             , t3          <- typeOf te2 
272             , t1 == t3 
273             = TypedExpr (app' (unTypeExpr te1) (unTypeExpr te2)) t2
274 app te1 te2 | otherwise                          = error $ "Type mismatch in app: " ++
275                                                            show te1 ++ " " ++ show te2
276
277 app' :: Expr -> Expr -> Expr
278 app' Bottom    _   = Bottom    -- _|_ x = _|_
279 app' (Lambda tv e1) (e2) = replaceExpr (unTypeExpr tv) e2 e1 -- lambda application
280 app' Map (Conc []) = Conc []   -- map id = id
281 app' (Const e) _   = e         -- const x y = x
282 app' (Conc []) v   = v         -- id x   = x
283 app' f v           = App f v
284
285 lambda :: TypedExpr -> TypedExpr -> TypedExpr
286 lambda tv e = TypedExpr (lambda' tv (unTypeExpr e)) (Arrow (typeOf tv) (typeOf e))
287
288 lambda' :: TypedExpr -> Expr -> Expr
289 lambda' tv e  | e == EUnit           = Const EUnit
290               | (Just e') <- isApplOn (unTypeExpr tv) e
291               , not (unTypeExpr tv `occursIn` e')
292                                      = e'
293               | unTypeExpr tv == e   = Conc []
294               | otherwise            = Lambda tv e
295
296 conc :: Expr -> Expr -> Expr
297 conc (Lambda v (CaseUnit v' e)) (Conc ((Const EUnit):r))
298                                 | unTypeExpr v == v' = conc (Const e) (Conc r)
299 conc (Lambda v (CaseUnit v' e)) (Const EUnit) | unTypeExpr v == v' = Const e
300 conc (Conc xs) (Conc ys)        = Conc (xs  ++ ys)
301 conc (Conc xs)  y               = Conc (xs  ++ [y])
302 conc x         (Conc ys)        = Conc ([x] ++ ys)
303 conc x          y               = Conc ([x,y])
304
305
306 -- Specialization of g'
307
308 specialize :: BoolExpr -> BoolExpr
309 specialize (TypeVarInst strict i be') = 
310                 replaceTermBE (Var (FromTypVar i)) (if strict then Conc [] else Const EUnit) .
311                 everywhere (mkT $ go) $
312                 be
313         where be = specialize be'
314               go (TypInst i' _) | i' == i = TUnit
315               go tv                       = tv                 
316 -- No need to go further once we are through the quantors
317 specialize be = be
318
319 -- Helpers
320
321 isApplOn :: Expr -> Expr -> Maybe Expr
322 isApplOn e e'         | e == e'                       = Nothing
323 isApplOn e (App f e') | e == e'                       = Just (Conc [f])
324 isApplOn e (App f e') | (Just inner) <- isApplOn e e' = Just (conc f inner)
325 isApplOn _ _                                          = Nothing
326
327 occursIn :: (Typeable a, Data a1, Eq a) => a -> a1 -> Bool
328 e `occursIn` e'       = not (null (listify (==e) e'))
329
330 isTuple :: Typ -> Bool
331 isTuple (TPair _ _) = True
332 isTuple _           = False
333
334
335 -- showing
336
337 -- Precedences:
338 -- 10 fun app
339 --  9 (.)
340 --  8 ==
341 --  7 ==>
342 --  6 forall
343
344 instance Show EVar where
345         show F               = "f"
346         show (FromTypVar i)  = "g" ++ show i
347         show (FromParam i b) = "x" ++ show i ++ if b then "'" else ""
348
349
350 instance Show Expr where
351         showsPrec _ (Var v)     = showsPrec 11 v
352         showsPrec d (App e1 e2) = showParen (d>10) $
353                 showsPrec 10 e1 . showChar ' ' . showsPrec 11 e2
354         showsPrec _ (Conc [])   = showString "id"
355         showsPrec d (Conc [e])  = showsPrec d e
356         showsPrec d (Conc es)   = showParen (d>9) $
357                 showIntercalate (showString " . ") (map (showsPrec 10) es)
358         showsPrec _ (Lambda tv e) = showParen True $ 
359                                     showString "\\" .
360                                     showsPrec 11 tv .
361                                     showString " -> ".
362                                     showsPrec 0 e 
363         showsPrec _ (Pair e1 e2) = showParen True $ 
364                                    showsPrec 0 e1 .
365                                    showString "," .
366                                    showsPrec 0 e2
367         showsPrec _ EUnit         = showString "()"
368         showsPrec _ Map           = showString "map"
369         showsPrec d (ELeft e)     = showParen (d>10) $ 
370                                         showString "Left ".
371                                         showsPrec 11 e
372         showsPrec d (ERight e)    = showParen (d>10) $ 
373                                         showString "Right ".
374                                         showsPrec 11 e
375         showsPrec d (Const e)     = showParen (d>10) $ showString "const ".showsPrec 11 e
376         showsPrec d (CaseUnit t1 t2) = showParen (d>5) $
377                                         showString "case " .
378                                         showsPrec 0 t1 .
379                                         showString " of () ->  " .
380                                         showsPrec 11 t2
381         showsPrec _ EitherMap     = showString "eitherMap"
382         showsPrec _ Bottom        = showString "_|_"
383
384 showIntercalate :: ShowS -> [ShowS] -> ShowS
385 showIntercalate _ []  = id
386 showIntercalate _ [x] = x
387 showIntercalate i (x:xs) = x . i . showIntercalate i xs
388
389 instance Show TypedExpr where
390         showsPrec d (TypedExpr e t) = 
391                 showParen (d>10) $
392                         showsPrec 0 e .
393                         showString " :: " .
394                         showString (showTypePrec 0 t)
395
396 instance Show LambdaBE where
397         show (CurriedEquals _) = 
398                         "(==)"
399         show (LambdaBE v1 v2 be) = 
400                         "(" ++
401                         "\\" ++
402                         showsPrec 11 (unTypeExpr v1) "" ++
403                         " " ++
404                         showsPrec 11 (unTypeExpr v2) "" ++
405                         " -> " ++
406                         show be ++
407                         ")"
408
409 instance Show BoolExpr where
410         show (Equal e1 e2) = showsPrec 9 e1 $
411                              showString " == " $
412                              showsPrec 9 e2 ""
413         show (And [])      = "True"
414         show (And bes)     = intercalate " && " $ map show bes
415         show (AllZipWith lbe e1 e2) =
416                         "allZipWith " ++
417                         show lbe ++
418                         " " ++
419                         showsPrec 11 e1 "" ++
420                         " " ++
421                         showsPrec 11 e2 ""
422         show (AndEither lbe1 lbe2 e1 e2) =
423                         "andEither " ++
424                         show lbe1 ++
425                         " " ++
426                         show lbe2 ++
427                         " " ++
428                         showsPrec 11 e1 "" ++
429                         " " ++
430                         showsPrec 11 e2 ""
431         show (Condition tvars be1 be2) = 
432                         "forall " ++
433                         intercalate ", " (map show tvars) ++
434                         ".\n" ++
435                         (if be1 /= beTrue then indent 2 (show be1) ++ "==>\n" else "") ++
436                         indent 2 (show be2)
437         show (UnpackPair v1 v2 e be) = 
438                         "let (" ++
439                         showsPrec 0 v1 "" ++
440                         "," ++
441                         showsPrec 0 v2 "" ++
442                         ") = " ++
443                         showsPrec 0 e "" ++
444                         " in\n" ++
445                         indent 2 (show be)
446         show (TypeVarInst strict i be) = 
447                         "forall types t" ++
448                         show (2*i-1) ++
449                         ", t" ++
450                         show (2*i) ++
451                         ", " ++
452                         (if strict then "strict " else "(strict) ") ++
453                         "functions g" ++
454                         show i ++
455                         " :: t" ++
456                         show (2*i-1) ++
457                         " -> t" ++
458                         show (2*i) ++ 
459                         ".\n" ++
460                         indent 2 (show be)
461
462 indent :: Int -> String -> String
463 indent n = unlines . map (replicate n ' ' ++) . lines
464
465 showTypePrec :: Int -> Typ -> String
466 showTypePrec _ Int                          = "Int" 
467 showTypePrec _ (TVar (TypVar i))            = "a"++show i
468 showTypePrec _ (TVar (TypInst i b)) | not b = "t" ++  show (2*i-1)
469                                     |     b = "t" ++  show (2*i)
470 showTypePrec _ (TVar (TUnit))               = "()"
471 showTypePrec d (Arrow t1 t2)                = paren (d>9) $ 
472                                                 showTypePrec 10 t1 ++
473                                                 " -> " ++
474                                                 showTypePrec 9 t2 
475 showTypePrec _ (List t)                     = "[" ++ showTypePrec 0 t ++ "]"
476 showTypePrec _ (TEither t1 t2)              = "Either " ++ showTypePrec 11 t1 ++ 
477                                                     " " ++ showTypePrec 11 t2
478 showTypePrec _ (TPair t1 t2)                = "(" ++ showTypePrec 0 t1 ++
479                                               "," ++ showTypePrec 0 t2 ++ ")"
480 showTypePrec _ t                            = error $ "Did not expect to show " ++ show t
481
482 paren :: Bool -> String -> String
483 paren b p   =  if b then "(" ++ p ++ ")" else p