Add Edit warning to Parser.y.pp
[ghc.git] / compiler / basicTypes / MkId.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The AQUA Project, Glasgow University, 1998
4 %
5
6 This module contains definitions for the IdInfo for things that
7 have a standard form, namely:
8
9 - data constructors
10 - record selectors
11 - method and superclass selectors
12 - primitive operations
13
14 \begin{code}
15 {-# OPTIONS -fno-warn-tabs #-}
16 -- The above warning supression flag is a temporary kludge.
17 -- While working on this module you are encouraged to remove it and
18 -- detab the module (please do the detabbing in a separate patch). See
19 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#TabsvsSpaces
20 -- for details
21
22 module MkId (
23         mkDictFunId, mkDictFunTy, mkDictSelId,
24
25         mkDataConIds, mkPrimOpId, mkFCallId,
26
27         mkReboxingAlt, wrapNewTypeBody, unwrapNewTypeBody,
28         wrapFamInstBody, unwrapFamInstScrut,
29         wrapTypeFamInstBody, unwrapTypeFamInstScrut,
30         mkUnpackCase, mkProductBox,
31
32         -- And some particular Ids; see below for why they are wired in
33         wiredInIds, ghcPrimIds,
34         unsafeCoerceName, unsafeCoerceId, realWorldPrimId, 
35         voidArgId, nullAddrId, seqId, lazyId, lazyIdKey,
36         coercionTokenId,
37
38         -- Re-export error Ids
39         module PrelRules
40     ) where
41
42 #include "HsVersions.h"
43
44 import Rules
45 import TysPrim
46 import TysWiredIn
47 import PrelRules
48 import Type
49 import Coercion
50 import TcType
51 import MkCore
52 import CoreUtils        ( exprType, mkCast )
53 import CoreUnfold
54 import Literal
55 import TyCon
56 import Class
57 import VarSet
58 import Name
59 import PrimOp
60 import ForeignCall
61 import DataCon
62 import Id
63 import Var              ( mkExportedLocalVar )
64 import IdInfo
65 import Demand
66 import CoreSyn
67 import Unique
68 import PrelNames
69 import BasicTypes       hiding ( SuccessFlag(..) )
70 import Util
71 import Pair
72 import DynFlags
73 import Outputable
74 import FastString
75 import ListSetOps
76
77 import Data.Maybe       ( maybeToList )
78 \end{code}
79
80 %************************************************************************
81 %*                                                                      *
82 \subsection{Wired in Ids}
83 %*                                                                      *
84 %************************************************************************
85
86 Note [Wired-in Ids]
87 ~~~~~~~~~~~~~~~~~~~
88 There are several reasons why an Id might appear in the wiredInIds:
89
90 (1) The ghcPrimIds are wired in because they can't be defined in
91     Haskell at all, although the can be defined in Core.  They have
92     compulsory unfoldings, so they are always inlined and they  have
93     no definition site.  Their home module is GHC.Prim, so they
94     also have a description in primops.txt.pp, where they are called
95     'pseudoops'.
96
97 (2) The 'error' function, eRROR_ID, is wired in because we don't yet have
98     a way to express in an interface file that the result type variable
99     is 'open'; that is can be unified with an unboxed type
100
101     [The interface file format now carry such information, but there's
102     no way yet of expressing at the definition site for these 
103     error-reporting functions that they have an 'open' 
104     result type. -- sof 1/99]
105
106 (3) Other error functions (rUNTIME_ERROR_ID) are wired in (a) because
107     the desugarer generates code that mentiones them directly, and
108     (b) for the same reason as eRROR_ID
109
110 (4) lazyId is wired in because the wired-in version overrides the
111     strictness of the version defined in GHC.Base
112
113 In cases (2-4), the function has a definition in a library module, and
114 can be called; but the wired-in version means that the details are 
115 never read from that module's interface file; instead, the full definition
116 is right here.
117
118 \begin{code}
119 wiredInIds :: [Id]
120 wiredInIds
121   =  [lazyId]
122   ++ errorIds           -- Defined in MkCore
123   ++ ghcPrimIds
124
125 -- These Ids are exported from GHC.Prim
126 ghcPrimIds :: [Id]
127 ghcPrimIds
128   = [   -- These can't be defined in Haskell, but they have
129         -- perfectly reasonable unfoldings in Core
130     realWorldPrimId,
131     unsafeCoerceId,
132     nullAddrId,
133     seqId
134     ]
135 \end{code}
136
137 %************************************************************************
138 %*                                                                      *
139 \subsection{Data constructors}
140 %*                                                                      *
141 %************************************************************************
142
143 The wrapper for a constructor is an ordinary top-level binding that evaluates
144 any strict args, unboxes any args that are going to be flattened, and calls
145 the worker.
146
147 We're going to build a constructor that looks like:
148
149         data (Data a, C b) =>  T a b = T1 !a !Int b
150
151         T1 = /\ a b -> 
152              \d1::Data a, d2::C b ->
153              \p q r -> case p of { p ->
154                        case q of { q ->
155                        Con T1 [a,b] [p,q,r]}}
156
157 Notice that
158
159 * d2 is thrown away --- a context in a data decl is used to make sure
160   one *could* construct dictionaries at the site the constructor
161   is used, but the dictionary isn't actually used.
162
163 * We have to check that we can construct Data dictionaries for
164   the types a and Int.  Once we've done that we can throw d1 away too.
165
166 * We use (case p of q -> ...) to evaluate p, rather than "seq" because
167   all that matters is that the arguments are evaluated.  "seq" is 
168   very careful to preserve evaluation order, which we don't need
169   to be here.
170
171   You might think that we could simply give constructors some strictness
172   info, like PrimOps, and let CoreToStg do the let-to-case transformation.
173   But we don't do that because in the case of primops and functions strictness
174   is a *property* not a *requirement*.  In the case of constructors we need to
175   do something active to evaluate the argument.
176
177   Making an explicit case expression allows the simplifier to eliminate
178   it in the (common) case where the constructor arg is already evaluated.
179
180 Note [Wrappers for data instance tycons]
181 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
182 In the case of data instances, the wrapper also applies the coercion turning
183 the representation type into the family instance type to cast the result of
184 the wrapper.  For example, consider the declarations
185
186   data family Map k :: * -> *
187   data instance Map (a, b) v = MapPair (Map a (Pair b v))
188
189 The tycon to which the datacon MapPair belongs gets a unique internal
190 name of the form :R123Map, and we call it the representation tycon.
191 In contrast, Map is the family tycon (accessible via
192 tyConFamInst_maybe). A coercion allows you to move between
193 representation and family type.  It is accessible from :R123Map via
194 tyConFamilyCoercion_maybe and has kind
195
196   Co123Map a b v :: {Map (a, b) v ~ :R123Map a b v}
197
198 The wrapper and worker of MapPair get the types
199
200         -- Wrapper
201   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
202   $WMapPair a b v = MapPair a b v `cast` sym (Co123Map a b v)
203
204         -- Worker
205   MapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
206
207 This coercion is conditionally applied by wrapFamInstBody.
208
209 It's a bit more complicated if the data instance is a GADT as well!
210
211    data instance T [a] where
212         T1 :: forall b. b -> T [Maybe b]
213
214 Hence we translate to
215
216         -- Wrapper
217   $WT1 :: forall b. b -> T [Maybe b]
218   $WT1 b v = T1 (Maybe b) b (Maybe b) v
219                         `cast` sym (Co7T (Maybe b))
220
221         -- Worker
222   T1 :: forall c b. (c ~ Maybe b) => b -> :R7T c
223
224         -- Coercion from family type to representation type
225   Co7T a :: T [a] ~ :R7T a
226
227 \begin{code}
228 mkDataConIds :: Name -> Name -> DataCon -> DataConIds
229 mkDataConIds wrap_name wkr_name data_con
230   | isNewTyCon tycon                    -- Newtype, only has a worker
231   = DCIds Nothing nt_work_id                 
232
233   | any isBanged all_strict_marks      -- Algebraic, needs wrapper
234     || not (null eq_spec)              -- NB: LoadIface.ifaceDeclImplicitBndrs
235     || isFamInstTyCon tycon            --     depends on this test
236   = DCIds (Just alg_wrap_id) wrk_id
237
238   | otherwise                                -- Algebraic, no wrapper
239   = DCIds Nothing wrk_id
240   where
241     (univ_tvs, ex_tvs, eq_spec, 
242      other_theta, orig_arg_tys, res_ty) = dataConFullSig data_con
243     tycon = dataConTyCon data_con       -- The representation TyCon (not family)
244
245         ----------- Worker (algebraic data types only) --------------
246         -- The *worker* for the data constructor is the function that
247         -- takes the representation arguments and builds the constructor.
248     wrk_id = mkGlobalId (DataConWorkId data_con) wkr_name
249                         (dataConRepType data_con) wkr_info
250
251     wkr_arity = dataConRepArity data_con
252     wkr_info  = noCafIdInfo
253                 `setArityInfo`       wkr_arity
254                 `setStrictnessInfo`  Just wkr_sig
255                 `setUnfoldingInfo`   evaldUnfolding  -- Record that it's evaluated,
256                                                         -- even if arity = 0
257
258     wkr_sig = mkStrictSig (mkTopDmdType (replicate wkr_arity topDmd) cpr_info)
259         --      Note [Data-con worker strictness]
260         -- Notice that we do *not* say the worker is strict
261         -- even if the data constructor is declared strict
262         --      e.g.    data T = MkT !(Int,Int)
263         -- Why?  Because the *wrapper* is strict (and its unfolding has case
264         -- expresssions that do the evals) but the *worker* itself is not.
265         -- If we pretend it is strict then when we see
266         --      case x of y -> $wMkT y
267         -- the simplifier thinks that y is "sure to be evaluated" (because
268         --  $wMkT is strict) and drops the case.  No, $wMkT is not strict.
269         --
270         -- When the simplifer sees a pattern 
271         --      case e of MkT x -> ...
272         -- it uses the dataConRepStrictness of MkT to mark x as evaluated;
273         -- but that's fine... dataConRepStrictness comes from the data con
274         -- not from the worker Id.
275
276     cpr_info | isProductTyCon tycon && 
277                isDataTyCon tycon    &&
278                wkr_arity > 0        &&
279                wkr_arity <= mAX_CPR_SIZE        = retCPR
280              | otherwise                        = TopRes
281         -- RetCPR is only true for products that are real data types;
282         -- that is, not unboxed tuples or [non-recursive] newtypes
283
284         ----------- Workers for newtypes --------------
285     nt_work_id   = mkGlobalId (DataConWrapId data_con) wkr_name wrap_ty nt_work_info
286     nt_work_info = noCafIdInfo          -- The NoCaf-ness is set by noCafIdInfo
287                   `setArityInfo` 1      -- Arity 1
288                   `setInlinePragInfo`    alwaysInlinePragma
289                   `setUnfoldingInfo`     newtype_unf
290     id_arg1      = mkTemplateLocal 1 (head orig_arg_tys)
291     newtype_unf  = ASSERT2( isVanillaDataCon data_con &&
292                             isSingleton orig_arg_tys, ppr data_con  )
293                               -- Note [Newtype datacons]
294                    mkCompulsoryUnfolding $ 
295                    mkLams wrap_tvs $ Lam id_arg1 $ 
296                    wrapNewTypeBody tycon res_ty_args (Var id_arg1)
297
298
299         ----------- Wrapper --------------
300         -- We used to include the stupid theta in the wrapper's args
301         -- but now we don't.  Instead the type checker just injects these
302         -- extra constraints where necessary.
303     wrap_tvs    = (univ_tvs `minusList` map fst eq_spec) ++ ex_tvs
304     res_ty_args = substTyVars (mkTopTvSubst eq_spec) univ_tvs
305     ev_tys      = other_theta
306     wrap_ty     = mkForAllTys wrap_tvs $ 
307                   mkFunTys ev_tys $
308                   mkFunTys orig_arg_tys $ res_ty
309
310         ----------- Wrappers for algebraic data types -------------- 
311     alg_wrap_id = mkGlobalId (DataConWrapId data_con) wrap_name wrap_ty alg_wrap_info
312     alg_wrap_info = noCafIdInfo
313                     `setArityInfo`         wrap_arity
314                         -- It's important to specify the arity, so that partial
315                         -- applications are treated as values
316                     `setInlinePragInfo`    alwaysInlinePragma
317                     `setUnfoldingInfo`     wrap_unf
318                     `setStrictnessInfo` Just wrap_sig
319                         -- We need to get the CAF info right here because TidyPgm
320                         -- does not tidy the IdInfo of implicit bindings (like the wrapper)
321                         -- so it not make sure that the CAF info is sane
322
323     all_strict_marks = dataConExStricts data_con ++ dataConStrictMarks data_con
324     wrap_sig = mkStrictSig (mkTopDmdType wrap_arg_dmds cpr_info)
325     wrap_stricts = dropList eq_spec all_strict_marks
326     wrap_arg_dmds = map mk_dmd wrap_stricts
327     mk_dmd str | isBanged str = evalDmd
328                | otherwise    = lazyDmd
329         -- The Cpr info can be important inside INLINE rhss, where the
330         -- wrapper constructor isn't inlined.
331         -- And the argument strictness can be important too; we
332         -- may not inline a contructor when it is partially applied.
333         -- For example:
334         --      data W = C !Int !Int !Int
335         --      ...(let w = C x in ...(w p q)...)...
336         -- we want to see that w is strict in its two arguments
337
338     wrap_unf = mkInlineUnfolding (Just (length ev_args + length id_args)) wrap_rhs
339     wrap_rhs = mkLams wrap_tvs $ 
340                mkLams ev_args $
341                mkLams id_args $
342                foldr mk_case con_app 
343                      (zip (ev_args ++ id_args) wrap_stricts)
344                      i3 []
345              -- The ev_args is the evidence arguments *other than* the eq_spec
346              -- Because we are going to apply the eq_spec args manually in the
347              -- wrapper
348
349     con_app _ rep_ids = wrapFamInstBody tycon res_ty_args $
350                           Var wrk_id `mkTyApps`  res_ty_args
351                                      `mkVarApps` ex_tvs                 
352                                      `mkCoApps`  map (mkReflCo . snd) eq_spec
353                                      `mkVarApps` reverse rep_ids
354                             -- Dont box the eq_spec coercions since they are
355                             -- marked as HsUnpack by mk_dict_strict_mark
356
357     (ev_args,i2) = mkLocals 1  ev_tys
358     (id_args,i3) = mkLocals i2 orig_arg_tys
359     wrap_arity   = i3-1
360
361     mk_case 
362            :: (Id, HsBang)      -- Arg, strictness
363            -> (Int -> [Id] -> CoreExpr) -- Body
364            -> Int                       -- Next rep arg id
365            -> [Id]                      -- Rep args so far, reversed
366            -> CoreExpr
367     mk_case (arg,strict) body i rep_args
368           = case strict of
369                 HsNoBang -> body i (arg:rep_args)
370                 HsUnpack -> unboxProduct i (Var arg) (idType arg) the_body 
371                       where
372                         the_body i con_args = body i (reverse con_args ++ rep_args)
373                 _other  -- HsUnpackFailed and HsStrict
374                    | isUnLiftedType (idType arg) -> body i (arg:rep_args)
375                    | otherwise -> Case (Var arg) arg res_ty 
376                                        [(DEFAULT,[], body i (arg:rep_args))]
377
378 mAX_CPR_SIZE :: Arity
379 mAX_CPR_SIZE = 10
380 -- We do not treat very big tuples as CPR-ish:
381 --      a) for a start we get into trouble because there aren't 
382 --         "enough" unboxed tuple types (a tiresome restriction, 
383 --         but hard to fix), 
384 --      b) more importantly, big unboxed tuples get returned mainly
385 --         on the stack, and are often then allocated in the heap
386 --         by the caller.  So doing CPR for them may in fact make
387 --         things worse.
388
389 mkLocals :: Int -> [Type] -> ([Id], Int)
390 mkLocals i tys = (zipWith mkTemplateLocal [i..i+n-1] tys, i+n)
391                where
392                  n = length tys
393 \end{code}
394
395 Note [Newtype datacons]
396 ~~~~~~~~~~~~~~~~~~~~~~~
397 The "data constructor" for a newtype should always be vanilla.  At one
398 point this wasn't true, because the newtype arising from
399      class C a => D a
400 looked like
401        newtype T:D a = D:D (C a)
402 so the data constructor for T:C had a single argument, namely the
403 predicate (C a).  But now we treat that as an ordinary argument, not
404 part of the theta-type, so all is well.
405
406
407 %************************************************************************
408 %*                                                                      *
409 \subsection{Dictionary selectors}
410 %*                                                                      *
411 %************************************************************************
412
413 Selecting a field for a dictionary.  If there is just one field, then
414 there's nothing to do.  
415
416 Dictionary selectors may get nested forall-types.  Thus:
417
418         class Foo a where
419           op :: forall b. Ord b => a -> b -> b
420
421 Then the top-level type for op is
422
423         op :: forall a. Foo a => 
424               forall b. Ord b => 
425               a -> b -> b
426
427 This is unlike ordinary record selectors, which have all the for-alls
428 at the outside.  When dealing with classes it's very convenient to
429 recover the original type signature from the class op selector.
430
431 \begin{code}
432 mkDictSelId :: Bool          -- True <=> don't include the unfolding
433                              -- Little point on imports without -O, because the
434                              -- dictionary itself won't be visible
435             -> Name          -- Name of one of the *value* selectors 
436                              -- (dictionary superclass or method)
437             -> Class -> Id
438 mkDictSelId no_unf name clas
439   = mkGlobalId (ClassOpId clas) name sel_ty info
440   where
441     sel_ty = mkForAllTys tyvars (mkFunTy (idType dict_id) (idType the_arg_id))
442         -- We can't just say (exprType rhs), because that would give a type
443         --      C a -> C a
444         -- for a single-op class (after all, the selector is the identity)
445         -- But it's type must expose the representation of the dictionary
446         -- to get (say)         C a -> (a -> a)
447
448     base_info = noCafIdInfo
449                 `setArityInfo`      1
450                 `setStrictnessInfo` Just strict_sig
451                 `setUnfoldingInfo`  (if no_unf then noUnfolding
452                                      else mkImplicitUnfolding rhs)
453                    -- In module where class op is defined, we must add
454                    -- the unfolding, even though it'll never be inlined
455                    -- becuase we use that to generate a top-level binding
456                    -- for the ClassOp
457
458     info | new_tycon = base_info `setInlinePragInfo` alwaysInlinePragma
459                    -- See Note [Single-method classes] in TcInstDcls
460                    -- for why alwaysInlinePragma
461          | otherwise = base_info  `setSpecInfo`       mkSpecInfo [rule]
462                                   `setInlinePragInfo` neverInlinePragma
463                    -- Add a magic BuiltinRule, and never inline it
464                    -- so that the rule is always available to fire.
465                    -- See Note [ClassOp/DFun selection] in TcInstDcls
466
467     n_ty_args = length tyvars
468
469     -- This is the built-in rule that goes
470     --      op (dfT d1 d2) --->  opT d1 d2
471     rule = BuiltinRule { ru_name = fsLit "Class op " `appendFS` 
472                                      occNameFS (getOccName name)
473                        , ru_fn    = name
474                        , ru_nargs = n_ty_args + 1
475                        , ru_try   = dictSelRule val_index n_ty_args }
476
477         -- The strictness signature is of the form U(AAAVAAAA) -> T
478         -- where the V depends on which item we are selecting
479         -- It's worth giving one, so that absence info etc is generated
480         -- even if the selector isn't inlined
481     strict_sig = mkStrictSig (mkTopDmdType [arg_dmd] TopRes)
482     arg_dmd | new_tycon = evalDmd
483             | otherwise = Eval (Prod [ if the_arg_id == id then evalDmd else Abs
484                                      | id <- arg_ids ])
485
486     tycon          = classTyCon clas
487     new_tycon      = isNewTyCon tycon
488     [data_con]     = tyConDataCons tycon
489     tyvars         = dataConUnivTyVars data_con
490     arg_tys        = dataConRepArgTys data_con  -- Includes the dictionary superclasses
491
492     -- 'index' is a 0-index into the *value* arguments of the dictionary
493     val_index      = assoc "MkId.mkDictSelId" sel_index_prs name
494     sel_index_prs  = map idName (classAllSelIds clas) `zip` [0..]
495
496     the_arg_id     = arg_ids !! val_index
497     pred           = mkClassPred clas (mkTyVarTys tyvars)
498     dict_id        = mkTemplateLocal 1 pred
499     arg_ids        = mkTemplateLocalsNum 2 arg_tys
500
501     rhs = mkLams tyvars  (Lam dict_id   rhs_body)
502     rhs_body | new_tycon = unwrapNewTypeBody tycon (map mkTyVarTy tyvars) (Var dict_id)
503              | otherwise = Case (Var dict_id) dict_id (idType the_arg_id)
504                                 [(DataAlt data_con, arg_ids, varToCoreExpr the_arg_id)]
505                                 -- varToCoreExpr needed for equality superclass selectors
506                                 --   sel a b d = case x of { MkC _ (g:a~b) _ -> CO g }
507
508 dictSelRule :: Int -> Arity 
509             -> Id -> IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
510 -- Tries to persuade the argument to look like a constructor
511 -- application, using exprIsConApp_maybe, and then selects
512 -- from it
513 --       sel_i t1..tk (D t1..tk op1 ... opm) = opi
514 --
515 dictSelRule val_index n_ty_args _ id_unf args
516   | (dict_arg : _) <- drop n_ty_args args
517   , Just (_, _, con_args) <- exprIsConApp_maybe id_unf dict_arg
518   = Just (con_args !! val_index)
519   | otherwise
520   = Nothing
521 \end{code}
522
523
524 %************************************************************************
525 %*                                                                      *
526         Boxing and unboxing
527 %*                                                                      *
528 %************************************************************************
529
530 \begin{code}
531 -- unbox a product type...
532 -- we will recurse into newtypes, casting along the way, and unbox at the
533 -- first product data constructor we find. e.g.
534 --  
535 --   data PairInt = PairInt Int Int
536 --   newtype S = MkS PairInt
537 --   newtype T = MkT S
538 --
539 -- If we have e = MkT (MkS (PairInt 0 1)) and some body expecting a list of
540 -- ids, we get (modulo int passing)
541 --
542 --   case (e `cast` CoT) `cast` CoS of
543 --     PairInt a b -> body [a,b]
544 --
545 -- The Ints passed around are just for creating fresh locals
546 unboxProduct :: Int -> CoreExpr -> Type -> (Int -> [Id] -> CoreExpr) -> CoreExpr
547 unboxProduct i arg arg_ty body
548   = result
549   where 
550     result = mkUnpackCase the_id arg con_args boxing_con rhs
551     (_tycon, _tycon_args, boxing_con, tys) = deepSplitProductType "unboxProduct" arg_ty
552     ([the_id], i') = mkLocals i [arg_ty]
553     (con_args, i'') = mkLocals i' tys
554     rhs = body i'' con_args
555
556 mkUnpackCase ::  Id -> CoreExpr -> [Id] -> DataCon -> CoreExpr -> CoreExpr
557 -- (mkUnpackCase x e args Con body)
558 --      returns
559 -- case (e `cast` ...) of bndr { Con args -> body }
560 -- 
561 -- the type of the bndr passed in is irrelevent
562 mkUnpackCase bndr arg unpk_args boxing_con body
563   = Case cast_arg (setIdType bndr bndr_ty) (exprType body) [(DataAlt boxing_con, unpk_args, body)]
564   where
565   (cast_arg, bndr_ty) = go (idType bndr) arg
566   go ty arg 
567     | (tycon, tycon_args, _, _)  <- splitProductType "mkUnpackCase" ty
568     , isNewTyCon tycon && not (isRecursiveTyCon tycon)
569     = go (newTyConInstRhs tycon tycon_args) 
570          (unwrapNewTypeBody tycon tycon_args arg)
571     | otherwise = (arg, ty)
572
573 -- ...and the dual
574 reboxProduct :: [Unique]     -- uniques to create new local binders
575              -> Type         -- type of product to box
576              -> ([Unique],   -- remaining uniques
577                  CoreExpr,   -- boxed product
578                  [Id])       -- Ids being boxed into product
579 reboxProduct us ty
580   = let 
581         (_tycon, _tycon_args, _pack_con, con_arg_tys) = deepSplitProductType "reboxProduct" ty
582  
583         us' = dropList con_arg_tys us
584
585         arg_ids  = zipWith (mkSysLocal (fsLit "rb")) us con_arg_tys
586
587         bind_rhs = mkProductBox arg_ids ty
588
589     in
590       (us', bind_rhs, arg_ids)
591
592 mkProductBox :: [Id] -> Type -> CoreExpr
593 mkProductBox arg_ids ty 
594   = result_expr
595   where 
596     (tycon, tycon_args, pack_con, _con_arg_tys) = splitProductType "mkProductBox" ty
597
598     result_expr
599       | isNewTyCon tycon && not (isRecursiveTyCon tycon) 
600       = wrap (mkProductBox arg_ids (newTyConInstRhs tycon tycon_args))
601       | otherwise = mkConApp pack_con (map Type tycon_args ++ varsToCoreExprs arg_ids)
602
603     wrap expr = wrapNewTypeBody tycon tycon_args expr
604
605
606 -- (mkReboxingAlt us con xs rhs) basically constructs the case
607 -- alternative (con, xs, rhs)
608 -- but it does the reboxing necessary to construct the *source* 
609 -- arguments, xs, from the representation arguments ys.
610 -- For example:
611 --      data T = MkT !(Int,Int) Bool
612 --
613 -- mkReboxingAlt MkT [x,b] r 
614 --      = (DataAlt MkT, [y::Int,z::Int,b], let x = (y,z) in r)
615 --
616 -- mkDataAlt should really be in DataCon, but it can't because
617 -- it manipulates CoreSyn.
618
619 mkReboxingAlt
620   :: [Unique] -- Uniques for the new Ids
621   -> DataCon
622   -> [Var]    -- Source-level args, *including* all evidence vars 
623   -> CoreExpr -- RHS
624   -> CoreAlt
625
626 mkReboxingAlt us con args rhs
627   | not (any isMarkedUnboxed stricts)
628   = (DataAlt con, args, rhs)
629
630   | otherwise
631   = let
632         (binds, args') = go args stricts us
633     in
634     (DataAlt con, args', mkLets binds rhs)
635
636   where
637     stricts = dataConExStricts con ++ dataConStrictMarks con
638
639     go [] _stricts _us = ([], [])
640
641     -- Type variable case
642     go (arg:args) stricts us 
643       | isTyVar arg
644       = let (binds, args') = go args stricts us
645         in  (binds, arg:args')
646
647         -- Term variable case
648     go (arg:args) (str:stricts) us
649       | isMarkedUnboxed str
650       = let (binds, unpacked_args')        = go args stricts us'
651             (us', bind_rhs, unpacked_args) = reboxProduct us (idType arg)
652         in
653             (NonRec arg bind_rhs : binds, unpacked_args ++ unpacked_args')
654       | otherwise
655       = let (binds, args') = go args stricts us
656         in  (binds, arg:args')
657     go (_ : _) [] _ = panic "mkReboxingAlt"
658 \end{code}
659
660
661 %************************************************************************
662 %*                                                                      *
663         Wrapping and unwrapping newtypes and type families
664 %*                                                                      *
665 %************************************************************************
666
667 \begin{code}
668 wrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
669 -- The wrapper for the data constructor for a newtype looks like this:
670 --      newtype T a = MkT (a,Int)
671 --      MkT :: forall a. (a,Int) -> T a
672 --      MkT = /\a. \(x:(a,Int)). x `cast` sym (CoT a)
673 -- where CoT is the coercion TyCon assoicated with the newtype
674 --
675 -- The call (wrapNewTypeBody T [a] e) returns the
676 -- body of the wrapper, namely
677 --      e `cast` (CoT [a])
678 --
679 -- If a coercion constructor is provided in the newtype, then we use
680 -- it, otherwise the wrap/unwrap are both no-ops 
681 --
682 -- If the we are dealing with a newtype *instance*, we have a second coercion
683 -- identifying the family instance with the constructor of the newtype
684 -- instance.  This coercion is applied in any case (ie, composed with the
685 -- coercion constructor of the newtype or applied by itself).
686
687 wrapNewTypeBody tycon args result_expr
688   = ASSERT( isNewTyCon tycon )
689     wrapFamInstBody tycon args $
690     mkCast result_expr (mkSymCo co)
691   where
692     co = mkAxInstCo (newTyConCo tycon) args
693
694 -- When unwrapping, we do *not* apply any family coercion, because this will
695 -- be done via a CoPat by the type checker.  We have to do it this way as
696 -- computing the right type arguments for the coercion requires more than just
697 -- a spliting operation (cf, TcPat.tcConPat).
698
699 unwrapNewTypeBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
700 unwrapNewTypeBody tycon args result_expr
701   = ASSERT( isNewTyCon tycon )
702     mkCast result_expr (mkAxInstCo (newTyConCo tycon) args)
703
704 -- If the type constructor is a representation type of a data instance, wrap
705 -- the expression into a cast adjusting the expression type, which is an
706 -- instance of the representation type, to the corresponding instance of the
707 -- family instance type.
708 -- See Note [Wrappers for data instance tycons]
709 wrapFamInstBody :: TyCon -> [Type] -> CoreExpr -> CoreExpr
710 wrapFamInstBody tycon args body
711   | Just co_con <- tyConFamilyCoercion_maybe tycon
712   = mkCast body (mkSymCo (mkAxInstCo co_con args))
713   | otherwise
714   = body
715
716 -- Same as `wrapFamInstBody`, but for type family instances, which are
717 -- represented by a `CoAxiom`, and not a `TyCon`
718 wrapTypeFamInstBody :: CoAxiom -> [Type] -> CoreExpr -> CoreExpr
719 wrapTypeFamInstBody axiom args body
720   = mkCast body (mkSymCo (mkAxInstCo axiom args))
721
722 unwrapFamInstScrut :: TyCon -> [Type] -> CoreExpr -> CoreExpr
723 unwrapFamInstScrut tycon args scrut
724   | Just co_con <- tyConFamilyCoercion_maybe tycon
725   = mkCast scrut (mkAxInstCo co_con args)
726   | otherwise
727   = scrut
728
729 unwrapTypeFamInstScrut :: CoAxiom -> [Type] -> CoreExpr -> CoreExpr
730 unwrapTypeFamInstScrut axiom args scrut
731   = mkCast scrut (mkAxInstCo axiom args)
732 \end{code}
733
734
735 %************************************************************************
736 %*                                                                      *
737 \subsection{Primitive operations}
738 %*                                                                      *
739 %************************************************************************
740
741 \begin{code}
742 mkPrimOpId :: PrimOp -> Id
743 mkPrimOpId prim_op 
744   = id
745   where
746     (tyvars,arg_tys,res_ty, arity, strict_sig) = primOpSig prim_op
747     ty   = mkForAllTys tyvars (mkFunTys arg_tys res_ty)
748     name = mkWiredInName gHC_PRIM (primOpOcc prim_op) 
749                          (mkPrimOpIdUnique (primOpTag prim_op))
750                          (AnId id) UserSyntax
751     id   = mkGlobalId (PrimOpId prim_op) name ty info
752                 
753     info = noCafIdInfo
754            `setSpecInfo`          mkSpecInfo (maybeToList $ primOpRules name prim_op)
755            `setArityInfo`         arity
756            `setStrictnessInfo` Just strict_sig
757
758 -- For each ccall we manufacture a separate CCallOpId, giving it
759 -- a fresh unique, a type that is correct for this particular ccall,
760 -- and a CCall structure that gives the correct details about calling
761 -- convention etc.  
762 --
763 -- The *name* of this Id is a local name whose OccName gives the full
764 -- details of the ccall, type and all.  This means that the interface 
765 -- file reader can reconstruct a suitable Id
766
767 mkFCallId :: DynFlags -> Unique -> ForeignCall -> Type -> Id
768 mkFCallId dflags uniq fcall ty
769   = ASSERT( isEmptyVarSet (tyVarsOfType ty) )
770     -- A CCallOpId should have no free type variables; 
771     -- when doing substitutions won't substitute over it
772     mkGlobalId (FCallId fcall) name ty info
773   where
774     occ_str = showSDoc dflags (braces (ppr fcall <+> ppr ty))
775     -- The "occurrence name" of a ccall is the full info about the
776     -- ccall; it is encoded, but may have embedded spaces etc!
777
778     name = mkFCallName uniq occ_str
779
780     info = noCafIdInfo
781            `setArityInfo`         arity
782            `setStrictnessInfo` Just strict_sig
783
784     (_, tau)     = tcSplitForAllTys ty
785     (arg_tys, _) = tcSplitFunTys tau
786     arity        = length arg_tys
787     strict_sig   = mkStrictSig (mkTopDmdType (replicate arity evalDmd) TopRes)
788 \end{code}
789
790
791 %************************************************************************
792 %*                                                                      *
793 \subsection{DictFuns and default methods}
794 %*                                                                      *
795 %************************************************************************
796
797 Important notes about dict funs and default methods
798 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
799 Dict funs and default methods are *not* ImplicitIds.  Their definition
800 involves user-written code, so we can't figure out their strictness etc
801 based on fixed info, as we can for constructors and record selectors (say).
802
803 We build them as LocalIds, but with External Names.  This ensures that
804 they are taken to account by free-variable finding and dependency
805 analysis (e.g. CoreFVs.exprFreeVars).
806
807 Why shouldn't they be bound as GlobalIds?  Because, in particular, if
808 they are globals, the specialiser floats dict uses above their defns,
809 which prevents good simplifications happening.  Also the strictness
810 analyser treats a occurrence of a GlobalId as imported and assumes it
811 contains strictness in its IdInfo, which isn't true if the thing is
812 bound in the same module as the occurrence.
813
814 It's OK for dfuns to be LocalIds, because we form the instance-env to
815 pass on to the next module (md_insts) in CoreTidy, afer tidying
816 and globalising the top-level Ids.
817
818 BUT make sure they are *exported* LocalIds (mkExportedLocalId) so 
819 that they aren't discarded by the occurrence analyser.
820
821 \begin{code}
822 mkDictFunId :: Name      -- Name to use for the dict fun;
823             -> [TyVar]
824             -> ThetaType
825             -> Class 
826             -> [Type]
827             -> Id
828 -- Implements the DFun Superclass Invariant (see TcInstDcls)
829
830 mkDictFunId dfun_name tvs theta clas tys
831   = mkExportedLocalVar (DFunId n_silent is_nt)
832                        dfun_name
833                        dfun_ty
834                        vanillaIdInfo
835   where
836     is_nt = isNewTyCon (classTyCon clas)
837     (n_silent, dfun_ty) = mkDictFunTy tvs theta clas tys
838
839 mkDictFunTy :: [TyVar] -> ThetaType -> Class -> [Type] -> (Int, Type)
840 mkDictFunTy tvs theta clas tys
841   = (length silent_theta, dfun_ty)
842   where
843     dfun_ty = mkSigmaTy tvs (silent_theta ++ theta) (mkClassPred clas tys)
844     silent_theta 
845       | null tvs, null theta 
846       = []
847       | otherwise
848       = filterOut discard $
849         substTheta (zipTopTvSubst (classTyVars clas) tys)
850                    (classSCTheta clas)
851                    -- See Note [Silent Superclass Arguments]
852     discard pred = any (`eqPred` pred) theta
853                  -- See the DFun Superclass Invariant in TcInstDcls
854 \end{code}
855
856
857 %************************************************************************
858 %*                                                                      *
859 \subsection{Un-definable}
860 %*                                                                      *
861 %************************************************************************
862
863 These Ids can't be defined in Haskell.  They could be defined in
864 unfoldings in the wired-in GHC.Prim interface file, but we'd have to
865 ensure that they were definitely, definitely inlined, because there is
866 no curried identifier for them.  That's what mkCompulsoryUnfolding
867 does.  If we had a way to get a compulsory unfolding from an interface
868 file, we could do that, but we don't right now.
869
870 unsafeCoerce# isn't so much a PrimOp as a phantom identifier, that
871 just gets expanded into a type coercion wherever it occurs.  Hence we
872 add it as a built-in Id with an unfolding here.
873
874 The type variables we use here are "open" type variables: this means
875 they can unify with both unlifted and lifted types.  Hence we provide
876 another gun with which to shoot yourself in the foot.
877
878 \begin{code}
879 lazyIdName, unsafeCoerceName, nullAddrName, seqName, realWorldName, coercionTokenName :: Name
880 unsafeCoerceName  = mkWiredInIdName gHC_PRIM (fsLit "unsafeCoerce#") unsafeCoerceIdKey  unsafeCoerceId
881 nullAddrName      = mkWiredInIdName gHC_PRIM (fsLit "nullAddr#")     nullAddrIdKey      nullAddrId
882 seqName           = mkWiredInIdName gHC_PRIM (fsLit "seq")           seqIdKey           seqId
883 realWorldName     = mkWiredInIdName gHC_PRIM (fsLit "realWorld#")    realWorldPrimIdKey realWorldPrimId
884 lazyIdName        = mkWiredInIdName gHC_BASE (fsLit "lazy")         lazyIdKey           lazyId
885 coercionTokenName = mkWiredInIdName gHC_PRIM (fsLit "coercionToken#") coercionTokenIdKey coercionTokenId
886 \end{code}
887
888 \begin{code}
889 ------------------------------------------------
890 -- unsafeCoerce# :: forall a b. a -> b
891 unsafeCoerceId :: Id
892 unsafeCoerceId
893   = pcMiscPrelId unsafeCoerceName ty info
894   where
895     info = noCafIdInfo `setInlinePragInfo` alwaysInlinePragma
896                        `setUnfoldingInfo`  mkCompulsoryUnfolding rhs
897            
898
899     ty  = mkForAllTys [openAlphaTyVar,openBetaTyVar]
900                       (mkFunTy openAlphaTy openBetaTy)
901     [x] = mkTemplateLocals [openAlphaTy]
902     rhs = mkLams [openAlphaTyVar,openBetaTyVar,x] $
903           Cast (Var x) (mkUnsafeCo openAlphaTy openBetaTy)
904
905 ------------------------------------------------
906 nullAddrId :: Id
907 -- nullAddr# :: Addr#
908 -- The reason is is here is because we don't provide 
909 -- a way to write this literal in Haskell.
910 nullAddrId = pcMiscPrelId nullAddrName addrPrimTy info
911   where
912     info = noCafIdInfo `setInlinePragInfo` alwaysInlinePragma
913                        `setUnfoldingInfo`  mkCompulsoryUnfolding (Lit nullAddrLit)
914
915 ------------------------------------------------
916 seqId :: Id     -- See Note [seqId magic]
917 seqId = pcMiscPrelId seqName ty info
918   where
919     info = noCafIdInfo `setInlinePragInfo` alwaysInlinePragma
920                        `setUnfoldingInfo`  mkCompulsoryUnfolding rhs
921                        `setSpecInfo`       mkSpecInfo [seq_cast_rule]
922            
923
924     ty  = mkForAllTys [alphaTyVar,betaTyVar]
925                       (mkFunTy alphaTy (mkFunTy betaTy betaTy))
926               -- NB argBetaTyVar; see Note [seqId magic]
927
928     [x,y] = mkTemplateLocals [alphaTy, betaTy]
929     rhs = mkLams [alphaTyVar,betaTyVar,x,y] (Case (Var x) x betaTy [(DEFAULT, [], Var y)])
930
931     -- See Note [Built-in RULES for seq]
932     seq_cast_rule = BuiltinRule { ru_name  = fsLit "seq of cast"
933                                 , ru_fn    = seqName
934                                 , ru_nargs = 4
935                                 , ru_try   = match_seq_of_cast
936                                 }
937
938 match_seq_of_cast :: Id -> IdUnfoldingFun -> [CoreExpr] -> Maybe CoreExpr
939     -- See Note [Built-in RULES for seq]
940 match_seq_of_cast _ _ [Type _, Type res_ty, Cast scrut co, expr]
941   = Just (Var seqId `mkApps` [Type (pFst (coercionKind co)), Type res_ty,
942                               scrut, expr])
943 match_seq_of_cast _ _ _ = Nothing
944
945 ------------------------------------------------
946 lazyId :: Id    -- See Note [lazyId magic]
947 lazyId = pcMiscPrelId lazyIdName ty info
948   where
949     info = noCafIdInfo
950     ty  = mkForAllTys [alphaTyVar] (mkFunTy alphaTy alphaTy)
951 \end{code}
952
953 Note [Unsafe coerce magic]
954 ~~~~~~~~~~~~~~~~~~~~~~~~~~
955 We define a *primitive*
956    GHC.Prim.unsafeCoerce#
957 and then in the base library we define the ordinary function
958    Unsafe.Coerce.unsafeCoerce :: forall (a:*) (b:*). a -> b
959    unsafeCoerce x = unsafeCoerce# x
960
961 Notice that unsafeCoerce has a civilized (albeit still dangerous)
962 polymorphic type, whose type args have kind *.  So you can't use it on
963 unboxed values (unsafeCoerce 3#).
964
965 In contrast unsafeCoerce# is even more dangerous because you *can* use
966 it on unboxed things, (unsafeCoerce# 3#) :: Int. Its type is
967    forall (a:OpenKind) (b:OpenKind). a -> b
968
969 Note [seqId magic]
970 ~~~~~~~~~~~~~~~~~~
971 'GHC.Prim.seq' is special in several ways. 
972
973 a) Its second arg can have an unboxed type
974       x `seq` (v +# w)
975    Hence its second type variable has ArgKind
976
977 b) Its fixity is set in LoadIface.ghcPrimIface
978
979 c) It has quite a bit of desugaring magic. 
980    See DsUtils.lhs Note [Desugaring seq (1)] and (2) and (3)
981
982 d) There is some special rule handing: Note [User-defined RULES for seq]
983
984 e) See Note [Typing rule for seq] in TcExpr.
985
986 Note [User-defined RULES for seq]
987 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
988 Roman found situations where he had
989       case (f n) of _ -> e
990 where he knew that f (which was strict in n) would terminate if n did.
991 Notice that the result of (f n) is discarded. So it makes sense to
992 transform to
993       case n of _ -> e
994
995 Rather than attempt some general analysis to support this, I've added
996 enough support that you can do this using a rewrite rule:
997
998   RULE "f/seq" forall n.  seq (f n) e = seq n e
999
1000 You write that rule.  When GHC sees a case expression that discards
1001 its result, it mentally transforms it to a call to 'seq' and looks for
1002 a RULE.  (This is done in Simplify.rebuildCase.)  As usual, the
1003 correctness of the rule is up to you.
1004
1005 To make this work, we need to be careful that the magical desugaring
1006 done in Note [seqId magic] item (c) is *not* done on the LHS of a rule.
1007 Or rather, we arrange to un-do it, in DsBinds.decomposeRuleLhs.
1008
1009 Note [Built-in RULES for seq]
1010 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1011 We also have the following built-in rule for seq
1012
1013   seq (x `cast` co) y = seq x y
1014
1015 This eliminates unnecessary casts and also allows other seq rules to
1016 match more often.  Notably,     
1017
1018    seq (f x `cast` co) y  -->  seq (f x) y
1019   
1020 and now a user-defined rule for seq (see Note [User-defined RULES for seq])
1021 may fire.
1022
1023
1024 Note [lazyId magic]
1025 ~~~~~~~~~~~~~~~~~~~
1026     lazy :: forall a?. a? -> a?   (i.e. works for unboxed types too)
1027
1028 Used to lazify pseq:   pseq a b = a `seq` lazy b
1029
1030 Also, no strictness: by being a built-in Id, all the info about lazyId comes from here,
1031 not from GHC.Base.hi.   This is important, because the strictness
1032 analyser will spot it as strict!
1033
1034 Also no unfolding in lazyId: it gets "inlined" by a HACK in CorePrep.
1035 It's very important to do this inlining *after* unfoldings are exposed 
1036 in the interface file.  Otherwise, the unfolding for (say) pseq in the
1037 interface file will not mention 'lazy', so if we inline 'pseq' we'll totally
1038 miss the very thing that 'lazy' was there for in the first place.
1039 See Trac #3259 for a real world example.
1040
1041 lazyId is defined in GHC.Base, so we don't *have* to inline it.  If it
1042 appears un-applied, we'll end up just calling it.
1043
1044 -------------------------------------------------------------
1045 @realWorld#@ used to be a magic literal, \tr{void#}.  If things get
1046 nasty as-is, change it back to a literal (@Literal@).
1047
1048 voidArgId is a Local Id used simply as an argument in functions
1049 where we just want an arg to avoid having a thunk of unlifted type.
1050 E.g.
1051         x = \ void :: State# RealWorld -> (# p, q #)
1052
1053 This comes up in strictness analysis
1054
1055 \begin{code}
1056 realWorldPrimId :: Id
1057 realWorldPrimId -- :: State# RealWorld
1058   = pcMiscPrelId realWorldName realWorldStatePrimTy
1059                  (noCafIdInfo `setUnfoldingInfo` evaldUnfolding)
1060         -- The evaldUnfolding makes it look that realWorld# is evaluated
1061         -- which in turn makes Simplify.interestingArg return True,
1062         -- which in turn makes INLINE things applied to realWorld# likely
1063         -- to be inlined
1064
1065 voidArgId :: Id
1066 voidArgId       -- :: State# RealWorld
1067   = mkSysLocal (fsLit "void") voidArgIdKey realWorldStatePrimTy
1068
1069 coercionTokenId :: Id         -- :: () ~ ()
1070 coercionTokenId -- Used to replace Coercion terms when we go to STG
1071   = pcMiscPrelId coercionTokenName 
1072                  (mkTyConApp eqPrimTyCon [liftedTypeKind, unitTy, unitTy])
1073                  noCafIdInfo
1074 \end{code}
1075
1076
1077 \begin{code}
1078 pcMiscPrelId :: Name -> Type -> IdInfo -> Id
1079 pcMiscPrelId name ty info
1080   = mkVanillaGlobalWithInfo name ty info
1081     -- We lie and say the thing is imported; otherwise, we get into
1082     -- a mess with dependency analysis; e.g., core2stg may heave in
1083     -- random calls to GHCbase.unpackPS__.  If GHCbase is the module
1084     -- being compiled, then it's just a matter of luck if the definition
1085     -- will be in "the right place" to be in scope.
1086 \end{code}