Update.
[vte.git] / configure.in
1 AC_INIT(vte.pc.in)
2 VERSION=`grep ^Version: $srcdir/vte.spec | awk '{print $NF}'`
3 AM_INIT_AUTOMAKE(vte,$VERSION)
4
5 AC_ISC_POSIX
6 AC_PROG_CC
7 AC_STDC_HEADERS
8 AM_PROG_CC_STDC
9 AM_MAINTAINER_MODE
10
11 AM_PROG_LIBTOOL
12 ALL_LINGUAS="ang am ar az be bg bn bs ca cs cy da de el en_CA en_GB es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka ko li lt lv mi mk ml mn ms nb ne nl nn no or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sv ta th tr ug uk vi wa xh zh_CN zh_TW"
13
14 AM_GLIB_GNU_GETTEXT
15 AC_CHECK_DECLS(bind_textdomain_codeset,,,[#include "libintl.h"])
16
17 # On some OSs, AC_PATH_XTRA doesn't work right(?), so let the user specify
18 # X_PRE_LIBS and X_EXTRA_LIBS to add even more libraries, and add -lX11 to
19 # the list of libraries for grins.
20 AC_PATH_XTRA
21 X_CFLAGS=
22 X_LIBS=
23 if test "$have_x" = yes ; then
24         if test -d "$ac_x_includes" ; then
25                 X_CFLAGS="-I$ac_x_includes $X_CFLAGS"
26         fi
27         X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
28         if test -d "$ac_x_libraries" ; then
29                 X_LIBS="-L$ac_x_libraries $X_LIBS"
30         fi
31 fi
32 CFLAGS="$X_CFLAGS $CFLAGS"
33 LIBS="$X_LIBS $LIBS"
34
35 if pkg-config --exists "gtk+-2.0 >= 2.2" ; then
36         MODULEGTK="gtk+-2.0 >= 2.2"
37         AC_DEFINE(GDK_MULTIHEAD_SAFE,1,[Force use of GDK's multihead-safe APIs.])
38 else
39         MODULEGTK="gtk+-2.0"
40 fi
41 PKG_CHECK_MODULES(GLIB,glib-2.0)
42 PKG_CHECK_MODULES(GOBJECT,[glib-2.0 gobject-2.0])
43 PKG_CHECK_MODULES(GTK,[glib-2.0 gobject-2.0 $MODULEGTK])
44
45 wantedmodules="glib-2.0 gobject-2.0 $MODULEGTK fontconfig"
46
47 # Let the user specify the default terminal emulation.
48 AC_ARG_WITH(default-emulation,
49 AS_HELP_STRING(--with-default-emulation=xterm,default terminal type to be emulated),
50 emulation=$withval,emulation=xterm)
51 AC_DEFINE_UNQUOTED(VTE_DEFAULT_EMULATION,"$emulation",[The default terminal type to be emulated.])
52 VTE_DEFAULT_EMULATION=$emulation
53 AC_SUBST(VTE_DEFAULT_EMULATION)
54
55 # Use Xft2 if Pango has Xft2 support and it isn't disabled.
56 if test "$have_x" = yes ; then
57         AC_ARG_WITH(xft2,[AS_HELP_STRING(--with-xft2,enable drawing using Xft2)],with_xft2=$withval,with_xft2=yes)
58         if test $with_xft2 = yes ; then
59                 if pkg-config --exists pangoxft '>=' 1.1.0 ; then
60                         AC_DEFINE(HAVE_XFT2,1,[Whether we have Xft2])
61                         wantedmodules="$wantedmodules pangoxft >= 1.1.0"
62                         wantedmodules="xft >= 2.0 $wantedmodules"
63                 else
64                         AC_MSG_WARN([Xft2 not detected])
65                 fi
66         fi
67 fi
68
69 # Use PangoX if we have it and it isn't disabled.
70 if test "$have_x" = yes ; then
71         AC_ARG_WITH(pangox,[AS_HELP_STRING(--with-pangox,enable drawing using PangoX)],with_pangox=$withval,with_pangox=yes)
72         if test $with_pangox = yes ; then
73                 if pkg-config --exists pangox ; then
74                         AC_DEFINE(HAVE_PANGOX,1,[Whether we have PangoX])
75                         wantedmodules="$wantedmodules pangox"
76                 else
77                         AC_MSG_WARN([PangoX not detected])
78                 fi
79         fi
80 fi
81
82 # Use glX if we have it and it isn't disabled.
83 if test "$have_x" = yes ; then
84         AC_ARG_WITH(glX,[AS_HELP_STRING(--with-glX,enable drawing using glX)],with_glx=$withval,with_glx=no)
85         if test $with_glx = yes ; then
86                 have_gl=0
87                 have_libgl=0
88                 AC_CHECK_HEADERS(GL/glx.h)
89                 if test $ac_cv_header_GL_glx_h = yes ; then
90                         AC_CHECK_FUNC(glXQueryExtension,[have_gl=1],AC_CHECK_LIB(GL,glXQueryExtension,[have_gl=1;have_libgl=1]))
91                 fi
92                 if test $have_gl = 1 ; then
93                         AC_DEFINE(HAVE_GL,1,[Whether we have GL and glX.])
94                 fi
95                 if test $have_libgl = 1 ; then
96                         LIBS="-lGLU -lGL $LIBS"
97                 fi
98         fi
99 fi
100
101 # Search for the required modules.
102 PKG_CHECK_MODULES(VTE,[$wantedmodules])
103 NEEDEDPACKAGES="$wantedmodules"
104 AC_SUBST(NEEDEDPACKAGES)
105
106 # Require Freetype2.  We use our local copy of the macro because packages of
107 # freetype's development files don't always include the proper macro.
108 VTE_CHECK_FT2(6.1.0,,[AC_MSG_ERROR([You must have freetype 2.0.2 or later to build vte.])])
109
110 # Temporarily pull in the Freetype cflags and libs for checking what's
111 # available in this version.
112 savecflags="$CFLAGS"
113 CFLAGS="$CFLAGS $FT2_CFLAGS"
114 savecppflags="$CPPFLAGS"
115 CPPFLAGS="$CPPFLAGS $FT2_CFLAGS"
116 if test -d "$ac_x_includes" ; then
117         CFLAGS="$CFLAGS -I$ac_x_includes"
118         CPPFLAGS="$CPPFLAGS -I$ac_x_includes"
119 fi
120 AC_CHECK_HEADERS(ft2build.h)
121 if test x$ac_cv_header_ft2build_h != xyes ; then
122         AC_MSG_ERROR([You must have freetype 2.0.2 or later to build vte.])
123 fi
124
125 AC_CHECK_DECL(ft_render_mode_mono,[AC_DEFINE(HAVE_DECL_ft_render_mode_mono,1,Define if your freetype2 installation defines ft_render_mode_mono.)],,[
126 #ifdef HAVE_FT2BUILD_H
127 #include <ft2build.h>
128 #include FT_FREETYPE_H
129 #endif
130 ])
131
132 AC_CHECK_DECL(FT_RENDER_MODE_MONO,[AC_DEFINE(HAVE_DECL_FT_RENDER_MODE_MONO,1,Define if your freetype2 installation defines FT_RENDER_MODE_MONO.)],,[
133 #ifdef HAVE_FT2BUILD_H
134 #include <ft2build.h>
135 #include FT_FREETYPE_H
136 #endif
137 ])
138
139 AC_CHECK_DECLS(FT_LOAD_NO_HINTING,,,[
140 #ifdef HAVE_FT2BUILD_H
141 #include <ft2build.h>
142 #include FT_FREETYPE_H
143 #endif
144 ])
145
146 AC_CHECK_DECLS(FT_RENDER_MODE_LIGHT,,,[
147 #ifdef HAVE_FT2BUILD_H
148 #include <ft2build.h>
149 #include FT_FREETYPE_H
150 #endif
151 ])
152
153 AC_CHECK_DECLS(FT_RENDER_MODE_NORMAL,,,[
154 #ifdef HAVE_FT2BUILD_H
155 #include <ft2build.h>
156 #include FT_FREETYPE_H
157 #endif
158 ])
159
160 AC_CHECK_DECL(FT_PIXEL_MODE_MONO,[AC_DEFINE(HAVE_DECL_FT_PIXEL_MODE_MONO,1,Define if your freetype2 build declares FT_PIXEL_MODE_MONO.)],,[
161 #ifdef HAVE_FT2BUILD_H
162 #include <ft2build.h>
163 #include FT_FREETYPE_H
164 #endif
165 ])
166 AC_CHECK_DECL(ft_pixel_mode_mono,[AC_DEFINE(HAVE_DECL_ft_pixel_mode_mono,1,Define if your freetype2 build declares ft_pixel_mode_mono.)],,[
167 #ifdef HAVE_FT2BUILD_H
168 #include <ft2build.h>
169 #include FT_FREETYPE_H
170 #endif
171 ])
172
173 AC_CHECK_DECLS(FT_PIXEL_MODE_GRAY2,,,[
174 #ifdef HAVE_FT2BUILD_H
175 #include <ft2build.h>
176 #include FT_FREETYPE_H
177 #endif
178 ])
179 AC_CHECK_DECLS(FT_PIXEL_MODE_GRAY4,,,[
180 #ifdef HAVE_FT2BUILD_H
181 #include <ft2build.h>
182 #include FT_FREETYPE_H
183 #endif
184 ])
185
186 AC_CHECK_DECL(FT_PIXEL_MODE_GRAY,[AC_DEFINE(HAVE_DECL_FT_PIXEL_MODE_GRAY,1,Define if your freetype2 build declares FT_PIXEL_MODE_GRAY.)],,[
187 #ifdef HAVE_FT2BUILD_H
188 #include <ft2build.h>
189 #include FT_FREETYPE_H
190 #endif
191 ])
192 AC_CHECK_DECL(ft_pixel_mode_grays,[AC_DEFINE(HAVE_DECL_ft_pixel_mode_grays,1,Define if your freetype2 build declares ft_pixel_mode_grays.)],,[
193 #ifdef HAVE_FT2BUILD_H
194 #include <ft2build.h>
195 #include FT_FREETYPE_H
196 #endif
197 ])
198
199 AC_CHECK_DECLS(FT_PIXEL_MODE_LCD,,,[
200 #ifdef HAVE_FT2BUILD_H
201 #include <ft2build.h>
202 #include FT_FREETYPE_H
203 #endif
204 ])
205
206 CFLAGS="$savecflags"
207 CPPFLAGS="$savecppflags"
208
209 # Use all available features under glibc, and disable accidental use of
210 # deprecated functionality.
211 AC_EGREP_CPP(glibc,
212                 [
213                  #include <stdio.h>
214                  #ifdef __GLIBC__
215                  glibc
216                  #endif
217                 ],
218                 AC_DEFINE(_GNU_SOURCE,1,[Use all glibc features.]))
219 AC_DEFINE(_XOPEN_SOURCE_EXTENDED,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
220 AC_DEFINE(_XOPEN_SOURCE,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
221 AC_DEFINE(__EXTENSIONS__,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
222
223 AC_ARG_ENABLE(deprecation,[AS_HELP_STRING(--enable-deprecation,prohibit VTE from using deprecated GLib/Pango/GDK/GTK+ features)],usedeprecation=$enableval,usedeprecation=no)
224 if test "$usedeprecation" = yes ; then
225 AC_DEFINE(G_DISABLE_DEPRECATED,1,[Disable deprecated GLib features.])
226 AC_DEFINE(GDK_DISABLE_DEPRECATED,1,[Disable deprecated GDK features.])
227 AC_DEFINE(GDK_PIXBUF_DISABLE_DEPRECATED,1,[Disable deprecated gdk-pixbuf features.])
228 AC_DEFINE(GTK_DISABLE_DEPRECATED,1,[Disable deprecated GTK+ features.])
229 AC_DEFINE(PANGO_DISABLE_DEPRECATED,1,[Disable deprecated Pango features.])
230 fi
231
232 # Miscellaneous definitions.
233 AC_DEFINE(VTE_UTF8_BPC,6,[Maximum number of bytes used per UTF-8 character.])
234 AC_DEFINE(VTE_INVALID_SOURCE,-1,[A number which can never be a valid source ID.])
235 AC_DEFINE_UNQUOTED(PACKAGE,"$PACKAGE",[Package name.])
236
237 # Check for headers.
238 AC_CHECK_HEADERS(sys/select.h sys/termios.h sys/un.h stropts.h termios.h wchar.h)
239 AC_HEADER_TIOCGWINSZ
240
241 # Check for PTY handling functions.
242 AC_CHECK_FUNCS(cfmakeraw getpgid getpt grantpt unlockpt ptsname ptsname_r)
243
244 # Pull in the right libraries for various functions which might not be
245 # bundled into an exploded libc.
246 AC_CHECK_FUNC(socket,[have_socket=1],AC_CHECK_LIB(socket,socket,[have_socket=1; LIBS="$LIBS -lsocket"]))
247 AC_CHECK_FUNC(socketpair,[have_socketpair=1],AC_CHECK_LIB(socket,socketpair,[have_socketpair=1; LIBS="$LIBS -lsocket"]))
248 AC_CHECK_FUNC(recvmsg,[have_recvmsg=1],AC_CHECK_LIB(socket,recvmsg,[have_recvmsg=1; LIBS="$LIBS -lsocket -lnsl"]))
249 if test x$have_socket = x1 ; then
250         AC_DEFINE(HAVE_SOCKET,1,[Define if you have the socket function.])
251 fi
252 if test x$have_socketpair = x1 ; then
253         AC_DEFINE(HAVE_SOCKETPAIR,1,[Define if you have the socketpair function.])
254 fi
255 if test x$have_recvmsg = x1 ; then
256         AC_DEFINE(HAVE_RECVMSG,1,[Define if you have the recvmsg function.])
257 fi
258 AC_CHECK_FUNC(floor,,AC_CHECK_LIB(m,floor,LIBS=["$LIBS -lm"]))
259
260 # Look for ncurses or curses or termcap.
261 AC_CHECK_HEADER(ncurses.h,[AC_CHECK_HEADER(term.h,[AC_CHECK_LIB(ncurses,tgetent,[LIBS="-lncurses $LIBS";AC_DEFINE(HAVE_NCURSES,1,[Define if you have ncurses.h and libncurses])])])])
262 if test x$ac_cv_lib_ncurses_tgetent != xyes ; then
263         AC_CHECK_HEADER(curses.h,[AC_CHECK_HEADER(term.h,[AC_CHECK_LIB(curses,tgetent,[LIBS="-lcurses $LIBS";AC_DEFINE(HAVE_CURSES,1,[Define if you have curses.h and libcurses])])])])
264         if test x$ac_cv_lib_curses_tgetent != xyes ; then
265                 AC_CHECK_HEADER(termcap.h,[AC_CHECK_LIB(termcap,tgetent,[LIBS="-ltermcap $LIBS";AC_DEFINE(HAVE_TERMCAP,1,[Define if you have termcap.h and libtermcap])])])
266                 if test x$ac_cv_header_termcap_h != xyes ; then
267                         AC_MSG_ERROR([You must have at least one of ncurses, curses, or libtermcap installed to build vte.])
268                 fi
269         fi
270 fi
271
272 # Save the names of these other libraries.
273 OTHERCFLAGS="$X_CFLAGS"
274 AC_SUBST(OTHERCFLAGS)
275 OTHERLIBS="$LIBS"
276 AC_SUBST(OTHERLIBS)
277
278 # Enable debugging messages and additional run-time checks.
279 AC_ARG_ENABLE(debugging,[AS_HELP_STRING(--enable-debugging,enable extra debugging checks and logging messages)],DEBUG=$enableval,DEBUG=no)
280 if test x$DEBUG != x ; then
281         if test x$DEBUG != xno ; then
282                 if test x$GCC = xyes ; then
283                         AC_CHECK_CC_OPT(-std=c99,vte_std_c99)
284                         CFLAGS="${CFLAGS} $vte_std_c99"
285                         CFLAGS="${CFLAGS} -Wall"
286                         CFLAGS="${CFLAGS} -Waggregate-return"
287                         CFLAGS="${CFLAGS} -Wcast-align"
288                         CFLAGS="${CFLAGS} -Wimplicit"
289                         CFLAGS="${CFLAGS} -Wmissing-declarations"
290                         CFLAGS="${CFLAGS} -Wmissing-prototypes"
291                         CFLAGS="${CFLAGS} -Wpointer-arith"
292                         CFLAGS="${CFLAGS} -Wstrict-prototypes"
293                         CFLAGS="${CFLAGS} -Wuninitialized"
294                         #CFLAGS="${CFLAGS} -Wsign-compare"
295                         #CFLAGS="${CFLAGS} -Wunused-value"
296                 fi
297                 VTE_DEBUG=1
298         fi
299 fi
300 if test x$VTE_DEBUG = x1 ; then
301         AC_MSG_RESULT([enabling debug checks and messages])
302         AC_DEFINE(VTE_DEBUG,1,[Enable debugging messages.])
303 fi
304
305 wcs_funcs_includes="
306 #ifdef HAVE_STRING_H
307 # if !STDC_HEADERS && HAVE_MEMORY_H
308 #  include <memory.h>
309 # endif
310 # include <string.h>
311 #else
312 # ifdef HAVE_STRINGS_H
313 #  include <strings.h>
314 # endif
315 #endif
316 #ifdef HAVE_WCHAR_H
317 # include <wchar.h>
318 #endif
319 "
320
321 AC_CHECK_TYPES(wint_t, AC_DEFINE(HAVE_WINT_T, , [Defined when the wint_t type is supported]), ,$wcs_funcs_includes)
322
323 # Search for Python.
324 BUILD_PYTHON=true
325 AC_ARG_ENABLE(python, [AS_HELP_STRING(--enable-python,Build python bindings [default=yes])],[
326 if test x"$enableval" != xno ; then
327         BUILD_PYTHON=true
328 else
329         BUILD_PYTHON=false
330 fi],BUILD_PYTHON=true)
331
332 if $BUILD_PYTHON ; then
333         AM_PATH_PYTHON
334         if test -z "$PYTHON" ; then
335                 BUILD_PYTHON=false
336         fi
337 fi
338
339 if $BUILD_PYTHON ; then
340         AC_MSG_CHECKING(for python >= 2.2)
341         prog="
342 import sys, string
343 minver = (2,2,0,'final',0)
344 if sys.version_info < minver:
345         sys.exit(1)
346 sys.exit(0)
347 "
348         if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
349         then
350                 AC_MSG_RESULT([okay])
351         else
352                 BUILD_PYTHON=false
353                 AC_MSG_RESULT([too old])
354         fi
355 fi
356
357 if $BUILD_PYTHON ; then
358         AM_CHECK_PYTHON_HEADERS(,BUILD_PYTHON=false)
359 fi
360
361 if $BUILD_PYTHON ; then
362         AC_MSG_CHECKING([for pygtk-2.0])
363         if pkg-config --exists pygtk-2.0 ; then
364                 AC_MSG_RESULT([found])
365                 PKG_CHECK_MODULES(PYGTK,[pygtk-2.0])
366
367                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
368                 if test "x$PYGTK_CODEGEN" = xno; then
369                   AC_MSG_ERROR(could not find pygtk-codegen-2.0 script)
370                 fi
371
372                 AC_MSG_CHECKING(for pygtk defs)
373                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
374                 AC_SUBST(PYGTK_DEFSDIR)
375                 AC_MSG_RESULT($PYGTK_DEFSDIR)
376         else
377                 AC_MSG_RESULT([not found])
378                 BUILD_PYTHON=false
379         fi
380 fi
381
382 if ! $BUILD_PYTHON ; then
383         AC_MSG_RESULT([Python bindings disabled.])
384 fi
385
386 AC_SUBST(PYTHONREV)
387 AC_SUBST(PYTHONMODULES)
388 AM_CONDITIONAL(BUILD_PYTHON_MODULES, $BUILD_PYTHON)
389
390 # If we can find libzvt on the system, set up to build a variant of "reflect"
391 # which uses it.
392 REFLECT_ZVT=false
393 if pkg-config --exists libzvt-2.0 ; then
394         REFLECT_ZVT=true
395         ZVT_DEFS=-DHAVE_ZVT
396         PKG_CHECK_MODULES(ZVT,[gtk+-2.0 libzvt-2.0])
397 fi
398 AC_SUBST(ZVT_DEFS)
399 AM_CONDITIONAL(REFLECT_USE_ZVT, $REFLECT_ZVT)
400
401 mylibdir=`eval echo $libdir`
402 mylibexecdir=`eval echo $libexecdir`
403 mydatadir=`eval echo $datadir`
404 if test x$exec_prefix = xNONE ; then
405         if test x$prefix = xNONE ; then
406                 mylibdir=` echo $mylibdir  | sed s,NONE,$ac_default_prefix,g`
407                 mylibexecdir=` echo $mylibexecdir  | sed s,NONE,$ac_default_prefix,g`
408         else
409                 mylibdir=` echo $mylibdir  | sed s,NONE,$prefix,g`
410                 mylibexecdir=` echo $mylibexecdir  | sed s,NONE,$prefix,g`
411         fi
412 fi
413 if test x$prefix = xNONE ; then
414         mydatadir=`echo $mydatadir | sed s,NONE,$ac_default_prefix,g`
415 fi
416 AC_DEFINE_UNQUOTED(PKGLIBDIR,"$mylibdir/$PACKAGE",
417                    [The location where package-specific helpers can be found.])
418 AC_DEFINE_UNQUOTED(LIBEXECDIR,"$mylibexecdir",
419                    [The location where package-specific helpers can be found.])
420 AC_DEFINE_UNQUOTED(DATADIR,"$mydatadir",
421                    [The location where arch-independent package-specific data can be found.])
422 AC_DEFINE_UNQUOTED(LOCALEDIR,"$mydatadir/locale",
423                    [The location where locale data can be found.])
424
425 GETTEXT_PACKAGE=vte
426 AC_SUBST(GETTEXT_PACKAGE)
427
428 AC_ARG_ENABLE(gnome-pty-helper, [AS_HELP_STRING(--enable-gnome-pty-helper,Build a setuid helper for opening ptys [default=yes])], enable_gnome_pty_helper="$enableval", enable_gnome_pty_helper=yes)
429 if test "$enable_gnome_pty_helper" != no; then
430         AC_DEFINE(VTE_USE_GNOME_PTY_HELPER,1,[Define if you intend to use gnome-pty-helper.])
431         AC_CONFIG_SUBDIRS(gnome-pty-helper)
432 fi
433 AM_CONDITIONAL(BUILD_GNOME_PTY_HELPER,[test "$enable_gnome_pty_helper" != no])
434
435 ################################################################################
436
437 # This is a check for gtk-doc which you can insert into your configure.in.
438 # You shouldn't need to change it at all.
439
440 ##################################################
441 # Check for gtk-doc.
442 ##################################################
443
444 AC_ARG_WITH(html-dir, [AS_HELP_STRING(--with-html-dir=PATH,path to installed docs)])
445
446 if test "x$with_html_dir" = "x" ; then
447   HTML_DIR='${datadir}/gtk-doc/html'
448 else
449   HTML_DIR=$with_html_dir
450 fi
451
452 AC_SUBST(HTML_DIR)
453
454 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
455
456 gtk_doc_min_version=0.6
457 if $GTKDOC ; then 
458     gtk_doc_version=`gtkdoc-mkdb --version`
459     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
460
461     IFS="${IFS=         }"; vte_save_IFS="$IFS"; IFS="."
462     set $gtk_doc_version
463     for min in $gtk_doc_min_version ; do
464         cur=$1; shift
465         if test -z $min ; then break; fi
466         if test -z $cur ; then GTKDOC=false; break; fi
467         if test $cur -gt $min ; then break ; fi
468         if test $cur -lt $min ; then GTKDOC=false; break ; fi
469     done
470     IFS="$vte_save_IFS"
471
472     if $GTKDOC ; then
473       AC_MSG_RESULT(yes)
474     else
475       AC_MSG_RESULT(no)
476     fi
477 fi
478
479 dnl Let people disable the gtk-doc stuff.
480 AC_ARG_ENABLE(gtk-doc, [AS_HELP_STRING(--enable-gtk-doc,Use gtk-doc to build documentation [default=auto])], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
481
482 if test x$enable_gtk_doc = xauto ; then
483   if test x$GTKDOC = xtrue ; then
484     enable_gtk_doc=yes
485   else
486     enable_gtk_doc=no 
487   fi
488 fi
489
490 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
491
492 ################################################################################
493
494 AM_CONFIG_HEADER(config.h)
495
496 AC_OUTPUT([
497 Makefile
498 src/Makefile
499 termcaps/Makefile
500 python/Makefile
501 po/Makefile.in
502 doc/Makefile
503 doc/openi18n/Makefile
504 doc/reference/Makefile
505 vte.pc
506 vte-uninstalled.pc
507 ])