a928862410208e4af4fd4e581a352501a58eef3f
[darcs-mirror-polyfix.git] / Expr.hs
1 {-# LANGUAGE PatternGuards, DeriveDataTypeable   #-}
2 module Expr where
3
4 import Data.List
5 import Data.Maybe
6 import ParseType
7
8 -- import Debug.Trace
9
10 import Data.Generics hiding (typeOf)
11 import Data.Generics.Schemes
12
13 data TypedExpr = TypedExpr
14         { unTypeExpr    :: Expr
15         , typeOf        :: Typ
16         } deriving (Eq, Typeable, Data)
17
18 typedLeft, typedRight :: Expr -> Typ -> TypedExpr
19 typedLeft  e t = TypedExpr e (instType False t)
20 typedRight e t = TypedExpr e (instType True t)
21
22 data EVar = F
23           | FromTypVar Int
24           | FromParam Int Bool
25             deriving (Eq, Ord, Typeable, Data)
26
27 data Expr
28         = Var EVar
29         | App Expr Expr
30         | Conc [Expr] -- Conc [] is Id
31         | Lambda Expr Expr
32         | Pair Expr Expr
33         | Map
34         | Const Expr
35         | ELeft Expr
36         | ERight Expr
37         | CaseUnit Expr Expr
38         | EitherMap
39         | HeadMap
40         | EUnit
41         | Singleton Expr
42         | Zero
43         | Bottom
44             deriving (Eq, Typeable, Data)
45
46 data LambdaBE = CurriedEquals Typ
47               | LambdaBE TypedExpr TypedExpr BoolExpr
48             deriving (Eq, Typeable, Data)
49
50 data BoolExpr 
51         = Equal Expr Expr
52         | And [BoolExpr] -- And [] is True
53         | AllZipWith LambdaBE Expr Expr
54         | AndEither  LambdaBE LambdaBE Expr Expr
55         | Condition [TypedExpr] BoolExpr BoolExpr
56         | UnpackPair TypedExpr TypedExpr TypedExpr BoolExpr
57         | TypeVarInst Bool Int BoolExpr
58             deriving (Eq, Typeable, Data)
59
60 -- Smart constructors
61
62 -- | Try eta reduction
63 equal :: TypedExpr -> TypedExpr -> BoolExpr
64 equal te1 te2 | typeOf te1 /= typeOf te2 = error "Type mismatch in equal"
65               | otherwise                = equal' (unTypeExpr te1) (unTypeExpr te2)
66
67 equal' :: Expr -> Expr -> BoolExpr
68 equal' e1 e2  | (Just (lf,lv)) <- isFunctionApplication e1
69               , (Just (rf,rv)) <- isFunctionApplication e2
70               , lv == rv 
71               , False
72                                          = equal' lf rf
73               -- This makes it return True...
74               | e1 == e2                 = beTrue
75               | otherwise                = Equal e1 e2
76
77 -- | If e is of the type (app f1 (app f2 .. (app fn x)..)),
78 --   return Just (f1 . f2. ... . fn, x)
79 isFunctionApplication :: Expr -> Maybe (Expr, Expr)
80 isFunctionApplication (App f e') | (Just (inner,v)) <- isFunctionApplication e'
81                                  = Just (conc f inner, v)
82                                  | otherwise
83                                  = Just (f, e')
84 isFunctionApplication _          = Nothing
85
86
87 unpackPair :: TypedExpr -> TypedExpr -> TypedExpr -> BoolExpr -> BoolExpr
88 -- | if the te is already a tuple, then replace the variables
89 unpackPair v1 v2 te be | Pair pe1 pe2 <- unTypeExpr te
90                        = replaceTermBE (unTypeExpr v1) pe1 $
91                          replaceTermBE (unTypeExpr v2) pe2 $ be
92 -- | If both bound variables are just functions, we can replace this
93 --   by a comparison
94 unpackPair v1 v2 te be | Just subst1 <- findReplacer v1 be
95                        , Just subst2 <- findReplacer v2 be
96                        = subst1. subst2 $ (pair v1 v2 `equal` te) `aand` be
97
98 -- | Don’t unpack pair if vars are not used
99 unpackPair v1 v2 te be | not (unTypeExpr v1 `occursIn` be || unTypeExpr v2 `occursIn` be)
100                        = be
101 -- | If the whole tuple is a function, we can replace this
102 --   by a comparison
103 unpackPair v1 v2 te be | Just subst <- findReplacer (pair v1 v2) be
104                        = subst $ (pair v1 v2 `equal` te) `aand` be
105 -- | Nothing to optimize
106 unpackPair v1 v2 te be = UnpackPair v1 v2 te be
107
108 pair :: TypedExpr -> TypedExpr -> TypedExpr
109 pair (TypedExpr e1 t1) (TypedExpr e2 t2) = TypedExpr (Pair e1 e2) (TPair t1 t2)
110
111 lambdaBE :: TypedExpr -> TypedExpr -> BoolExpr -> LambdaBE
112 lambdaBE v1 v2 rel | typeOf v1 == typeOf v2 
113                    , rel == v1 `equal` v2    = CurriedEquals (typeOf v1)
114                    | otherwise               = LambdaBE v1 v2 rel
115
116 andEither :: LambdaBE -> LambdaBE -> TypedExpr -> TypedExpr -> BoolExpr
117 andEither (CurriedEquals _) (CurriedEquals _) e1 e2 = e1 `equal` e2
118 andEither lbe1 lbe2 e1 e2 | Just f1 <- arg1IsFunc lbe1
119                           , Just f2 <- arg1IsFunc lbe2
120                           = e1 `equal` eitherE f1 f2 e2
121                           | Just f1 <- arg2IsFunc lbe1
122                           , Just f2 <- arg2IsFunc lbe2
123                           = eitherE f1 f2 e1 `equal` e2
124                           | otherwise
125                           = andEither' lbe1 lbe2 (unTypeExpr e1) (unTypeExpr e2)
126
127 andEither' :: LambdaBE -> LambdaBE -> Expr -> Expr -> BoolExpr
128 andEither' (LambdaBE v1 v2 rel) _ (ELeft e1) (ELeft e2)
129        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
130 andEither' _ (LambdaBE v1 v2 rel) (ERight e1) (ERight e2)
131        = replaceTermBE (unTypeExpr v1) e1 $ replaceTermBE (unTypeExpr v2) e2 $ rel
132 andEither' lbe1 lbe2 e1 e2
133        = AndEither lbe1 lbe2 e1 e2
134
135
136 arg1IsFunc :: LambdaBE -> Maybe TypedExpr
137 arg1IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
138 arg1IsFunc (LambdaBE v1 v2 rel) | Just v1' <- defFor v1 rel
139                                 = Just (lambda v2 v1')
140                                 | otherwise = Nothing
141
142 arg2IsFunc :: LambdaBE -> Maybe TypedExpr
143 arg2IsFunc (CurriedEquals t)    = Just $ TypedExpr (Conc []) (Arrow t t)
144 arg2IsFunc (LambdaBE v1 v2 rel) | Just v2' <- defFor v2 rel
145                                 = Just (lambda v1 v2')
146                                 | otherwise = Nothing
147
148 allZipWith :: TypedExpr -> TypedExpr -> BoolExpr -> TypedExpr -> TypedExpr -> BoolExpr
149 allZipWith v1 v2 rel e1 e2 | Just v1' <- defFor v1 rel =
150                                 e1 `equal` amap (lambda v2 v1') e2
151                            | Just v2' <- defFor v2 rel =
152                                 amap (lambda v1 v2') e1 `equal` e2
153                            | otherwise =
154                                 AllZipWith (LambdaBE v1 v2 rel) (unTypeExpr e1) (unTypeExpr e2)
155
156 eitherE :: TypedExpr -> TypedExpr -> TypedExpr -> TypedExpr
157 eitherE f1 f2 e | Arrow lt1 lt2 <- typeOf f1
158                 , Arrow rt1 rt2 <- typeOf f2
159                 , TEither lt rt <- typeOf e
160                 , lt1 == lt
161                 , rt1 == rt
162         = let tEither = TypedExpr EitherMap (Arrow (typeOf f1) (Arrow (typeOf f2) (Arrow (typeOf e) (TEither lt2 rt2))))
163           in  app (app (app tEither f1) f2) e
164                 | otherwise = error $ "Type error in eitherE\n" ++ show (f1, f2, e)
165
166 amap :: TypedExpr -> TypedExpr -> TypedExpr
167 amap tf tl | Arrow t1 t2 <- typeOf tf
168            , List t      <- typeOf tl
169            , t1 == t
170            = let tMap = TypedExpr Map (Arrow (Arrow t1 t2) (Arrow (List t1) (List t2)))
171              in app (app tMap tf) tl
172            | otherwise = error "Type error in map"
173
174 aand :: BoolExpr -> BoolExpr -> BoolExpr
175 aand (And xs) (And ys) = And (xs  ++ ys)
176 aand (And xs) y        = And (xs  ++ [y])
177 aand x        (And ys) = And ([x] ++ ys)
178 aand x        y        = And ([x,y])
179
180 beTrue :: BoolExpr
181 beTrue = And []
182
183 -- | Optimize a forall condition
184 condition :: [TypedExpr] -> BoolExpr -> BoolExpr -> BoolExpr
185 -- empty condition
186 condition [] cond concl   | cond == beTrue
187                           = concl
188 -- float out conditions on the right
189 condition vars cond (Condition vars' cond' concl')
190                           = condition (vars ++ vars') (cond `aand` cond') concl'
191
192 -- Try to find variables that are functions of other variables, and remove them
193 condition vars cond concl | True -- set to false to disable
194                           , ((vars',cond',concl'):_) <- mapMaybe try vars
195                           = condition vars' cond' concl'
196               -- A variable which can be replaced
197   where try v | Just subst <- findReplacer v cond
198               = -- trace ("Tested " ++ show v ++ ", can be replaced") $
199                 Just (delete v vars, subst cond, subst concl)
200  
201               -- A variable with can be removed
202               | not (unTypeExpr v `occursIn` cond || unTypeExpr v `occursIn` concl)
203               = -- trace ("Tested " ++ show v ++ ", can be reased") $
204                 Just (delete v vars, cond, concl)
205
206               -- Nothing to do with this variable
207               | otherwise
208               = -- trace ("Tested " ++ show v ++ " without success") $
209                 Nothing
210
211 -- Nothing left to optizmize
212 condition vars cond concl = Condition vars cond concl
213
214
215 caseUnit Bottom e = Bottom
216 caseUnit EUnit e  = e
217 caseUnit v e      = CaseUnit v e
218
219 -- | Replaces a Term in a BoolExpr
220 replaceTermBE :: Expr -> Expr -> BoolExpr -> BoolExpr
221 replaceTermBE d r = go
222   where go (e1 `Equal` e2) | d == e1 && r == e2 = beTrue
223                            | d == e2 && r == e1 = beTrue
224                            | otherwise          = go' e1 `equal'` go' e2
225         go (And es)        = foldr aand beTrue (map go es)
226         go (AllZipWith lbe e1 e2) 
227                            = AllZipWith (goL lbe) (go' e1) (go' e2)
228         go (AndEither lbe1 lbe2 e1 e2)
229                            = andEither' (goL lbe1) (goL lbe2) (go' e1) (go' e2)
230         go c@(Condition vs cond concl) -- shadowed definition
231                            | d `elem` map unTypeExpr vs 
232                            = c
233         go (Condition vs cond concl)
234                            = condition vs (go cond) (go concl)
235         go (UnpackPair v1 v2 e be)
236                            = unpackPair v1 v2 (goT e) (go be)
237         go (TypeVarInst _ _ _) = error "TypeVarInst not expected here"
238
239         go' = replaceExpr d r
240
241         goT te = te { unTypeExpr = go' (unTypeExpr te) }
242
243         goL (CurriedEquals t)   = (CurriedEquals t)
244         goL (LambdaBE v1 v2 be) = lambdaBE v1 v2 (go be)
245
246
247 replaceExpr :: Expr -> Expr -> Expr -> Expr
248 replaceExpr d r = go
249   where go e | e == d    = r
250         go (App e1 e2)   = app' (go e1) (go e2)
251         go (Conc es)     = foldr conc (Conc []) (map go es)
252         go (Lambda v e)  = lambda' v (go e)
253         go (Pair e1 e2)  = Pair (go e1) (go e2)
254         go (Const e)     = Const (go e)
255         go (CaseUnit v e)= caseUnit (go v) (go e)
256         go e             = e
257
258
259 -- | Is inside the term a definition for the variable?
260 findReplacer :: TypedExpr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
261 findReplacer tv be = findReplacer' (unTypeExpr tv) be
262         
263 -- | Find a definition, and return a substitution
264 findReplacer' :: Expr -> BoolExpr -> Maybe (BoolExpr -> BoolExpr)
265 -- For combined types, look up the components
266 findReplacer' (Pair x y) e | Just (delX) <- findReplacer' x e
267                            , Just (delY) <- findReplacer' y e
268                     = Just (delX . delY)
269 -- Find the definition
270 findReplacer' e (e1 `Equal` e2) | e == e1    = Just (replaceTermBE e e2)
271                                 | e == e2    = Just (replaceTermBE e e1)
272 findReplacer' e (And es)        = listToMaybe (mapMaybe (findReplacer' e) es)
273                                   -- assuming no two definitions can exist
274 findReplacer' _ _               = Nothing
275
276 -- | Is inside the term a definition for the variable?
277 defFor :: TypedExpr -> BoolExpr -> Maybe (TypedExpr)
278 defFor tv be | Just (e') <- defFor' (unTypeExpr tv) be
279                          = Just (TypedExpr e' (typeOf tv))
280              | otherwise = Nothing
281         
282 -- | Find a definition, and return it along the definition remover
283 defFor' :: Expr -> BoolExpr -> Maybe (Expr)
284 defFor' e (e1 `Equal` e2) | e == e1                 = Just (e2)
285                           | e == e2                 = Just (e1)
286 defFor' e (And es)        | [d]  <- mapMaybe (defFor' e) es -- exactly one definition
287                                                     = Just d
288 defFor' _ _                                         = Nothing
289
290 app :: TypedExpr -> TypedExpr -> TypedExpr
291 app te1 te2 | Arrow t1 t2 <- typeOf te1
292             , t3          <- typeOf te2 
293             , t1 == t3 
294             = TypedExpr (app' (unTypeExpr te1) (unTypeExpr te2)) t2
295 app te1 te2 | otherwise                          = error $ "Type mismatch in app: " ++
296                                                            show te1 ++ " " ++ show te2
297
298 app' :: Expr -> Expr -> Expr
299 app' (App HeadMap f) Bottom                 = Bottom
300 app' (App HeadMap f) (Singleton e)          = app' f e
301 app' (App (App EitherMap f1) f2) Bottom     = Bottom
302 app' (App (App EitherMap f1) f2) (ELeft v)  = ELeft (app' f1 v)
303 app' (App (App EitherMap f1) f2) (ERight v) = ERight (app' f2 v)
304 app' Bottom    _   = Bottom    -- _|_ x = _|_
305 app' (Lambda v e1) (e2) = replaceExpr v e2 e1 -- lambda application
306 app' (App Map f) (Singleton v) = Singleton (app' f v)
307 app' Map (Conc []) = Conc []   -- map id = id
308 app' (Const e) _   = e         -- const x y = x
309 app' (Conc []) v   = v         -- id x   = x
310 app' (Conc xs) v   = foldr app' v xs
311 app' f v           = App f v
312
313 lambda :: TypedExpr -> TypedExpr -> TypedExpr
314 lambda tv e = TypedExpr (lambda' (unTypeExpr tv) (unTypeExpr e))
315                         (Arrow (typeOf tv) (typeOf e))
316
317 lambda' :: Expr -> Expr -> Expr
318 lambda' v e  | e == EUnit           = Const EUnit
319               | (Just e') <- isApplOn v e
320               , not (v `occursIn` e')
321                                      = e'
322               | v == e   = Conc []
323               | otherwise            = Lambda v e
324
325 conc :: Expr -> Expr -> Expr
326 conc (Lambda v (CaseUnit v' e)) (Conc ((Const EUnit):r))
327                                 | v == v' = conc (Const e) (Conc r)
328 conc (Lambda v (CaseUnit v' e)) (Const EUnit) | v == v' = Const e
329 conc (Conc xs) (Conc ys)        | [x] <- xs ++ ys       = x
330                                 | otherwise             = Conc (xs  ++ ys)
331 conc (Conc xs)  y               = Conc (xs  ++ [y])
332 conc x         (Conc ys)        = Conc ([x] ++ ys)
333 conc x          y               = Conc ([x,y])
334
335
336 -- Specialization of g'
337
338 specialize :: BoolExpr -> BoolExpr
339 specialize (TypeVarInst strict i be') = 
340                 replaceTermBE (Var (FromTypVar i)) (if strict then Conc [] else Const EUnit) .
341                 everywhere (mkT $ go) $
342                 be
343         where be = specialize be'
344               go (TypInst i' _) | i' == i = TUnit
345               go tv                       = tv                 
346 -- No need to go further once we are through the quantors
347 specialize be = be
348
349 -- Helpers
350
351 isApplOn :: Expr -> Expr -> Maybe Expr
352 isApplOn e e'         | e == e'                       = Nothing
353 isApplOn e (App f e') | e == e'                       = Just (Conc [f])
354 isApplOn e (App f e') | (Just inner) <- isApplOn e e' = Just (conc f inner)
355 isApplOn _ _                                          = Nothing
356
357 occursIn :: (Typeable a, Data a1, Eq a) => a -> a1 -> Bool
358 e `occursIn` e'       = not (null (listify (==e) e'))
359
360 isTuple :: Typ -> Bool
361 isTuple (TPair _ _) = True
362 isTuple _           = False
363
364
365 -- showing
366
367 -- Precedences:
368 -- 10 fun app
369 --  9 (.)
370 --  8 ==
371 --  7 ==>
372 --  6 forall
373
374 instance Show EVar where
375         show F               = "f"
376         show (FromTypVar i)  = "g" ++ show i
377         show (FromParam i b) = "x" ++ show i ++ if b then "'" else ""
378
379
380 instance Show Expr where
381         showsPrec _ (Var v)     = showsPrec 11 v
382         showsPrec d (App e1 e2) = showParen (d>10) $
383                 showsPrec 10 e1 . showChar ' ' . showsPrec 11 e2
384         showsPrec _ (Conc [])   = showString "id"
385         showsPrec d (Conc [e])  = showsPrec d e
386         showsPrec d (Conc es)   = showParen (d>9) $
387                 showIntercalate (showString " . ") (map (showsPrec 10) es)
388         showsPrec _ (Lambda v e)  = showParen True $ 
389                                     showString "\\" .
390                                     showsPrec 11 v .
391                                     showString " -> ".
392                                     showsPrec 0 e 
393         showsPrec _ (Pair e1 e2) = showParen True $ 
394                                    showsPrec 0 e1 .
395                                    showString "," .
396                                    showsPrec 0 e2
397         showsPrec _ Zero          = showString "0"
398         showsPrec _ EUnit         = showString "()"
399         showsPrec _ (Singleton e) = showString "[" . showsPrec 0 e . showString "]"
400         showsPrec _ Map           = showString "map"
401         showsPrec d (ELeft e)     = showParen (d>10) $ 
402                                         showString "Left ".
403                                         showsPrec 11 e
404         showsPrec d (ERight e)    = showParen (d>10) $ 
405                                         showString "Right ".
406                                         showsPrec 11 e
407         showsPrec d (Const e)     = showParen (d>10) $ showString "const ".showsPrec 11 e
408         showsPrec d (CaseUnit t1 t2) = showParen (d>5) $
409                                         showString "case " .
410                                         showsPrec 0 t1 .
411                                         showString " of () ->  " .
412                                         showsPrec 11 t2
413         showsPrec _ EitherMap     = showString "eitherMap"
414         showsPrec _ HeadMap       = showString "headMap"
415         showsPrec _ Bottom        = showString "_|_"
416
417 showIntercalate :: ShowS -> [ShowS] -> ShowS
418 showIntercalate _ []  = id
419 showIntercalate _ [x] = x
420 showIntercalate i (x:xs) = x . i . showIntercalate i xs
421
422 instance Show TypedExpr where
423         showsPrec d (TypedExpr e t) = 
424                 showParen (d>10) $
425                         showsPrec 0 e .
426                         showString " :: " .
427                         showString (showTypePrec 0 t)
428
429 instance Show LambdaBE where
430         show (CurriedEquals _) = 
431                         "(==)"
432         show (LambdaBE v1 v2 be) = 
433                         "(" ++
434                         "\\" ++
435                         showsPrec 11 (unTypeExpr v1) "" ++
436                         " " ++
437                         showsPrec 11 (unTypeExpr v2) "" ++
438                         " -> " ++
439                         show be ++
440                         ")"
441
442 instance Show BoolExpr where
443         show (Equal e1 e2) = showsPrec 9 e1 $
444                              showString " == " $
445                              showsPrec 9 e2 ""
446         show (And [])      = "True"
447         show (And bes)     = intercalate " && " $ map show bes
448         show (AllZipWith lbe e1 e2) =
449                         "allZipWith " ++
450                         show lbe ++
451                         " " ++
452                         showsPrec 11 e1 "" ++
453                         " " ++
454                         showsPrec 11 e2 ""
455         show (AndEither lbe1 lbe2 e1 e2) =
456                         "andEither " ++
457                         show lbe1 ++
458                         " " ++
459                         show lbe2 ++
460                         " " ++
461                         showsPrec 11 e1 "" ++
462                         " " ++
463                         showsPrec 11 e2 ""
464         show (Condition tvars be1 be2) = 
465                         "forall " ++
466                         intercalate ", " (map show tvars) ++
467                         ".\n" ++
468                         (if be1 /= beTrue then indent 2 (show be1) ++ "==>\n" else "") ++
469                         indent 2 (show be2)
470         show (UnpackPair v1 v2 e be) = 
471                         "let (" ++
472                         showsPrec 0 v1 "" ++
473                         "," ++
474                         showsPrec 0 v2 "" ++
475                         ") = " ++
476                         showsPrec 0 e "" ++
477                         " in\n" ++
478                         indent 2 (show be)
479         show (TypeVarInst strict i be) = 
480                         "forall types t" ++
481                         show (2*i-1) ++
482                         ", t" ++
483                         show (2*i) ++
484                         ", " ++
485                         (if strict then "strict " else "(strict) ") ++
486                         "functions g" ++
487                         show i ++
488                         " :: t" ++
489                         show (2*i-1) ++
490                         " -> t" ++
491                         show (2*i) ++ 
492                         ".\n" ++
493                         indent 2 (show be)
494
495 indent :: Int -> String -> String
496 indent n = unlines . map (replicate n ' ' ++) . lines
497
498 showTypePrec :: Int -> Typ -> String
499 showTypePrec _ Int                          = "Int" 
500 showTypePrec _ (TVar (TypVar i))            = "a"++show i
501 showTypePrec _ (TVar (TypInst i b)) | not b = "t" ++  show (2*i-1)
502                                     |     b = "t" ++  show (2*i)
503 showTypePrec _ (TVar (TUnit))               = "()"
504 showTypePrec d (Arrow t1 t2)                = paren (d>9) $ 
505                                                 showTypePrec 10 t1 ++
506                                                 " -> " ++
507                                                 showTypePrec 9 t2 
508 showTypePrec _ (List t)                     = "[" ++ showTypePrec 0 t ++ "]"
509 showTypePrec _ (TEither t1 t2)              = "Either " ++ showTypePrec 11 t1 ++ 
510                                                     " " ++ showTypePrec 11 t2
511 showTypePrec _ (TPair t1 t2)                = "(" ++ showTypePrec 0 t1 ++
512                                               "," ++ showTypePrec 0 t2 ++ ")"
513 showTypePrec _ t                            = error $ "Did not expect to show " ++ show t
514
515 paren :: Bool -> String -> String
516 paren b p   =  if b then "(" ++ p ++ ")" else p