comments
[darcs-mirror-polyfix.git] / SimpleFT.hs
1 {-# LANGUAGE PatternGuards, FlexibleContexts  #-}
2
3 module SimpleFT where
4
5 import ParseType
6 import Expr
7 import Control.Monad.Reader
8
9 test = putStrLn . show . freeTheorem . parseType
10
11 freeTheorem t = runReader (freeTheorem' (Var "f") (Var "f") t) freeVars
12
13 freeVars = (map (:"") ['a'..])
14
15
16 freeTheorem' :: Expr -> Expr -> Typ -> Reader [String] BoolExpr
17
18 freeTheorem' e1 e2 Int = return $
19         Equal e1 e2
20
21 freeTheorem' e1 e2 (TVar (TypVar i)) = return $
22         Equal (App (Var ("g"++show i)) e1) e2
23
24 freeTheorem' e1 e2 (Arrow t1 t2) | isTuple t1 = do
25         -- Create patterns for (possily nested) tuples and only give
26         -- the inner variables names
27         fillTuplevars t1 $ \ve1 -> 
28                 fillTuplevars t1 $ \ve2 ->  do
29                         cond  <- freeTheorem' ve1 ve2 t1
30                         concl <- freeTheorem' (App e1 ve1) (App e2 ve2) t2
31                         return $ Condition ve1 ve2 t1 cond concl
32
33         -- No tuple on the left hand side:
34                                  | otherwise  = getVars 2 $ \[v1,v2] -> do
35         cond  <- freeTheorem' (Var v1) (Var v2) t1
36         -- See if the variables actually have definitions
37         case (defFor v1 cond, defFor v2 cond) of
38           (Just ev1, _) -> do
39                 concl <- freeTheorem' (App e1 ev1)      (App e2 (Var v2)) t2
40                 return $ unCond v2 True t1 concl
41           (Nothing,Just ev2) -> do
42                 concl <- freeTheorem' (App e1 (Var v1)) (App e2 ev2)      t2
43                 return $ unCond v1 False t1 concl
44           _ -> do
45                 concl <- freeTheorem' (App e1 (Var v1)) (App e2 (Var v2)) t2
46                 return $ Condition (Var v1) (Var v2) t1 cond concl
47
48 freeTheorem' e1 e2 (List t) = getVars 2 $ \[v1,v2] -> do
49         map <- freeTheorem' (Var v1) (Var v2) t
50         return $ allZipWith v1 v2 map e1 e2
51
52 {-
53 freeTheorem' e1 e2 (TPair t1 t2) = getVars 4 $ \[x1,x2,y1,y2] -> do
54         concl1 <- freeTheorem' (Var x1) (Var y1) t1
55         concl2 <- freeTheorem' (Var x2) (Var y2) t2
56         return $ Condition x1 y1 t1 BETrue $
57                  Condition x2 y2 t2 (
58                         And (Equal e2 (Pair (Var y1) (Var y2)))
59                             (Equal e1 (Pair (Var x1) (Var x2)))) $
60                         And concl1 concl2
61 -}
62
63 freeTheorem' (Pair x1 x2) (Pair y1 y2) (TPair t1 t2) = do
64         concl1 <- freeTheorem' x1 y1 t1
65         concl2 <- freeTheorem' x2 y2 t2
66         return $ And concl1 concl2
67
68 freeTheorem' e1 e2 t@(TPair t1 t2) = getVars 4 $ \[x1,x2,y1,y2] -> do
69         concl1 <- freeTheorem' (Var x1) (Var y1) t1
70         concl2 <- freeTheorem' (Var x2) (Var y2) t2
71         return $ unpackPair x1 x2 e1 False t $
72                         unpackPair y1 y2 e2 True t $
73                                 And concl1 concl2
74
75 freeTheorem' e1 e2 (AllStar (TypVar i) t) = TypeVarInst i `fmap` freeTheorem' e1 e2 t
76 freeTheorem' e1 e2 (All     (TypVar i) t) = TypeVarInst i `fmap` freeTheorem' e1 e2 t
77
78 getVars :: (MonadReader [String] m) => Int -> ([String] -> m a) -> m a
79 getVars n a = asks (take n) >>= local (drop n) . a 
80
81 fillTuplevars :: (MonadReader [String] m) => Typ -> (Expr -> m a) -> m a
82 fillTuplevars (TPair t1 t2) a = do
83         fillTuplevars t1 $ \ve1 ->
84                 fillTuplevars t2 $ \ve2 ->
85                         a (Pair ve1 ve2)
86 fillTuplevars _ a = getVars 1 $ \[s] -> a (Var s)
87