unused untyped exprs
[darcs-mirror-polyfix.git] / SimpleFT.hs
1 {-# LANGUAGE PatternGuards, FlexibleContexts  #-}
2
3 module SimpleFT where
4
5 import ParseType
6 import Expr
7 import Control.Monad.Reader
8
9 test = putStrLn . show . freeTheorem . parseType
10
11 freeTheorem t = flip runReader freeVars $ 
12                         freeTheorem' (typedLeft  (Var "f") (unquantify t))
13                                      (typedRight (Var "f") (unquantify t))
14                                      t
15 freeVars = (map (:"") ['a'..])
16
17
18 freeTheorem' :: TypedExpr -> TypedExpr -> Typ -> Reader [String] BoolExpr
19
20 freeTheorem' e1 e2 Int = return $
21         equal e1 e2
22
23 freeTheorem' e1 e2 (TVar (TypVar i)) = return $
24         let tv = TypedExpr (Var ("g"++show i))
25                            (Arrow (TVar (TypInst i False)) (TVar (TypInst i True)))
26         in equal (app tv e1) e2
27
28 freeTheorem' e1 e2 (Arrow t1 t2) | isTuple t1 = do
29         -- Create patterns for (possily nested) tuples and only give
30         -- the inner variables names
31         fillTuplevars False t1 $ \tve1 -> 
32                 fillTuplevars True t1 $ \tve2 ->  do
33                         cond  <- freeTheorem' (tve1) (tve2) t1
34                         concl <- freeTheorem' (app e1 tve1) (app e2 tve2) t2
35                         return $ Condition [tve1, tve2] cond concl
36
37         -- No tuple on the left hand side:
38                                  | otherwise  = getSideVars t1 $ \(v1,v2) -> do
39         cond  <- freeTheorem'  v1  v2 t1
40         -- See if the variables (tv*) actually have equivalent terms (ev*)
41         case (defFor  v1 cond, defFor  v2 cond) of
42           (Just ev1, _) -> do
43                 concl <- freeTheorem' (app e1 ev1) (app e2  v2) t2
44                 return $ unCond v2 concl
45           (Nothing,Just ev2) -> do
46                 concl <- freeTheorem' (app e1  v1) (app e2 ev2) t2
47                 return $ unCond v1 concl
48           _ -> do
49                 concl <- freeTheorem' (app e1  v1) (app e2  v2) t2
50                 return $ Condition [ v1, v2 ] cond concl
51
52 freeTheorem' e1 e2 (List t) = getSideVars t $ \(v1,v2) -> do
53         map <- freeTheorem' v1 v2 t
54         return $ allZipWith v1 v2 map e1 e2
55
56 {-
57 freeTheorem' e1 e2 (TPair t1 t2) = getVars 4 $ \[x1,x2,y1,y2] -> do
58         concl1 <- freeTheorem' (Var x1) (Var y1) t1
59         concl2 <- freeTheorem' (Var x2) (Var y2) t2
60         return $ Condition x1 y1 t1 BETrue $
61                  Condition x2 y2 t2 (
62                         And (Equal e2 (Pair (Var y1) (Var y2)))
63                             (Equal e1 (Pair (Var x1) (Var x2)))) $
64                         And concl1 concl2
65 -}
66
67 freeTheorem' e1 e2 t@(TPair t1 t2) 
68         | (Pair   x1  x2) <- unTypeExpr e1
69         , (Pair   y1  y2) <- unTypeExpr e2
70            = do concl1 <- freeTheorem' 
71                         (TypedExpr x1 tx1)
72                         (TypedExpr y1 ty1)
73                         t1
74                 concl2 <- freeTheorem'
75                         (TypedExpr x2 tx2)
76                         (TypedExpr y2 ty2)
77                         t2
78                 return $ aand concl1 concl2
79         | otherwise
80            = getVars 4 $ \[x1',x2',y1',y2'] -> do
81                 let x1 = TypedExpr (Var x1') tx1
82                     x2 = TypedExpr (Var x2') tx2
83                     y1 = TypedExpr (Var y1') ty1
84                     y2 = TypedExpr (Var y2') ty2
85                 concl1 <- freeTheorem' x1 y1 t1
86                 concl2 <- freeTheorem' x2 y2 t2
87                 return $ unpackPair x1 x2 e1 $
88                                 unpackPair y1 y2 e2  $
89                                         aand concl1 concl2
90  where (TPair tx1 tx2) = typeOf e1
91        (TPair ty1 ty2) = typeOf e2
92
93 freeTheorem' e1 e2 (AllStar (TypVar i) t) = TypeVarInst i `fmap` freeTheorem' e1 e2 t
94 freeTheorem' e1 e2 (All     (TypVar i) t) = TypeVarInst i `fmap` freeTheorem' e1 e2 t
95
96 getVars :: (MonadReader [String] m) => Int -> ([String] -> m a) -> m a
97 getVars n a = asks (take n) >>= local (drop n) . a 
98
99 getSideVars :: (MonadReader [String] m) => Typ -> ((TypedExpr,TypedExpr) -> m a) -> m a
100 getSideVars t a = getVars 2 $ \[v1,v2] -> a (typedLeft (Var v1) t, typedRight (Var v2) t)
101
102 fillTuplevars :: (MonadReader [String] m) => Bool -> Typ -> (TypedExpr -> m a) -> m a
103 fillTuplevars rightSide t@(TPair t1 t2) a = do
104         fillTuplevars rightSide t1 $ \ve1 ->
105                 fillTuplevars rightSide t2 $ \ve2 ->
106                         let pair = Pair (unTypeExpr ve1) (unTypeExpr ve2) in
107                         a (TypedExpr pair (instType rightSide t))
108 fillTuplevars rightSide t a = getVars 1 $ \[s] ->
109                         a (TypedExpr (Var s) (instType rightSide t))
110