Fix ambiguous flag resolution (#7138)
[ghc.git] / compiler / main / CmdLineParser.hs
1 -------------------------------------------------------------------------------
2 --
3 -- | Command-line parser
4 --
5 -- This is an abstract command-line parser used by both StaticFlags and
6 -- DynFlags.
7 --
8 -- (c) The University of Glasgow 2005
9 --
10 -------------------------------------------------------------------------------
11
12 module CmdLineParser
13     (
14       processArgs, OptKind(..),
15       CmdLineP(..), getCmdLineState, putCmdLineState,
16       Flag(..),
17       errorsToGhcException,
18
19       EwM, addErr, addWarn, getArg, getCurLoc, liftEwM, deprecate
20     ) where
21
22 #include "HsVersions.h"
23
24 import Util
25 import Outputable
26 import Panic
27 import Bag
28 import SrcLoc
29
30 import Data.Function
31 import Data.List
32
33
34 --------------------------------------------------------
35 --         The Flag and OptKind types
36 --------------------------------------------------------
37
38 data Flag m = Flag
39     {   flagName    :: String,   -- Flag, without the leading "-"
40         flagOptKind :: OptKind m -- What to do if we see it
41     }
42
43 data OptKind m                             -- Suppose the flag is -f
44     = NoArg     (EwM m ())                 -- -f all by itself
45     | HasArg    (String -> EwM m ())       -- -farg or -f arg
46     | SepArg    (String -> EwM m ())       -- -f arg
47     | Prefix    (String -> EwM m ())       -- -farg
48     | OptPrefix (String -> EwM m ())       -- -f or -farg (i.e. the arg is optional)
49     | OptIntSuffix (Maybe Int -> EwM m ()) -- -f or -f=n; pass n to fn
50     | IntSuffix (Int -> EwM m ())          -- -f or -f=n; pass n to fn
51     | PassFlag  (String -> EwM m ())       -- -f; pass "-f" fn
52     | AnySuffix (String -> EwM m ())       -- -f or -farg; pass entire "-farg" to fn
53     | PrefixPred    (String -> Bool) (String -> EwM m ())
54     | AnySuffixPred (String -> Bool) (String -> EwM m ())
55
56
57 --------------------------------------------------------
58 --         The EwM monad
59 --------------------------------------------------------
60
61 type Err   = Located String
62 type Warn  = Located String
63 type Errs  = Bag Err
64 type Warns = Bag Warn
65
66 -- EwM ("errors and warnings monad") is a monad
67 -- transformer for m that adds an (err, warn) state
68 newtype EwM m a = EwM { unEwM :: Located String -- Current parse arg
69                               -> Errs -> Warns
70                               -> m (Errs, Warns, a) }
71
72 instance Monad m => Monad (EwM m) where
73     (EwM f) >>= k = EwM (\l e w -> do (e', w', r) <- f l e w
74                                       unEwM (k r) l e' w')
75     return v = EwM (\_ e w -> return (e, w, v))
76
77 setArg :: Monad m => Located String -> EwM m () -> EwM m ()
78 setArg l (EwM f) = EwM (\_ es ws -> f l es ws)
79
80 addErr :: Monad m => String -> EwM m ()
81 addErr e = EwM (\(L loc _) es ws -> return (es `snocBag` L loc e, ws, ()))
82
83 addWarn :: Monad m => String -> EwM m ()
84 addWarn msg = EwM (\(L loc _) es ws -> return (es, ws `snocBag` L loc msg, ()))
85
86 deprecate :: Monad m => String -> EwM m ()
87 deprecate s = do
88     arg <- getArg
89     addWarn (arg ++ " is deprecated: " ++ s)
90
91 getArg :: Monad m => EwM m String
92 getArg = EwM (\(L _ arg) es ws -> return (es, ws, arg))
93
94 getCurLoc :: Monad m => EwM m SrcSpan
95 getCurLoc = EwM (\(L loc _) es ws -> return (es, ws, loc))
96
97 liftEwM :: Monad m => m a -> EwM m a
98 liftEwM action = EwM (\_ es ws -> do { r <- action; return (es, ws, r) })
99
100
101 --------------------------------------------------------
102 -- A state monad for use in the command-line parser
103 --------------------------------------------------------
104
105 -- (CmdLineP s) typically instantiates the 'm' in (EwM m) and (OptKind m)
106 newtype CmdLineP s a = CmdLineP { runCmdLine :: s -> (a, s) }
107
108 instance Monad (CmdLineP s) where
109     m >>= k = CmdLineP $ \s ->
110                   let (a, s') = runCmdLine m s
111                   in runCmdLine (k a) s'
112
113     return a = CmdLineP $ \s -> (a, s)
114
115 getCmdLineState :: CmdLineP s s
116 getCmdLineState   = CmdLineP $ \s -> (s,s)
117 putCmdLineState :: s -> CmdLineP s ()
118 putCmdLineState s = CmdLineP $ \_ -> ((),s)
119
120
121 --------------------------------------------------------
122 --         Processing arguments
123 --------------------------------------------------------
124
125 processArgs :: Monad m
126             => [Flag m]               -- cmdline parser spec
127             -> [Located String]       -- args
128             -> m ( [Located String],  -- spare args
129                    [Located String],  -- errors
130                    [Located String] ) -- warnings
131 processArgs spec args = do
132     (errs, warns, spare) <- unEwM action (panic "processArgs: no arg yet")
133                                   emptyBag emptyBag
134     return (spare, bagToList errs, bagToList warns)
135   where
136     action = process args []
137
138     -- process :: [Located String] -> [Located String] -> EwM m [Located String]
139     process [] spare = return (reverse spare)
140
141     process (locArg@(L _ ('-' : arg)) : args) spare =
142         case findArg spec arg of
143             Just (rest, opt_kind) ->
144                 case processOneArg opt_kind rest arg args of
145                     Left err ->
146                         let b = process args spare
147                         in (setArg locArg $ addErr err) >> b
148
149                     Right (action,rest) ->
150                         let b = process rest spare
151                         in (setArg locArg $ action) >> b
152
153             Nothing -> process args (locArg : spare)
154
155     process (arg : args) spare = process args (arg : spare)
156
157
158 processOneArg :: OptKind m -> String -> String -> [Located String]
159               -> Either String (EwM m (), [Located String])
160 processOneArg opt_kind rest arg args
161   = let dash_arg = '-' : arg
162         rest_no_eq = dropEq rest
163     in case opt_kind of
164         NoArg  a -> ASSERT(null rest) Right (a, args)
165
166         HasArg f | notNull rest_no_eq -> Right (f rest_no_eq, args)
167                  | otherwise -> case args of
168                                     []               -> missingArgErr dash_arg
169                                     (L _ arg1:args1) -> Right (f arg1, args1)
170
171         SepArg f -> case args of
172                         []               -> unknownFlagErr dash_arg
173                         (L _ arg1:args1) -> Right (f arg1, args1)
174
175         Prefix f | notNull rest_no_eq -> Right (f rest_no_eq, args)
176                  | otherwise          -> unknownFlagErr dash_arg
177
178         PrefixPred _ f | notNull rest_no_eq -> Right (f rest_no_eq, args)
179                        | otherwise          -> unknownFlagErr dash_arg
180
181         PassFlag f  | notNull rest -> unknownFlagErr dash_arg
182                     | otherwise    -> Right (f dash_arg, args)
183
184         OptIntSuffix f | null rest                     -> Right (f Nothing,  args)
185                        | Just n <- parseInt rest_no_eq -> Right (f (Just n), args)
186                        | otherwise -> Left ("malformed integer argument in " ++ dash_arg)
187
188         IntSuffix f | Just n <- parseInt rest_no_eq -> Right (f n, args)
189                     | otherwise -> Left ("malformed integer argument in " ++ dash_arg)
190
191         OptPrefix f       -> Right (f rest_no_eq, args)
192         AnySuffix f       -> Right (f dash_arg, args)
193         AnySuffixPred _ f -> Right (f dash_arg, args)
194
195
196 findArg :: [Flag m] -> String -> Maybe (String, OptKind m)
197 findArg spec arg =
198     case sortBy (compare `on` (length . fst)) -- prefer longest matching flag
199            [ (removeSpaces rest, optKind)
200            | flag <- spec,
201              let optKind  = flagOptKind flag,
202              Just rest <- [stripPrefix (flagName flag) arg],
203              arg_ok optKind rest arg ]
204     of
205         []      -> Nothing
206         (one:_) -> Just one
207
208 arg_ok :: OptKind t -> [Char] -> String -> Bool
209 arg_ok (NoArg           _)  rest _   = null rest
210 arg_ok (HasArg          _)  _    _   = True
211 arg_ok (SepArg          _)  rest _   = null rest
212 arg_ok (Prefix          _)  rest _   = notNull rest
213 arg_ok (PrefixPred p    _)  rest _   = notNull rest && p (dropEq rest)
214 arg_ok (OptIntSuffix    _)  _    _   = True
215 arg_ok (IntSuffix       _)  _    _   = True
216 arg_ok (OptPrefix       _)  _    _   = True
217 arg_ok (PassFlag        _)  rest _   = null rest
218 arg_ok (AnySuffix       _)  _    _   = True
219 arg_ok (AnySuffixPred p _)  _    arg = p arg
220
221 -- | Parse an Int
222 --
223 -- Looks for "433" or "=342", with no trailing gubbins
224 --   * n or =n      => Just n
225 --   * gibberish    => Nothing
226 parseInt :: String -> Maybe Int
227 parseInt s = case reads s of
228                  ((n,""):_) -> Just n
229                  _          -> Nothing
230
231 -- | Discards a leading equals sign
232 dropEq :: String -> String
233 dropEq ('=' : s) = s
234 dropEq s         = s
235
236 unknownFlagErr :: String -> Either String a
237 unknownFlagErr f = Left ("unrecognised flag: " ++ f)
238
239 missingArgErr :: String -> Either String a
240 missingArgErr f = Left ("missing argument for flag: " ++ f)
241
242 --------------------------------------------------------
243 -- Utils
244 --------------------------------------------------------
245
246 errorsToGhcException :: [Located String] -> GhcException
247 errorsToGhcException errs =
248     UsageError $
249         intercalate "\n" [ showUserSpan True l ++ ": " ++ e | L l e <- errs ]
250