d4f1a000e249c3c885f23bfa785e955acb1bbf37
[vte.git] / configure.in
1 m4_define([version_major],0)
2 m4_define([version_minor],27)
3 m4_define([version_micro],2)
4 m4_define([version_triplet],version_major.version_minor.version_micro)
5
6 m4_define([so_major_adjust],9) dnl Don't change!
7
8 AC_PREREQ([2.59])
9 AC_INIT(vte, [version_triplet], [http://bugzilla.gnome.org/enter_bug.cgi?product=vte])
10 AC_CONFIG_SRCDIR([src/vte.c])
11 AC_CONFIG_HEADERS([config.h])
12
13 AM_INIT_AUTOMAKE([1.9 foreign no-dist-gzip dist-bzip2])
14
15 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
16
17 if test -z "$enable_maintainer_mode"; then
18   enable_maintainer_mode=yes
19 fi
20 AM_MAINTAINER_MODE([enable])
21
22 ################################################################################
23 # Libtool versioning
24 ################################################################################
25 m4_define([lt_revision], m4_if(m4_eval(version_minor%2),1,0,version_micro))
26 m4_define([lt_age], m4_eval(version_minor*100+version_micro-lt_revision))
27 m4_define([lt_current], m4_eval(so_major_adjust+version_major+lt_age))
28 m4_define([lt_triplet],lt_current:lt_revision:lt_age)
29
30 LT_VERSION_INFO="lt_triplet()"
31 AC_SUBST([LT_VERSION_INFO])
32
33 ################################################################################
34 # GTK+
35 ################################################################################
36
37 AC_MSG_CHECKING([which gtk+ version to compile against])
38 AC_ARG_WITH([gtk],
39   [AS_HELP_STRING([--with-gtk=2.0|3.0],[which gtk+ version to compile against (default: 2.0)])],
40   [case "$with_gtk" in
41      2.0|3.0) ;;
42      *) AC_MSG_ERROR([invalid gtk version specified]) ;;
43    esac],
44   [with_gtk=2.0])
45 AC_MSG_RESULT([$with_gtk])
46
47 case "$with_gtk" in
48   2.0) VTE_API_VERSION=0.0
49        VTE_API_MAJOR_VERSION=0
50        VTE_API_MINOR_VERSION=0
51        VTE_PC_VERSION=
52        VTE_LIBRARY_SUFFIX=
53        VTE_SEAL_CFLAGS=
54        GTK_API_VERSION=2.0
55        GTK_REQUIRED=2.20.0
56        ;;
57   3.0) VTE_API_VERSION=2.90
58        VTE_API_MAJOR_VERSION=2
59        VTE_API_MINOR_VERSION=90
60        VTE_PC_VERSION=-$VTE_API_VERSION
61        VTE_LIBRARY_SUFFIX=$VTE_API_VERSION
62        VTE_SEAL_CFLAGS="-DVTE_SEAL_ENABLE"
63        GTK_API_VERSION=3.0
64        GTK_REQUIRED=2.91.0
65        ;;
66 esac
67
68 AC_SUBST([VTE_API_VERSION])
69 AC_SUBST([VTE_API_VERSION_U],[AS_TR_SH([$VTE_API_VERSION])])
70 AC_SUBST([VTE_API_MAJOR_VERSION])
71 AC_SUBST([VTE_API_MINOR_VERSION])
72 AC_SUBST([VTE_PC_VERSION])
73 AC_SUBST([VTE_SEAL_CFLAGS])
74 AC_SUBST([GTK_API_VERSION])
75 AC_SUBST([VTE_LIBRARY_SUFFIX_U],[AS_TR_SH([$VTE_LIBRARY_SUFFIX])])
76
77 AM_CONDITIONAL([HAVE_GTK_2],[test "$with_gtk" = "2.0"])
78 AM_CONDITIONAL([HAVE_GTK_3],[test "$with_gtk" = "3.0"])
79
80 ################################################################################
81
82 AC_ISC_POSIX
83 AC_PROG_CC
84 AC_STDC_HEADERS
85 AM_PROG_CC_STDC
86
87 AM_PROG_CC_C_O
88
89 AM_PROG_LIBTOOL
90
91 AC_PROG_SED
92
93 ################################################################################
94 # i18n
95 ################################################################################
96
97 IT_PROG_INTLTOOL([0.35.0])
98
99 GETTEXT_PACKAGE=vte-$VTE_API_VERSION
100 AC_SUBST(GETTEXT_PACKAGE)
101 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",
102                    [Package translatable messages domain name.])
103 AM_GLIB_GNU_GETTEXT
104 AC_CHECK_DECLS(bind_textdomain_codeset,,,[#include "libintl.h"])
105
106
107 ################################################################################
108 # Platform checks
109 ################################################################################
110
111 AC_MSG_CHECKING([for a win32 platform])
112 platform_win32=no
113 case "$host" in
114         *-*-mingw*|*-*-cygwin*)
115                 platform_win32=yes
116                 ;;
117 esac
118 AC_MSG_RESULT([$platform_win32])
119 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
120
121 os_win32=no
122 if test "x$platform_win32" = "xyes"; then
123         AC_MSG_CHECKING([for native win32])
124         case "$host" in
125                 *-*-mingw*)
126                         os_win32=yes
127                         ;;
128         esac
129         AC_MSG_RESULT([$os_win32])
130 fi
131 AM_CONDITIONAL(OS_WIN32, test "x$os_win32" = "xyes")
132
133
134 if test "x$platform_win32" != "xyes"; then
135         LIBTOOL_EXPORT_OPTIONS=
136 else
137         LIBTOOL_EXPORT_OPTIONS='-no-undefined'
138 fi
139 AC_SUBST([LIBTOOL_EXPORT_OPTIONS])
140 LIBTOOL_FLAGS='-as-needed'
141 AC_SUBST([LIBTOOL_FLAGS])
142
143
144 ################################################################################
145 # Compilation
146 ################################################################################
147
148 dnl Use lots of warning flags with with gcc and compatible compilers
149 dnl Copied from cairo
150 AC_DEFUN([VTE_CC_TRY_FLAG], [
151   AC_MSG_CHECKING([whether $CC supports $1])
152
153   vte_save_CFLAGS="$CFLAGS"
154   CFLAGS="$CFLAGS $1"
155
156   AC_COMPILE_IFELSE([ ], [vte_cc_flag=yes], [vte_cc_flag=no])
157   CFLAGS="$vte_save_CFLAGS"
158
159   if test "x$vte_cc_flag" = "xyes"; then
160     ifelse([$2], , :, [$2])
161   else
162     ifelse([$3], , :, [$3])
163   fi
164   AC_MSG_RESULT([$vte_cc_flag])
165 ])
166 AC_DEFUN([VTE_LD_TRY_FLAG], [
167   AC_MSG_CHECKING([whether $CC supports $1 when linking])
168
169   vte_save_LDFLAGS="$LDFLAGS"
170   LDFLAGS="$LDFLAGS $1"
171
172   AC_LINK_IFELSE([int main(void) {return 0;}],
173                 [vte_ld_flag=yes], [vte_ld_flag=no])
174   LDFLAGS="$vte_save_LDFLAGS"
175
176   if test "x$vte_ld_flag" = "xyes"; then
177     ifelse([$2], , :, [$2])
178   else
179     ifelse([$3], , :, [$3])
180   fi
181   AC_MSG_RESULT([$vte_ld_flag])
182 ])
183
184
185 dnl Note: if you change the following variable, the cache is automatically
186 dnl skipped and all flags rechecked.  So there's no need to do anything
187 dnl else.  If for any reason you need to force a recheck, just change
188 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
189
190 MAYBE_WARN="-Wall -Wextra \
191 -Wsign-compare -Werror-implicit-function-declaration \
192 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
193 -Waggregate-return -Wcast-align -Wimplicit -Wuninitialised \
194 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
195 -Wpacked -Wmissing-format-attribute -Wshadow \
196 -Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
197 -Wdeclaration-after-statement -Wold-style-definition \
198 -Wno-missing-field-initializers -Wno-unused-parameter \
199 -fno-common -Wno-switch-enum"
200
201 # invalidate cached value if MAYBE_WARN has changed
202 if test "x$vte_cv_warn_maybe" != "x$MAYBE_WARN"; then
203         unset vte_cv_warn_cflags
204 fi
205 AC_CACHE_CHECK([for supported warning flags], vte_cv_warn_cflags, [
206         echo
207         WARN_CFLAGS=""
208
209         # Some warning options are not supported by all versions of
210         # gcc, so test all desired options against the current
211         # compiler.
212         #
213         # Note that there are some order dependencies
214         # here. Specifically, an option that disables a warning will
215         # have no net effect if a later option then enables that
216         # warnings, (perhaps implicitly). So we put some grouped
217         # options (-Wall and -Wextra) up front and the -Wno options
218         # last.
219
220         for W in $MAYBE_WARN; do
221                 VTE_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
222         done
223
224         vte_cv_warn_cflags=$WARN_CFLAGS
225         vte_cv_warn_maybe=$MAYBE_WARN
226
227         AC_MSG_CHECKING([which warning flags were supported])])
228 WARN_CFLAGS=$vte_cv_warn_cflags
229 AC_SUBST(WARN_CFLAGS)
230 CFLAGS="$CFLAGS $WARN_CFLAGS"
231
232 PYTHON_LDFLAGS=""
233 for W in "-Wl,--warn-unresolved-symbols"; do
234         VTE_LD_TRY_FLAG([$W], [PYTHON_LDFLAGS="$PYTHON_LDFLAGS $W"])
235 done
236 AC_SUBST(PYTHON_LDFLAGS)
237
238 # Enable debugging messages and additional run-time checks.
239 AC_ARG_ENABLE(debug,
240               [AS_HELP_STRING([--enable-debug],
241                               [enable extra debugging checks and logging messages]
242                               )],
243               DEBUG=$enableval, DEBUG=no)
244 if test "x$DEBUG" != "xno" ; then
245         AC_MSG_RESULT([enabling debug checks and messages])
246         AC_DEFINE(VTE_DEBUG,1,[Enable debugging messages.])
247 fi
248
249 ##########################################################
250 # Check for -Bsymbolic-functions linker flag used to avoid
251 # intra-library PLT jumps, if available.
252 ##########################################################
253
254 AC_ARG_ENABLE([Bsymbolic],
255   [AS_HELP_STRING([--disable-Bsymbolic],
256                   [disable linking with -Bsymbolic])],
257   [],[enable_Bsymbolic=yes])
258
259 VTE_LDFLAGS=
260 if test "$enable_Bsymbolic" != "no"; then
261   FLAG="-Wl,-Bsymbolic-functions"
262   VTE_LD_TRY_FLAG([$FLAG],
263     [VTE_LDFLAGS="$VTE_LDFLAGS $FLAG"],
264     [if test "$enable_Bsymbolic" = "auto"; then
265        AC_MSG_WARN([-Bsymbolic not supported by ld; disabling])
266        enable_Bsymbolic=no
267      else
268        AC_MSG_ERROR([-Bsymbolic requested but not supported by ld])
269      fi])
270 fi
271
272 AC_SUBST([VTE_LDFLAGS])
273
274 ################################################################################
275
276 GNOME_COMMON_INIT
277
278 # Disable deprecations and single includes
279 # We don't use GNOME_MAINTAINER_MODE_DEFINES here since it's too much and
280 # it also defines VTE's own defines.
281 dnl AC_ARG_ENABLE([deprecation],
282 dnl   [AS_HELP_STRING([--disable-deprecation],
283 dnl                   [prohibit VTE from using deprecated GLib/Pango/ATK/GDK/GTK+ features])],
284 dnl   [],[enable_deprecation=$enable_maintainer_mode])
285 dnl if test "x$enable_deprecation" = xyes; then
286 dnl   AC_MSG_NOTICE([disabling deprecated GLIB/PANGO/GDK/ATK/GTK+ features])
287 dnl 
288 dnl   AC_DEFINE([ATK_DISABLE_DEPRECATED],[1],[Disable deprecated features])
289 dnl   AC_DEFINE([ATK_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
290 dnl   AC_DEFINE([G_DISABLE_DEPRECATED],[1],[Disable deprecated features])
291 dnl   AC_DEFINE([G_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
292 dnl   AC_DEFINE([GDK_DISABLE_DEPRECATED],[1],[Disable deprecated features])
293 dnl   AC_DEFINE([GDK_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
294 dnl   AC_DEFINE([GDK_PIXBUF_DISABLE_DEPRECATED],[1],[Disable deprecated features])
295 dnl   AC_DEFINE([GDK_PIXBUF_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
296 dnl   AC_DEFINE([GTK_DISABLE_DEPRECATED],[1],[Disable deprecated features])
297 dnl   AC_DEFINE([GTK_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
298 dnl   AC_DEFINE([PANGO_DISABLE_DEPRECATED],[1],[Disable deprecated features])
299 dnl   AC_DEFINE([PANGO_DISABLE_SINGLE_INCLUDES],[1],[Disable single includes])
300 dnl fi
301
302 ################################################################################
303 # Core
304 ################################################################################
305
306 # Use all available features under glibc, and disable accidental use of
307 # deprecated functionality.
308 AC_EGREP_CPP(glibc,
309                 [
310                  #include <stdio.h>
311                  #ifdef __GLIBC__
312                  glibc
313                  #endif
314                 ],
315                 AC_DEFINE(_GNU_SOURCE,1,[Use all glibc features.]))
316
317 case $host in
318 *-*-solaris*)
319         AC_DEFINE(_XOPEN_SOURCE_EXTENDED,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
320         AC_DEFINE(_XOPEN_SOURCE,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
321         AC_DEFINE(__EXTENSIONS__,1,[Needed to get declarations for msg_control and msg_controllen on Solaris])
322         ;;
323 esac
324
325 GLIB_REQUIRED=2.22.0
326 PANGO_REQUIRED=1.22.0
327 AC_DEFINE(GDK_MULTIHEAD_SAFE,1,[Force use of GDK's multihead-safe APIs.])
328 PKG_CHECK_MODULES(GLIB,[glib-2.0 > $GLIB_REQUIRED gobject-2.0])
329 PKG_CHECK_MODULES(GTK,[glib-2.0 >= $GLIB_REQUIRED gobject-2.0 gtk+-$GTK_API_VERSION >= $GTK_REQUIRED])
330
331 AC_PATH_PROG([GLIB_GENMARSHAL],[glib-genmarshal])
332 AC_PATH_PROG([GLIB_MKENUMS],[glib-mkenums])
333
334 # Let the user specify the default terminal emulation.
335 AC_ARG_WITH(default-emulation,
336 AS_HELP_STRING(--with-default-emulation=xterm,default terminal type to be emulated),
337 emulation=$withval,emulation=xterm)
338 AC_DEFINE_UNQUOTED(VTE_DEFAULT_EMULATION,"$emulation",[The default terminal type to be emulated.])
339 VTE_DEFAULT_EMULATION=$emulation
340 AC_SUBST(VTE_DEFAULT_EMULATION)
341 AM_CONDITIONAL(VTE_DEFAULT_EMULATION, [test "$emulation" != xterm])
342
343 # Check for headers.
344 AC_CHECK_HEADERS(sys/select.h sys/syslimits.h sys/termios.h sys/un.h sys/wait.h stropts.h termios.h wchar.h)
345 AC_HEADER_TIOCGWINSZ
346
347 # Check for PTY handling functions.
348 AC_CHECK_FUNCS([cfmakeraw fork setsid setpgid getpgid getpt grantpt unlockpt ptsname ptsname_r tcgetattr tcsetattr])
349
350 # Pull in the right libraries for various functions which might not be
351 # bundled into an exploded libc.
352 AC_CHECK_FUNC(socket,[have_socket=1],AC_CHECK_LIB(socket,socket,[have_socket=1; LIBS="$LIBS -lsocket"]))
353 AC_CHECK_FUNC(socketpair,[have_socketpair=1],AC_CHECK_LIB(socket,socketpair,[have_socketpair=1; LIBS="$LIBS -lsocket"]))
354 AC_CHECK_FUNC(recvmsg,[have_recvmsg=1],AC_CHECK_LIB(socket,recvmsg,[have_recvmsg=1; LIBS="$LIBS -lsocket -lnsl"]))
355 if test x$have_socket = x1 ; then
356         AC_DEFINE(HAVE_SOCKET,1,[Define if you have the socket function.])
357 fi
358 if test x$have_socketpair = x1 ; then
359         AC_DEFINE(HAVE_SOCKETPAIR,1,[Define if you have the socketpair function.])
360 fi
361 if test x$have_recvmsg = x1 ; then
362         AC_DEFINE(HAVE_RECVMSG,1,[Define if you have the recvmsg function.])
363 fi
364 AC_CHECK_FUNC(floor,,AC_CHECK_LIB(m,floor,LIBS=["$LIBS -lm"]))
365 AC_CHECK_FUNCS([ceil floor])
366
367 # Look for tgetent
368
369 AC_CHECK_FUNC([tgetent],[vte_cv_termcap_lib=libc],
370   [AC_CHECK_LIB([ncurses],[tgetent],[vte_cv_termcap_lib=libncurses],
371     [AC_CHECK_LIB([tinfo],[tgetent],[vte_cv_termcap_lib=libtinfo],
372       [AC_CHECK_LIB([curses],[tgetent],[vte_cv_termcap_lib=libcurses],
373         [AC_CHECK_LIB([termcap],[tgetent],[vte_cv_termcap_lib=libtermcap],
374           [vte_cv_termcap_lib=])])])])])
375
376 case "$vte_cv_termcap_lib" in
377   libc)       # FIXME: which headers to include here?
378               ;;
379   libncurses) # We need ncurses.h and term.h, or ncurses/curses.h and ncurses/term.h
380               AC_CHECK_HEADERS([ncurses.h term.h],[],
381                 [AC_CHECK_HEADERS([ncurses/curses.h ncurses/term.h],[],
382                   [AC_MSG_ERROR([ncurses headers not found])])])
383               LIBS="-lncurses $LIBS"
384               ;;
385   libtinfo)   # Need ncurses/curses.h and ncurses/term.h
386               AC_CHECK_HEADERS([ncurses.h term.h],[],
387                 [AC_CHECK_HEADERS([ncurses/curses.h ncurses/term.h],[],
388                   [AC_MSG_ERROR([ncurses headers not found])])])
389               LIBS="-ltinfo $LIBS"
390               ;;
391   libcurses)  # Need curses.h and term.h
392               AC_CHECK_HEADERS([curses.h term.h],[],
393                 [AC_MSG_ERROR([curses headers not found])],
394                 [[#ifdef HAVE_CURSES_H
395                   #include <curses.h>
396                   #endif]])
397               LIBS="-lcurses $LIBS"
398               ;;
399   libtermcap) # Need termcap.h
400               AC_CHECK_HEADERS([termcap.h],[],
401                 [AC_MSG_ERROR([termcap headers not found])])
402               LIBS="-ltermcap $LIBS"
403               ;;
404   *)          AC_MSG_ERROR([tgetent not found in any library]) ;;
405 esac
406
407 # Search for the required modules.
408
409 # We have a direct dependency on X11 on gdk-x11, see bug #613525
410 AC_MSG_CHECKING([for GDK target])
411 GDK_TARGET="$($PKG_CONFIG --variable target gdk-$GTK_API_VERSION)"
412 AC_MSG_RESULT([$GDK_TARGET])
413 case "$GDK_TARGET" in
414   x11) PLATFORM_PKGS="x11 cairo-xlib" ;;
415   *) PLATFORM_PKGS="" ;;
416 esac
417
418 VTE_PKGS="glib-2.0 >= $GLIB_REQUIRED gobject-2.0 pango >= $PANGO_REQUIRED gtk+-$GTK_API_VERSION >= $GTK_REQUIRED gobject-2.0 gio-2.0 gio-unix-2.0 $PLATFORM_PKGS"
419 PKG_CHECK_MODULES([VTE],[$VTE_PKGS])
420 AC_SUBST([VTE_PKGS])
421
422 wcs_funcs_includes="
423 #ifdef HAVE_STRING_H
424 # if !STDC_HEADERS && HAVE_MEMORY_H
425 #  include <memory.h>
426 # endif
427 # include <string.h>
428 #else
429 # ifdef HAVE_STRINGS_H
430 #  include <strings.h>
431 # endif
432 #endif
433 #ifdef HAVE_WCHAR_H
434 # include <wchar.h>
435 #endif
436 "
437
438 AC_CHECK_TYPES(wint_t, AC_DEFINE(HAVE_WINT_T, , [Defined when the wint_t type is supported]), ,$wcs_funcs_includes)
439
440
441 ################################################################################
442 # Auxillary modules
443 ################################################################################
444
445 if test "$with_gtk" = "2.0"; then
446
447 # Search for Python.
448 BUILD_PYTHON=true
449 AC_ARG_ENABLE(python, [AS_HELP_STRING(--enable-python,Build python bindings [default=yes])],[
450 if test x"$enableval" != xno ; then
451         BUILD_PYTHON=true
452 else
453         BUILD_PYTHON=false
454 fi],BUILD_PYTHON=true)
455
456 if $BUILD_PYTHON ; then
457         AM_PATH_PYTHON
458         if test -z "$PYTHON" ; then
459                 BUILD_PYTHON=false
460         fi
461 fi
462
463 if $BUILD_PYTHON ; then
464         AC_MSG_CHECKING(for python >= 2.2)
465         prog="
466 import sys, string
467 minver = (2,2,0,'final',0)
468 if sys.version_info < minver:
469         sys.exit(1)
470 sys.exit(0)
471 "
472         if $PYTHON -c "$prog" 1>&AC_FD_CC 2>&AC_FD_CC
473         then
474                 AC_MSG_RESULT([okay])
475         else
476                 BUILD_PYTHON=false
477                 AC_MSG_RESULT([too old])
478         fi
479 fi
480
481 if $BUILD_PYTHON ; then
482         AM_CHECK_PYTHON_HEADERS(,BUILD_PYTHON=false)
483 fi
484
485 if $BUILD_PYTHON ; then
486         AC_MSG_CHECKING([for pygtk-2.0])
487         if pkg-config --exists pygtk-2.0 ; then
488                 AC_MSG_RESULT([found])
489                 PKG_CHECK_MODULES(PYGTK,[pygtk-2.0])
490
491                 AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
492                 if test "x$PYGTK_CODEGEN" = xno; then
493                   AC_MSG_ERROR(could not find pygtk-codegen-2.0 script)
494                 fi
495
496                 AC_MSG_CHECKING(for pygtk defs)
497                 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
498                 AC_SUBST(PYGTK_DEFSDIR)
499                 AC_MSG_RESULT($PYGTK_DEFSDIR)
500         else
501                 AC_MSG_RESULT([not found])
502                 BUILD_PYTHON=false
503         fi
504 fi
505
506 if ! $BUILD_PYTHON ; then
507         AC_MSG_RESULT([Python bindings disabled.])
508 fi
509
510 AC_SUBST(PYTHONREV)
511 AC_SUBST(PYTHONMODULES)
512
513 else # with_gtk = 3.0
514   BUILD_PYTHON=false
515 fi # with_gtk = 2.0
516
517 AM_CONDITIONAL(BUILD_PYTHON_MODULES, $BUILD_PYTHON)
518
519 ################################################################################
520 # GNOME PTY Helper
521 ################################################################################
522
523 AC_ARG_ENABLE(gnome-pty-helper, [AS_HELP_STRING(--enable-gnome-pty-helper,Build a setuid helper for opening ptys [default=yes])], enable_gnome_pty_helper="$enableval", enable_gnome_pty_helper=yes)
524 if test "$enable_gnome_pty_helper" != no; then
525         AC_DEFINE(VTE_USE_GNOME_PTY_HELPER,1,[Define if you intend to use gnome-pty-helper.])
526         AC_CONFIG_SUBDIRS(gnome-pty-helper)
527 fi
528 AM_CONDITIONAL(BUILD_GNOME_PTY_HELPER,[test "$enable_gnome_pty_helper" != no])
529
530 ################################################################################
531 # Glade catalogue
532 ################################################################################
533
534 AC_MSG_CHECKING([whether to install the glade catalogue])
535 AC_ARG_ENABLE([glade-catalogue],
536   [AS_HELP_STRING([--disable-glade],[Disable installing the glade catalogue])],
537   [],[enable_glade_catalogue=no])
538 AC_MSG_RESULT([$enable_glade_catalogue])
539
540 if test "$enable_glade_catalogue" = "yes"; then
541   GLADE_CATALOGUE_DIR="$($PKG_CONFIG --variable=catalogdir gladeui-1.0)"
542   GLADE_ICON_DIR="$($PKG_CONFIG --variable=pixmapdir gladeui-1.0)"
543   GLADE_MODULE_DIR="$($PKG_CONFIG --variable=moduledir gladeui-1.0)"
544
545   if test -z "$GLADE_CATALOGUE_DIR" -o -z "$GLADE_MODULE_DIR"; then
546     AC_MSG_ERROR([gladeui-1.0 not found])
547   fi
548
549   AC_SUBST([GLADE_CATALOGUE_DIR])
550   AC_SUBST([GLADE_ICON_DIR])
551   AC_SUBST([GLADE_MODULE_DIR])
552 fi
553   
554 AM_CONDITIONAL([ENABLE_GLADE_CATALOGUE],[test "$enable_glade_catalogue" = "yes"])
555
556 # *************
557 # Introspection
558 # *************
559
560 # No automagic please!
561 if test -z "$enable_introspection"; then
562   enable_introspection=no
563 fi
564
565 GOBJECT_INTROSPECTION_CHECK([0.6.7])
566
567 ################################################################################
568
569 GTK_DOC_CHECK([1.13],[--flavour no-tmpl])
570
571 AC_SUBST([GLIB_PREFIX],[$($PKG_CONFIG --variable=prefix glib-2.0)])
572 AC_SUBST([GTK_PREFIX],[$($PKG_CONFIG --variable=prefix gtk+-$GTK_API_VERSION)])
573
574 ################################################################################
575
576 AC_SUBST([VTE_MAJOR_VERSION],[version_major])
577 AC_SUBST([VTE_MINOR_VERSION],[version_minor])
578 AC_SUBST([VTE_MICRO_VERSION],[version_micro])
579
580 ################################################################################
581
582 AC_CONFIG_FILES([
583 Makefile
584 src/Makefile
585 src/vteversion.h
586 termcaps/Makefile
587 perf/Makefile
588 python/Makefile
589 python/pyvte.pc
590 po/Makefile.in
591 doc/Makefile
592 doc/openi18n/Makefile
593 doc/reference/Makefile
594 doc/reference/version.xml
595 glade/Makefile
596 ])
597
598 AC_CONFIG_FILES([vte${VTE_PC_VERSION}.pc:vte.pc.in],[VTE_PC_VERSION=${VTE_PC_VERSION}])
599 AC_CONFIG_FILES([vte${VTE_PC_VERSION}-uninstalled.pc:vte-uninstalled.pc.in],[VTE_PC_VERSION=${VTE_PC_VERSION}])
600
601 AC_OUTPUT
602
603 #####################
604 # Print configuration
605 #####################
606 cat <<EOF | tee -a config.log
607
608 ## -------------- ##
609 ## Configuration. ##
610 ## -------------- ##
611
612 Configuration for libvte $VERSION for gtk+-$GTK_API_VERSION
613         Installing Glade catalogue: $enable_glade_catalogue
614         Debugging: $DEBUG
615         Disallow deprecated features: $enable_deprecation
616 EOF