Remove foralls with empty variable list
[darcs-mirror-polyfix.git] / Expr.hs
1 {-# LANGUAGE PatternGuards, DeriveDataTypeable   #-}
2 module Expr where
3
4 import Data.List
5 import Data.Maybe
6 import ParseType
7
8 -- import Debug.Trace
9
10 import Data.Generics hiding (typeOf)
11 import Data.Generics.Schemes
12
13 data TypedExpr = TypedExpr
14         { unTypeExpr    :: Expr
15         , typeOf        :: Typ
16         } deriving (Eq, Typeable, Data)
17
18 typedLeft, typedRight :: Expr -> Typ -> TypedExpr
19 typedLeft  e t = TypedExpr e (instType False t)
20 typedRight e t = TypedExpr e (instType True t)
21
22 data EVar = F
23           | FromTypVar Int
24           | FromParam Int Bool
25             deriving (Eq, Ord, Typeable, Data)
26
27 data Expr
28         = Var EVar
29         | App Expr Expr
30         | Conc [Expr] -- Conc [] is Id
31         | Lambda Expr Expr
32         | Pair Expr Expr
33         | Map
34         | Const Expr
35         | ELeft Expr
36         | ERight Expr
37         | CaseUnit Expr Expr
38         | EitherMap
39         | HeadMap
40         | EUnit
41         | Singleton Expr
42         | Zero
43         | Bottom
44             deriving (Eq, Typeable, Data)
45
46 data LambdaBE = CurriedEquals Typ
47               | LambdaBE TypedExpr TypedExpr BoolExpr
48             deriving (Eq, Typeable, Data)
49
50 data BoolExpr 
51         = Equal Expr Expr
52         | And [BoolExpr] -- And [] is True
53         | AllZipWith LambdaBE Expr Expr
54         | AndEither  LambdaBE LambdaBE Expr Expr
55         | Condition [TypedExpr] BoolExpr BoolExpr
56         | UnpackPair TypedExpr TypedExpr TypedExpr BoolExpr
57         | TypeVarInst Bool Int BoolExpr
58             deriving (Eq, Typeable, Data)
59
60 -- Smart constructors
61
62 -- | Try eta reduction
63 equal :: TypedExpr -> TypedExpr -> BoolExpr
64 equal te1 te2 | typeOf te1 /= typeOf te2 = error "Type mismatch in equal"
65               | otherwise                = equal' (unTypeExpr te1) (unTypeExpr te2)
66
67 equal' :: Expr -> Expr -> BoolExpr
68 equal' e1 e2  | (Just (lf,lv)) <- isFunctionApplication e1
69               , (Just (rf,rv)) <- isFunctionApplication e2
70               , lv == rv 
71               , False
72                                          = equal' lf rf
73               -- This makes it return True...
74               | e1 == e2                 = beTrue
75               | otherwise                = Equal e1 e2
76
77 -- | If e is of the type (app f1 (app f2 .. (app fn x)..)),
78 --   return Just (f1 . f2. ... . fn, x)
79 isFunctionApplication :: Expr -> Maybe (Expr, Expr)
80 isFunctionApplication (App f e') | (Just (inner,v)) <- isFunctionApplication e'
81                                  = Just (conc f inner, v)
82                                  | otherwise
83                                  = Just (f, e')
84 isFunctionApplication _          = Nothing
85
86
87 -- | If both bound variables are just functions, we can replace this
88 --   by a comparison
89 unpackPair :: TypedExpr -> TypedExpr -> TypedExpr -> BoolExpr -> BoolExpr
90 unpackPair v1 v2 te be | Just subst1 <- findReplacer v1 be
91                        , Just subst2 <- findReplacer v2 be
92                        = subst1. subst2 $ (pair v1 v2 `equal` te) `aand` be
93
94 -- | Don’t unpack pair if vars are not used
95 unpackPair v1 v2 te be | not (v1 `occursIn` be || v2 `occursIn` be)
96                        = be
97 -- | If the whole tuple is a function, we can replace this
98 --   by a comparison
99 unpackPair v1 v2 te be | Just subst <- findReplacer (pair v1 v2) be
100                        = subst $ (pair v1 v2 `equal` te) `aand` be
101 -- | Nothing to optimize
102 unpackPair v1 v2 te be = UnpackPair v1 v2 te be
103
104 pair :: TypedExpr -> TypedExpr -> TypedExpr
105 pair (TypedExpr e1 t1) (TypedExpr e2 t2) = TypedExpr (Pair e1 e2) (TPair t1 t2)
106
107 lambdaBE :: TypedExpr -> TypedExpr -> BoolExpr -> LambdaBE
108 lambdaBE v1 v2 rel | typeOf v1 == typeOf v2 
109                    , rel == v1 `equal` v2    = CurriedEquals (typeOf v1)
110                    | otherwise               = LambdaBE v1 v2 rel
111
112 andEither :: LambdaBE -> LambdaBE -> TypedExpr -> TypedExpr -> BoolExpr
113 andEither (CurriedEquals _) (CurriedEquals _) e1 e2 = e1 `equal` e2
114 andEither lbe1 lbe2 e1 e2 | Just f1 <- arg1IsFunc lbe1
115                           , Just f2 <- arg1IsFunc lbe2
116                           = e1 `equal` eitherE f1 f2 e2
117                           | Just f1 <- arg2IsFunc lbe1
118                           , Just f2 <- arg2IsFunc lbe2
119                           = eitherE f1 f2 e1 `equal` e2
120                           | otherwise
121                           = andEither' lbe1 lbe2 (unTypeExpr e1) (unTypeExpr e2)
122
123 andEither' :: LambdaBE -> LambdaBE -> Expr -> Expr -> BoolExpr
124 andEither' (LambdaBE v1 v2 rel) _ (ELeft e1) (ELeft e2)
125        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
126 andEither' _ (LambdaBE v1 v2 rel) (ERight e1) (ERight e2)
127        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
128 andEither' lbe1 lbe2 e1 e2
129        = AndEither lbe1 lbe2 e1 e2
130
131
132 arg1IsFunc :: LambdaBE -> Maybe TypedExpr
133 arg1IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
134 arg1IsFunc (LambdaBE v1 v2 rel) | Just v1' <- defFor v1 rel
135                                 = Just (lambda v2 v1')
136                                 | otherwise = Nothing
137
138 arg2IsFunc :: LambdaBE -> Maybe TypedExpr
139 arg2IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
140 arg2IsFunc (LambdaBE v1 v2 rel) | Just v2' <- defFor v2 rel
141                                 = Just (lambda v1 v2')
142                                 | otherwise = Nothing
143
144 allZipWith :: TypedExpr -> TypedExpr -> BoolExpr -> TypedExpr -> TypedExpr -> BoolExpr
145 allZipWith v1 v2 rel e1 e2 | Just v1' <- defFor v1 rel =
146                                 e1 `equal` amap (lambda v2 v1') e2
147                            | Just v2' <- defFor v2 rel =
148                                 amap (lambda v1 v2') e1 `equal` e2
149                            | otherwise =
150                                 AllZipWith (LambdaBE v1 v2 rel) (unTypeExpr e1) (unTypeExpr e2)
151
152 eitherE :: TypedExpr -> TypedExpr -> TypedExpr -> TypedExpr
153 eitherE f1 f2 e | Arrow lt1 lt2 <- typeOf f1
154                 , Arrow rt1 rt2 <- typeOf f2
155                 , TEither lt rt <- typeOf e
156                 , lt1 == lt
157                 , rt1 == rt
158         = let tEither = TypedExpr EitherMap (Arrow (typeOf f1) (Arrow (typeOf f2) (Arrow (typeOf e) (TEither lt2 rt2))))
159           in  app (app (app tEither f1) f2) e
160                 | otherwise = error $ "Type error in eitherE\n" ++ show (f1, f2, e)
161
162 amap :: TypedExpr -> TypedExpr -> TypedExpr
163 amap tf tl | Arrow t1 t2 <- typeOf tf
164            , List t      <- typeOf tl
165            , t1 == t
166            = let tMap = TypedExpr Map (Arrow (Arrow t1 t2) (Arrow (List t1) (List t2)))
167              in app (app tMap tf) tl
168            | otherwise = error "Type error in map"
169
170 aand :: BoolExpr -> BoolExpr -> BoolExpr
171 aand (And xs) (And ys) = And (xs  ++ ys)
172 aand (And xs) y        = And (xs  ++ [y])
173 aand x        (And ys) = And ([x] ++ ys)
174 aand x        y        = And ([x,y])
175
176 beTrue :: BoolExpr
177 beTrue = And []
178
179 -- | Optimize a forall condition
180 condition :: [TypedExpr] -> BoolExpr -> BoolExpr -> BoolExpr
181 -- empty variable list
182 condition [] cond concl   = concl
183 -- float out conditions on the right
184 condition vars cond (Condition vars' cond' concl')
185                           = condition (vars ++ vars') (cond `aand` cond') concl'
186
187 -- Try to find variables that are functions of other variables, and remove them
188 condition vars cond concl | True -- set to false to disable
189                           , ((vars',cond',concl'):_) <- mapMaybe try vars
190                           = condition vars' cond' concl'
191               -- A variable which can be replaced
192   where try v | Just subst <- findReplacer v cond
193               = -- trace ("Tested " ++ show v ++ ", can be replaced") $
194                 Just (delete v vars, subst cond, subst concl)
195  
196               -- A variable with can be removed
197               | not (unTypeExpr v `occursIn` cond || unTypeExpr v `occursIn` concl)
198               = -- trace ("Tested " ++ show v ++ ", can be reased") $
199                 Just (delete v vars, cond, concl)
200
201               -- Nothing to do with this variable
202               | otherwise
203               = -- trace ("Tested " ++ show v ++ " without success") $
204                 Nothing
205
206 -- Nothing left to optizmize
207 condition vars cond concl = Condition vars cond concl
208
209
210 caseUnit Bottom e = Bottom
211 caseUnit EUnit e  = e
212 caseUnit v e      = CaseUnit v e
213
214 -- | Replaces a Term in a BoolExpr
215 replaceTermBE :: Expr -> Expr -> BoolExpr -> BoolExpr
216 replaceTermBE d r = go
217   where go (e1 `Equal` e2) | d == e1 && r == e2 = beTrue
218                            | d == e2 && r == e1 = beTrue
219                            | otherwise          = go' e1 `equal'` go' e2
220         go (And es)        = foldr aand beTrue (map go es)
221         go (AllZipWith lbe e1 e2) 
222                            = AllZipWith (goL lbe) (go' e1) (go' e2)
223         go (AndEither lbe1 lbe2 e1 e2)
224                            = andEither' (goL lbe1) (goL lbe2) (go' e1) (go' e2)
225         go c@(Condition vs cond concl) -- shadowed definition
226                            | d `elem` map unTypeExpr vs 
227                            = c
228         go (Condition vs cond concl)
229                            = condition vs (go cond) (go concl)
230         go (UnpackPair v1 v2 e be)
231                            = unpackPair v1 v2 (goT e) (go be)
232         go (TypeVarInst _ _ _) = error "TypeVarInst not expected here"
233
234         go' = replaceExpr d r
235
236         goT te = te { unTypeExpr = go' (unTypeExpr te) }
237
238         goL (CurriedEquals t)   = (CurriedEquals t)
239         goL (LambdaBE v1 v2 be) = lambdaBE v1 v2 (go be)
240
241
242 replaceExpr :: Expr -> Expr -> Expr -> Expr
243 replaceExpr d r = go
244   where go e | e == d    = r
245         go (App e1 e2)   = app' (go e1) (go e2)
246         go (Conc es)     = foldr conc (Conc []) (map go es)
247         go (Lambda v e)  = lambda' v (go e)
248         go (Pair e1 e2)  = Pair (go e1) (go e2)
249         go (Const e)     = Const (go e)
250         go (CaseUnit v e)= caseUnit (go v) (go e)
251         go e             = e
252
253
254 -- | Is inside the term a definition for the variable?
255 findReplacer :: TypedExpr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
256 findReplacer tv be = findReplacer' (unTypeExpr tv) be
257         
258 -- | Find a definition, and return a substitution
259 findReplacer' :: Expr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
260 -- For combined types, look up the components
261 findReplacer' (Pair x y) e | Just (delX) <- findReplacer' x e
262                            , Just (delY) <- findReplacer' y e
263                     = Just (delX . delY)
264 -- Find the definition
265 findReplacer' e (e1 `Equal` e2) | e == e1    = Just (replaceTermBE e e2)
266                                 | e == e2    = Just (replaceTermBE e e1)
267 findReplacer' e (And es)        = listToMaybe (mapMaybe (findReplacer' e) es)
268                                   -- assuming no two definitions can exist
269 findReplacer' _ _               = Nothing
270
271 -- | Is inside the term a definition for the variable?
272 defFor :: TypedExpr -> BoolExpr -> Maybe (TypedExpr)
273 defFor tv be | Just (e') <- defFor' (unTypeExpr tv) be
274                          = Just (TypedExpr e' (typeOf tv))
275              | otherwise = Nothing
276         
277 -- | Find a definition, and return it along the definition remover
278 defFor' :: Expr -> BoolExpr -> Maybe (Expr)
279 defFor' e (e1 `Equal` e2) | e == e1                 = Just (e2)
280                           | e == e2                 = Just (e1)
281 defFor' e (And es)        | [d]  <- mapMaybe (defFor' e) es -- exactly one definition
282                                                     = Just d
283 defFor' _ _                                         = Nothing
284
285 app :: TypedExpr -> TypedExpr -> TypedExpr
286 app te1 te2 | Arrow t1 t2 <- typeOf te1
287             , t3          <- typeOf te2 
288             , t1 == t3 
289             = TypedExpr (app' (unTypeExpr te1) (unTypeExpr te2)) t2
290 app te1 te2 | otherwise                          = error $ "Type mismatch in app: " ++
291                                                            show te1 ++ " " ++ show te2
292
293 app' :: Expr -> Expr -> Expr
294 app' (App HeadMap f) Bottom                 = Bottom
295 app' (App HeadMap f) (Singleton e)          = app' f e
296 app' (App (App EitherMap f1) f2) Bottom     = Bottom
297 app' (App (App EitherMap f1) f2) (ELeft v)  = app' f1 v
298 app' (App (App EitherMap f1) f2) (ERight v) = app' f2 v
299 app' Bottom    _   = Bottom    -- _|_ x = _|_
300 app' (Lambda v e1) (e2) = replaceExpr v e2 e1 -- lambda application
301 app' (App Map f) (Singleton v) = Singleton (app' f v)
302 app' Map (Conc []) = Conc []   -- map id = id
303 app' (Const e) _   = e         -- const x y = x
304 app' (Conc []) v   = v         -- id x   = x
305 app' (Conc xs) v   = foldr app' v xs
306 app' f v           = App f v
307
308 lambda :: TypedExpr -> TypedExpr -> TypedExpr
309 lambda tv e = TypedExpr (lambda' (unTypeExpr tv) (unTypeExpr e))
310                         (Arrow (typeOf tv) (typeOf e))
311
312 lambda' :: Expr -> Expr -> Expr
313 lambda' v e  | e == EUnit           = Const EUnit
314               | (Just e') <- isApplOn v e
315               , not (v `occursIn` e')
316                                      = e'
317               | v == e   = Conc []
318               | otherwise            = Lambda v e
319
320 conc :: Expr -> Expr -> Expr
321 conc (Lambda v (CaseUnit v' e)) (Conc ((Const EUnit):r))
322                                 | v == v' = conc (Const e) (Conc r)
323 conc (Lambda v (CaseUnit v' e)) (Const EUnit) | v == v' = Const e
324 conc (Conc xs) (Conc ys)        | [x] <- xs ++ ys       = x
325                                 | otherwise             = Conc (xs  ++ ys)
326 conc (Conc xs)  y               = Conc (xs  ++ [y])
327 conc x         (Conc ys)        = Conc ([x] ++ ys)
328 conc x          y               = Conc ([x,y])
329
330
331 -- Specialization of g'
332
333 specialize :: BoolExpr -> BoolExpr
334 specialize (TypeVarInst strict i be') = 
335                 replaceTermBE (Var (FromTypVar i)) (if strict then Conc [] else Const EUnit) .
336                 everywhere (mkT $ go) $
337                 be
338         where be = specialize be'
339               go (TypInst i' _) | i' == i = TUnit
340               go tv                       = tv                 
341 -- No need to go further once we are through the quantors
342 specialize be = be
343
344 -- Helpers
345
346 isApplOn :: Expr -> Expr -> Maybe Expr
347 isApplOn e e'         | e == e'                       = Nothing
348 isApplOn e (App f e') | e == e'                       = Just (Conc [f])
349 isApplOn e (App f e') | (Just inner) <- isApplOn e e' = Just (conc f inner)
350 isApplOn _ _                                          = Nothing
351
352 occursIn :: (Typeable a, Data a1, Eq a) => a -> a1 -> Bool
353 e `occursIn` e'       = not (null (listify (==e) e'))
354
355 isTuple :: Typ -> Bool
356 isTuple (TPair _ _) = True
357 isTuple _           = False
358
359
360 -- showing
361
362 -- Precedences:
363 -- 10 fun app
364 --  9 (.)
365 --  8 ==
366 --  7 ==>
367 --  6 forall
368
369 instance Show EVar where
370         show F               = "f"
371         show (FromTypVar i)  = "g" ++ show i
372         show (FromParam i b) = "x" ++ show i ++ if b then "'" else ""
373
374
375 instance Show Expr where
376         showsPrec _ (Var v)     = showsPrec 11 v
377         showsPrec d (App e1 e2) = showParen (d>10) $
378                 showsPrec 10 e1 . showChar ' ' . showsPrec 11 e2
379         showsPrec _ (Conc [])   = showString "id"
380         showsPrec d (Conc [e])  = showsPrec d e
381         showsPrec d (Conc es)   = showParen (d>9) $
382                 showIntercalate (showString " . ") (map (showsPrec 10) es)
383         showsPrec _ (Lambda v e)  = showParen True $ 
384                                     showString "\\" .
385                                     showsPrec 11 v .
386                                     showString " -> ".
387                                     showsPrec 0 e 
388         showsPrec _ (Pair e1 e2) = showParen True $ 
389                                    showsPrec 0 e1 .
390                                    showString "," .
391                                    showsPrec 0 e2
392         showsPrec _ Zero          = showString "0"
393         showsPrec _ EUnit         = showString "()"
394         showsPrec _ (Singleton e) = showString "[" . showsPrec 0 e . showString "]"
395         showsPrec _ Map           = showString "map"
396         showsPrec d (ELeft e)     = showParen (d>10) $ 
397                                         showString "Left ".
398                                         showsPrec 11 e
399         showsPrec d (ERight e)    = showParen (d>10) $ 
400                                         showString "Right ".
401                                         showsPrec 11 e
402         showsPrec d (Const e)     = showParen (d>10) $ showString "const ".showsPrec 11 e
403         showsPrec d (CaseUnit t1 t2) = showParen (d>5) $
404                                         showString "case " .
405                                         showsPrec 0 t1 .
406                                         showString " of () ->  " .
407                                         showsPrec 11 t2
408         showsPrec _ EitherMap     = showString "eitherMap"
409         showsPrec _ HeadMap       = showString "headMap"
410         showsPrec _ Bottom        = showString "_|_"
411
412 showIntercalate :: ShowS -> [ShowS] -> ShowS
413 showIntercalate _ []  = id
414 showIntercalate _ [x] = x
415 showIntercalate i (x:xs) = x . i . showIntercalate i xs
416
417 instance Show TypedExpr where
418         showsPrec d (TypedExpr e t) = 
419                 showParen (d>10) $
420                         showsPrec 0 e .
421                         showString " :: " .
422                         showString (showTypePrec 0 t)
423
424 instance Show LambdaBE where
425         show (CurriedEquals _) = 
426                         "(==)"
427         show (LambdaBE v1 v2 be) = 
428                         "(" ++
429                         "\\" ++
430                         showsPrec 11 (unTypeExpr v1) "" ++
431                         " " ++
432                         showsPrec 11 (unTypeExpr v2) "" ++
433                         " -> " ++
434                         show be ++
435                         ")"
436
437 instance Show BoolExpr where
438         show (Equal e1 e2) = showsPrec 9 e1 $
439                              showString " == " $
440                              showsPrec 9 e2 ""
441         show (And [])      = "True"
442         show (And bes)     = intercalate " && " $ map show bes
443         show (AllZipWith lbe e1 e2) =
444                         "allZipWith " ++
445                         show lbe ++
446                         " " ++
447                         showsPrec 11 e1 "" ++
448                         " " ++
449                         showsPrec 11 e2 ""
450         show (AndEither lbe1 lbe2 e1 e2) =
451                         "andEither " ++
452                         show lbe1 ++
453                         " " ++
454                         show lbe2 ++
455                         " " ++
456                         showsPrec 11 e1 "" ++
457                         " " ++
458                         showsPrec 11 e2 ""
459         show (Condition tvars be1 be2) = 
460                         "forall " ++
461                         intercalate ", " (map show tvars) ++
462                         ".\n" ++
463                         (if be1 /= beTrue then indent 2 (show be1) ++ "==>\n" else "") ++
464                         indent 2 (show be2)
465         show (UnpackPair v1 v2 e be) = 
466                         "let (" ++
467                         showsPrec 0 v1 "" ++
468                         "," ++
469                         showsPrec 0 v2 "" ++
470                         ") = " ++
471                         showsPrec 0 e "" ++
472                         " in\n" ++
473                         indent 2 (show be)
474         show (TypeVarInst strict i be) = 
475                         "forall types t" ++
476                         show (2*i-1) ++
477                         ", t" ++
478                         show (2*i) ++
479                         ", " ++
480                         (if strict then "strict " else "(strict) ") ++
481                         "functions g" ++
482                         show i ++
483                         " :: t" ++
484                         show (2*i-1) ++
485                         " -> t" ++
486                         show (2*i) ++ 
487                         ".\n" ++
488                         indent 2 (show be)
489
490 indent :: Int -> String -> String
491 indent n = unlines . map (replicate n ' ' ++) . lines
492
493 showTypePrec :: Int -> Typ -> String
494 showTypePrec _ Int                          = "Int" 
495 showTypePrec _ (TVar (TypVar i))            = "a"++show i
496 showTypePrec _ (TVar (TypInst i b)) | not b = "t" ++  show (2*i-1)
497                                     |     b = "t" ++  show (2*i)
498 showTypePrec _ (TVar (TUnit))               = "()"
499 showTypePrec d (Arrow t1 t2)                = paren (d>9) $ 
500                                                 showTypePrec 10 t1 ++
501                                                 " -> " ++
502                                                 showTypePrec 9 t2 
503 showTypePrec _ (List t)                     = "[" ++ showTypePrec 0 t ++ "]"
504 showTypePrec _ (TEither t1 t2)              = "Either " ++ showTypePrec 11 t1 ++ 
505                                                     " " ++ showTypePrec 11 t2
506 showTypePrec _ (TPair t1 t2)                = "(" ++ showTypePrec 0 t1 ++
507                                               "," ++ showTypePrec 0 t2 ++ ")"
508 showTypePrec _ t                            = error $ "Did not expect to show " ++ show t
509
510 paren :: Bool -> String -> String
511 paren b p   =  if b then "(" ++ p ++ ")" else p