2eda349f0866b67da11e62fd86b737eced1bf91c
[ghc-heap-view.git] / src / GHC / HeapView.hs
1 {-# LANGUAGE MagicHash, UnboxedTuples, CPP, ForeignFunctionInterface, GHCForeignImportPrim, UnliftedFFITypes, BangPatterns, RecordWildCards, DeriveFunctor, DeriveFoldable, DeriveTraversable, PatternGuards #-}
2 {-|
3 Module      :  GHC.HeapView
4 Copyright   :  (c) 2012 Joachim Breitner
5 License     :  BSD3
6 Maintainer  :  Joachim Breitner <mail@joachim-breitner.de>
7
8 With this module, you can investigate the heap representation of Haskell
9 values, i.e. to investigate sharing and lazy evaluation.
10 -}
11
12
13 module GHC.HeapView (
14     -- * Heap data types
15     GenClosure(..),
16     Closure,
17     allPtrs,
18     ClosureType(..),
19     StgInfoTable(..),
20     HalfWord,
21     -- * Reading from the heap
22     getClosureData,
23     getBoxedClosureData,
24     getClosureRaw,
25     -- * Pretty printing
26     ppClosure,
27     -- * Heap maps
28     -- $heapmap
29     HeapTree(..),
30     buildHeapTree,
31     ppHeapTree,
32     HeapGraphEntry(..),
33     HeapGraphIndex,
34     HeapGraph(..),
35     lookupHeapGraph,
36     heapGraphRoot,
37     buildHeapGraph,
38     multiBuildHeapGraph,
39     addHeapGraph,
40     annotateHeapGraph,
41     updateHeapGraph,
42     ppHeapGraph,
43     -- * Boxes
44     Box(..),
45     asBox,
46     areBoxesEqual,
47     -- * Disassembler
48     disassembleBCO,
49     )
50     where
51
52 import GHC.Exts         ( Any,
53                           Ptr(..), Addr#, Int(..), Word(..), Word#, Int#,
54                           ByteArray#, Array#, sizeofByteArray#, sizeofArray#, indexArray#, indexWordArray#,
55                           unsafeCoerce# )
56
57 import GHC.Arr          (Array(..))
58
59
60 import Foreign          hiding ( void )
61 import Numeric          ( showHex )
62 import Data.Char
63 import Data.List
64 import Data.Maybe       ( catMaybes )
65 import Data.Monoid      ( Monoid, (<>), mempty )
66 import Data.Functor
67 import Data.Function
68 import Data.Foldable    ( Foldable )
69 import qualified Data.Foldable as F
70 import Data.Traversable ( Traversable )
71 import qualified Data.Traversable as T
72 import qualified Data.IntMap as M
73 import Control.Monad
74 import Control.Monad.Trans.State
75 import Control.Monad.Trans.Class
76 import Control.Monad.IO.Class
77 import Control.Monad.Trans.Writer.Strict
78 import Control.Exception.Base (evaluate)
79
80 import GHC.Disassembler
81
82 #include "ghcautoconf.h"
83
84 -- | An arbitrarily Haskell value in a safe Box. The point is that even
85 -- unevaluated thunks can safely be moved around inside the Box, and when
86 -- required, e.g. in 'getBoxedClosureData', the function knows how far it has
87 -- to evalue the argument.
88 data Box = Box Any
89
90 #if SIZEOF_VOID_P == 8
91 type HalfWord = Word32
92 #else
93 type HalfWord = Word16
94 #endif
95
96 instance Show Box where
97 -- From libraries/base/GHC/Ptr.lhs
98    showsPrec _ (Box a) rs =
99     -- unsafePerformIO (print "↓" >> pClosure a) `seq`
100     pad_out (showHex addr "") ++ (if tag>0 then "/" ++ show tag else "") ++ rs
101      where
102        ptr  = W# (aToWord# a)
103        tag  = ptr .&. fromIntegral tAG_MASK -- ((1 `shiftL` TAG_BITS) -1)
104        addr = ptr - tag
105         -- want 0s prefixed to pad it out to a fixed length.
106        pad_out ls =
107           '0':'x':(replicate (2*wORD_SIZE - length ls) '0') ++ ls
108
109 -- | Boxes can be compared, but this is not pure, as different heap objects can,
110 -- after garbage collection, become the same object.
111 areBoxesEqual :: Box -> Box -> IO Bool
112 areBoxesEqual (Box a) (Box b) = case reallyUnsafePtrEqualityUpToTag# a b of
113     0# -> return False
114     _  -> return True
115
116
117 {-|
118   This takes an arbitrary value and puts it into a box. Note that calls like
119
120   > asBox (head list)
121
122   will put the thunk \"head list\" into the box, /not/ the element at the head
123   of the list. For that, use careful case expressions:
124
125   > case list of x:_ -> asBox x
126 -}
127 asBox :: a -> Box
128 asBox x = Box (unsafeCoerce# x)
129
130 {-
131    StgInfoTable parsing derived from ByteCodeItbls.lhs
132    Removed the code parameter for now
133    Replaced Type by an enumeration
134    Remove stuff dependent on GHCI_TABLES_NEXT_TO_CODE
135  -}
136
137 {-| This is a somewhat faithful representation of an info table. See
138    <http://hackage.haskell.org/trac/ghc/browser/includes/rts/storage/InfoTables.h>
139    for more details on this data structure. Note that the 'Storable' instance
140    provided here does _not_ support writing.
141  -}
142 data StgInfoTable = StgInfoTable {
143    ptrs   :: HalfWord,
144    nptrs  :: HalfWord,
145    tipe   :: ClosureType,
146    srtlen :: HalfWord
147   }
148   deriving (Show)
149
150 instance Storable StgInfoTable where
151
152    sizeOf itbl
153       = sum
154         [
155          fieldSz ptrs itbl,
156          fieldSz nptrs itbl,
157          sizeOf (undefined :: HalfWord),
158          fieldSz srtlen itbl
159         ]
160
161    alignment _
162       = wORD_SIZE
163
164    poke _a0 _itbl
165       = error "Storable StgInfoTable is read-only"
166
167    peek a0
168       = flip (evalStateT) (castPtr a0)
169       $ do
170            ptrs'   <- load
171            nptrs'  <- load
172            tipe'   <- load
173            srtlen' <- load
174            return
175               StgInfoTable {
176                  ptrs   = ptrs',
177                  nptrs  = nptrs',
178                  tipe   = toEnum (fromIntegral (tipe'::HalfWord)),
179                  srtlen = srtlen'
180               }
181
182 fieldSz :: Storable b => (a -> b) -> a -> Int
183 fieldSz sel x = sizeOf (sel x)
184
185 load :: Storable a => PtrIO a
186 load = do addr <- advance
187           lift (peek addr)
188
189 type PtrIO = StateT (Ptr Word8) IO
190
191 advance :: Storable a => PtrIO (Ptr a)
192 advance = StateT adv where
193     adv addr = case castPtr addr of { addrCast -> return
194         (addrCast, addr `plusPtr` sizeOfPointee addrCast) }
195
196 sizeOfPointee :: (Storable a) => Ptr a -> Int
197 sizeOfPointee addr = sizeOf (typeHack addr)
198     where typeHack = undefined :: Ptr a -> a
199
200 {-
201    Data Type representing Closures
202  -}
203
204
205 {-| A closure type enumeration, in order matching the actual value on the heap.
206    Needs to be synchronized with
207    <http://hackage.haskell.org/trac/ghc/browser/includes/rts/storage/ClosureTypes.h>
208  -}
209 data ClosureType =
210           INVALID_OBJECT
211         | CONSTR
212         | CONSTR_1_0
213         | CONSTR_0_1
214         | CONSTR_2_0
215         | CONSTR_1_1
216         | CONSTR_0_2
217 #if defined(GHC_8_0)
218         | CONSTR_STATIC
219         | CONSTR_NOCAF_STATIC
220 #else
221         | CONSTR_NOCAF
222 #endif
223         | FUN
224         | FUN_1_0
225         | FUN_0_1
226         | FUN_2_0
227         | FUN_1_1
228         | FUN_0_2
229         | FUN_STATIC
230         | THUNK
231         | THUNK_1_0
232         | THUNK_0_1
233         | THUNK_2_0
234         | THUNK_1_1
235         | THUNK_0_2
236         | THUNK_STATIC
237         | THUNK_SELECTOR
238         | BCO
239         | AP
240         | PAP
241         | AP_STACK
242         | IND
243 #if defined(GHC_8_0)
244         | IND_PERM
245 #endif
246         | IND_STATIC
247         | RET_BCO
248         | RET_SMALL
249         | RET_BIG
250         | RET_FUN
251         | UPDATE_FRAME
252         | CATCH_FRAME
253         | UNDERFLOW_FRAME
254         | STOP_FRAME
255         | BLOCKING_QUEUE
256         | BLACKHOLE
257         | MVAR_CLEAN
258         | MVAR_DIRTY
259         | TVAR
260         | ARR_WORDS
261         | MUT_ARR_PTRS_CLEAN
262         | MUT_ARR_PTRS_DIRTY
263         | MUT_ARR_PTRS_FROZEN0
264         | MUT_ARR_PTRS_FROZEN
265         | MUT_VAR_CLEAN
266         | MUT_VAR_DIRTY
267         | WEAK
268         | PRIM
269         | MUT_PRIM
270         | TSO
271         | STACK
272         | TREC_CHUNK
273         | ATOMICALLY_FRAME
274         | CATCH_RETRY_FRAME
275         | CATCH_STM_FRAME
276         | WHITEHOLE
277         | SMALL_MUT_ARR_PTRS_CLEAN
278         | SMALL_MUT_ARR_PTRS_DIRTY
279         | SMALL_MUT_ARR_PTRS_FROZEN0
280         | SMALL_MUT_ARR_PTRS_FROZEN
281 #if defined(GHC_8_2)
282         | COMPACT_NFDATA
283 #endif
284  deriving (Show, Eq, Enum, Bounded, Ord)
285
286 {-| This is the main data type of this module, representing a Haskell value on
287   the heap. This reflects
288   <http://hackage.haskell.org/trac/ghc/browser/includes/rts/storage/Closures.h>
289
290   The data type is parametrized by the type to store references in, which
291   is usually a 'Box' with appropriate type synonym 'Closure'.
292  -}
293 data GenClosure b =
294     ConsClosure {
295         info         :: StgInfoTable
296         , ptrArgs    :: [b]
297         , dataArgs   :: [Word]
298         , pkg        :: String
299         , modl       :: String
300         , name       :: String
301     } |
302     ThunkClosure {
303         info         :: StgInfoTable
304         , ptrArgs    :: [b]
305         , dataArgs   :: [Word]
306     } |
307     SelectorClosure {
308         info         :: StgInfoTable
309         , selectee   :: b
310     } |
311     IndClosure {
312         info         :: StgInfoTable
313         , indirectee   :: b
314     } |
315     BlackholeClosure {
316         info         :: StgInfoTable
317         , indirectee   :: b
318     } |
319     -- In GHCi, if Linker.h would allow a reverse lookup, we could for exported
320     -- functions fun actually find the name here.
321     -- At least the other direction works via "lookupSymbol
322     -- base_GHCziBase_zpzp_closure" and yields the same address (up to tags)
323     APClosure {
324         info         :: StgInfoTable
325         , arity      :: HalfWord
326         , n_args     :: HalfWord
327         , fun        :: b
328         , payload    :: [b]
329     } |
330     PAPClosure {
331         info         :: StgInfoTable
332         , arity      :: HalfWord
333         , n_args     :: HalfWord
334         , fun        :: b
335         , payload    :: [b]
336     } |
337     APStackClosure {
338         info         :: StgInfoTable
339         , fun        :: b
340         , payload    :: [b]
341     } |
342     BCOClosure {
343         info         :: StgInfoTable
344         , instrs     :: b
345         , literals   :: b
346         , bcoptrs    :: b
347         , arity      :: HalfWord
348         , size       :: HalfWord
349         , bitmap     :: Word
350     } |
351     ArrWordsClosure {
352         info         :: StgInfoTable
353         , bytes      :: Word
354         , arrWords   :: [Word]
355     } |
356     MutArrClosure {
357         info         :: StgInfoTable
358         , mccPtrs    :: Word
359         , mccSize    :: Word
360         , mccPayload :: [b]
361         -- Card table ignored
362     } |
363     MutVarClosure {
364         info         :: StgInfoTable
365         , var        :: b
366     } |
367     MVarClosure {
368         info         :: StgInfoTable
369         , queueHead  :: b
370         , queueTail  :: b
371         , value      :: b
372     } |
373     FunClosure {
374         info         :: StgInfoTable
375         , ptrArgs    :: [b]
376         , dataArgs   :: [Word]
377     } |
378     BlockingQueueClosure {
379         info         :: StgInfoTable
380         , link       :: b
381         , blackHole  :: b
382         , owner      :: b
383         , queue      :: b
384     } |
385     OtherClosure {
386         info         :: StgInfoTable
387         , hvalues    :: [b]
388         , rawWords   :: [Word]
389     } |
390     UnsupportedClosure {
391         info         :: StgInfoTable
392     }
393  deriving (Show, Functor, Foldable, Traversable)
394
395
396 type Closure = GenClosure Box
397
398 -- | For generic code, this function returns all referenced closures.
399 allPtrs :: GenClosure b -> [b]
400 allPtrs (ConsClosure {..}) = ptrArgs
401 allPtrs (ThunkClosure {..}) = ptrArgs
402 allPtrs (SelectorClosure {..}) = [selectee]
403 allPtrs (IndClosure {..}) = [indirectee]
404 allPtrs (BlackholeClosure {..}) = [indirectee]
405 allPtrs (APClosure {..}) = fun:payload
406 allPtrs (PAPClosure {..}) = fun:payload
407 allPtrs (APStackClosure {..}) = fun:payload
408 allPtrs (BCOClosure {..}) = [instrs,literals,bcoptrs]
409 allPtrs (ArrWordsClosure {..}) = []
410 allPtrs (MutArrClosure {..}) = mccPayload
411 allPtrs (MutVarClosure {..}) = [var]
412 allPtrs (MVarClosure {..}) = [queueHead,queueTail,value]
413 allPtrs (FunClosure {..}) = ptrArgs
414 allPtrs (BlockingQueueClosure {..}) = [link, blackHole, owner, queue]
415 allPtrs (OtherClosure {..}) = hvalues
416 allPtrs (UnsupportedClosure {..}) = []
417
418
419 #ifdef PRIM_SUPPORTS_ANY
420 foreign import prim "aToWordzh" aToWord# :: Any -> Word#
421 foreign import prim "slurpClosurezh" slurpClosure# :: Any -> (# Addr#, ByteArray#, Array# b #)
422 foreign import prim "reallyUnsafePtrEqualityUpToTag" reallyUnsafePtrEqualityUpToTag# :: Any -> Any -> Int#
423 #else
424 -- Workd-around code until http://hackage.haskell.org/trac/ghc/ticket/5931 was
425 -- accepted
426
427 -- foreign import prim "aToWordzh" aToWord'# :: Addr# -> Word#
428 foreign import prim "slurpClosurezh" slurpClosure'# :: Word#  -> (# Addr#, ByteArray#, Array# b #)
429
430 foreign import prim "reallyUnsafePtrEqualityUpToTag" reallyUnsafePtrEqualityUpToTag'# :: Word# -> Word# -> Int#
431
432 -- This is a datatype that has the same layout as Ptr, so that by
433 -- unsafeCoerce'ing, we obtain the Addr of the wrapped value
434 data Ptr' a = Ptr' a
435
436 aToWord# :: Any -> Word#
437 aToWord# a = case Ptr' a of mb@(Ptr' _) -> case unsafeCoerce# mb :: Word of W# addr -> addr
438
439 slurpClosure# :: Any -> (# Addr#, ByteArray#, Array# b #)
440 slurpClosure# a = slurpClosure'# (aToWord# a)
441
442 reallyUnsafePtrEqualityUpToTag# :: Any -> Any -> Int#
443 reallyUnsafePtrEqualityUpToTag# a b = reallyUnsafePtrEqualityUpToTag'# (aToWord# a) (aToWord# b)
444 #endif
445
446 --pClosure x = do
447 --    getClosure x >>= print
448
449 -- | This returns the raw representation of the given argument. The second
450 -- component of the triple are the words on the heap, and the third component
451 -- are those words that are actually pointers. Once back in Haskell word, the
452 -- 'Word'  may be outdated after a garbage collector run, but the corresponding
453 -- 'Box' will still point to the correct value.
454 getClosureRaw :: a -> IO (Ptr StgInfoTable, [Word], [Box])
455 getClosureRaw x =
456     case slurpClosure# (unsafeCoerce# x) of
457         (# iptr, dat, ptrs #) -> do
458             let nelems = (I# (sizeofByteArray# dat)) `div` wORD_SIZE
459                 rawWords = [W# (indexWordArray# dat i) | I# i <- [0.. fromIntegral nelems -1] ]
460                 pelems = I# (sizeofArray# ptrs)
461                 ptrList = amap' Box $ Array 0 (pelems - 1) pelems ptrs
462             -- This is just for good measure, and seems to be not important.
463             mapM_ evaluate ptrList
464             -- This seems to be required to avoid crashes as well
465             void $ evaluate nelems
466             -- The following deep evaluation is crucial to avoid crashes (but why)?
467             mapM_ evaluate rawWords
468             return (Ptr iptr, rawWords, ptrList)
469
470 -- From compiler/ghci/RtClosureInspect.hs
471 amap' :: (t -> b) -> Array Int t -> [b]
472 amap' f (Array i0 i _ arr#) = map g [0 .. i - i0]
473     where g (I# i#) = case indexArray# arr# i# of
474                           (# e #) -> f e
475
476 -- derived from vacuum-1.0.0.2/src/GHC/Vacuum/Internal.hs, which got it from
477 -- compiler/ghci/DebuggerUtils.hs
478 dataConInfoPtrToNames :: Ptr StgInfoTable -> IO (String, String, String)
479 dataConInfoPtrToNames ptr = do
480     conDescAddress <- getConDescAddress ptr
481     wl <- peekArray0 0 conDescAddress
482     let (pkg, modl, name) = parse wl
483     return (b2s pkg, b2s modl, b2s name)
484   where
485     b2s :: [Word8] -> String
486     b2s = fmap (chr . fromIntegral)
487
488     getConDescAddress :: Ptr StgInfoTable -> IO (Ptr Word8)
489     getConDescAddress ptr'
490       | True = do
491           offsetToString <- peek (ptr' `plusPtr` (negate wORD_SIZE))
492           return $ (ptr' `plusPtr` stdInfoTableSizeB)
493                     `plusPtr` (fromIntegral (offsetToString :: Word))
494     -- This is code for !ghciTablesNextToCode:
495     {-
496       | otherwise = peek . intPtrToPtr
497                       . (+ fromIntegral
498                             stdInfoTableSizeB)
499                         . ptrToIntPtr $ ptr
500     -}
501
502     -- hmmmmmm. Is there any way to tell this?
503     opt_SccProfilingOn = False
504
505     stdInfoTableSizeW :: Int
506     -- The size of a standard info table varies with profiling/ticky etc,
507     -- so we can't get it from Constants
508     -- It must vary in sync with mkStdInfoTable
509     stdInfoTableSizeW
510       = size_fixed + size_prof
511       where
512         size_fixed = 2  -- layout, type
513         size_prof | opt_SccProfilingOn = 2
514                   | otherwise    = 0
515
516     stdInfoTableSizeB :: Int
517     stdInfoTableSizeB = stdInfoTableSizeW * wORD_SIZE
518
519 -- From vacuum-1.0.0.2/src/GHC/Vacuum/Internal.hs
520 parse :: [Word8] -> ([Word8], [Word8], [Word8])
521 parse input = if not . all (>0) . fmap length $ [pkg,modl,occ]
522                 --then (error . concat)
523                 --        ["getConDescAddress:parse:"
524                 --        ,"(not . all (>0) . fmap le"
525                 --        ,"ngth $ [pkg,modl,occ]"]
526                 then ([], [], input) -- Not in the pkg.modl.occ format, for example END_TSO_QUEUE
527                 else (pkg, modl, occ)
528 --   = ASSERT (all (>0) (map length [pkg, modl, occ])) (pkg, modl, occ)   -- XXXXXXXXXXXXXXXX
529   where
530         (pkg, rest1) = break (== fromIntegral (ord ':')) input
531         (modl, occ)
532             = (concat $ intersperse [dot] $ reverse modWords, occWord)
533             where
534             (modWords, occWord) = if (length rest1 < 1) --  XXXXXXXXx YUKX
535                                     --then error "getConDescAddress:parse:length rest1 < 1"
536                                     then parseModOcc [] []
537                                     else parseModOcc [] (tail rest1)
538         -- ASSERT (length rest1 > 0) (parseModOcc [] (tail rest1))
539         dot = fromIntegral (ord '.')
540         parseModOcc :: [[Word8]] -> [Word8] -> ([[Word8]], [Word8])
541         parseModOcc acc str
542             = case break (== dot) str of
543                 (top, []) -> (acc, top)
544                 (top, _:bot) -> parseModOcc (top : acc) bot
545
546
547 -- | This function returns parsed heap representation of the argument _at this
548 -- moment_, even if it is unevaluated or an indirection or other exotic stuff.
549 -- Beware when passing something to this function, the same caveats as for
550 -- 'asBox' apply.
551 getClosureData :: a -> IO Closure
552 getClosureData x = do
553     (iptr, wds, ptrs) <- getClosureRaw x
554     itbl <- peek iptr
555     case tipe itbl of
556         t | t >= CONSTR
557 #if defined(GHC_8_0)
558           , t <= CONSTR_NOCAF_STATIC
559 #else
560           , t <= CONSTR_NOCAF
561 #endif
562           -> do
563             (pkg, modl, name) <- dataConInfoPtrToNames iptr
564             if modl == "ByteCodeInstr" && name == "BreakInfo"
565               then return $ UnsupportedClosure itbl
566               else return $ ConsClosure itbl ptrs (drop (length ptrs + 1) wds) pkg modl name
567
568         t | t >= THUNK && t <= THUNK_STATIC -> do
569             return $ ThunkClosure itbl ptrs (drop (length ptrs + 2) wds)
570
571         t | t >= FUN && t <= FUN_STATIC -> do
572             return $ FunClosure itbl ptrs (drop (length ptrs + 1) wds)
573
574         AP -> do
575             unless (length ptrs >= 1) $
576                 fail "Expected at least 1 ptr argument to AP"
577             unless (length wds >= 3) $
578                 fail "Expected at least 3 raw words to AP"
579             return $ APClosure itbl
580                 (fromIntegral $ wds !! 2)
581                 (fromIntegral $ shiftR (wds !! 2) (wORD_SIZE_IN_BITS `div` 2))
582                 (head ptrs) (tail ptrs)
583
584         PAP -> do
585             unless (length ptrs >= 1) $
586                 fail "Expected at least 1 ptr argument to PAP"
587             unless (length wds >= 3) $
588                 fail "Expected at least 3 raw words to AP"
589             return $ PAPClosure itbl
590                 (fromIntegral $ wds !! 2)
591                 (fromIntegral $ shiftR (wds !! 2) (wORD_SIZE_IN_BITS `div` 2))
592                 (head ptrs) (tail ptrs)
593
594         AP_STACK -> do
595             unless (length ptrs >= 1) $
596                 fail "Expected at least 1 ptr argument to AP_STACK"
597             return $ APStackClosure itbl (head ptrs) (tail ptrs)
598
599         THUNK_SELECTOR -> do
600             unless (length ptrs >= 1) $
601                 fail "Expected at least 1 ptr argument to THUNK_SELECTOR"
602             return $ SelectorClosure itbl (head ptrs)
603
604         IND -> do
605             unless (length ptrs >= 1) $
606                 fail "Expected at least 1 ptr argument to IND"
607             return $ IndClosure itbl (head ptrs)
608         IND_STATIC -> do
609             unless (length ptrs >= 1) $
610                 fail "Expected at least 1 ptr argument to IND_STATIC"
611             return $ IndClosure itbl (head ptrs)
612         BLACKHOLE -> do
613             unless (length ptrs >= 1) $
614                 fail "Expected at least 1 ptr argument to BLACKHOLE"
615             return $ BlackholeClosure itbl (head ptrs)
616
617         BCO -> do
618             unless (length ptrs >= 3) $
619                 fail $ "Expected at least 3 ptr argument to BCO, found " ++ show (length ptrs)
620             unless (length wds >= 6) $
621                 fail $ "Expected at least 6 words to BCO, found " ++ show (length wds)
622             return $ BCOClosure itbl (ptrs !! 0) (ptrs !! 1) (ptrs !! 2)
623                 (fromIntegral $ wds !! 4)
624                 (fromIntegral $ shiftR (wds !! 4) (wORD_SIZE_IN_BITS `div` 2))
625                 (wds !! 5)
626
627         ARR_WORDS -> do
628             unless (length wds >= 2) $
629                 fail $ "Expected at least 2 words to ARR_WORDS, found " ++ show (length wds)
630             return $ ArrWordsClosure itbl (wds !! 1) (drop 2 wds)
631
632         t | t == MUT_ARR_PTRS_FROZEN || t == MUT_ARR_PTRS_FROZEN0 -> do
633             unless (length wds >= 3) $
634                 fail $ "Expected at least 3 words to MUT_ARR_PTRS_FROZEN0 found " ++ show (length wds)
635             return $ MutArrClosure itbl (wds !! 1) (wds !! 2) ptrs
636
637         t | t == MUT_VAR_CLEAN || t == MUT_VAR_DIRTY ->
638             return $ MutVarClosure itbl (head ptrs)
639
640         t | t == MVAR_CLEAN || t == MVAR_DIRTY -> do
641             unless (length ptrs >= 3) $
642                 fail $ "Expected at least 3 ptrs to MVAR, found " ++ show (length ptrs)
643             return $ MVarClosure itbl (ptrs !! 0) (ptrs !! 1) (ptrs !! 2)
644
645         BLOCKING_QUEUE ->
646             return $ OtherClosure itbl ptrs wds
647         --    return $ BlockingQueueClosure itbl
648         --        (ptrs !! 0) (ptrs !! 1) (ptrs !! 2) (ptrs !! 3)
649
650         --  return $ OtherClosure itbl ptrs wds
651         --
652         _ ->
653             return $ UnsupportedClosure itbl
654
655 -- | Like 'getClosureData', but taking a 'Box', so it is easier to work with.
656 getBoxedClosureData :: Box -> IO Closure
657 getBoxedClosureData (Box a) = getClosureData a
658
659
660 isChar :: GenClosure b -> Maybe Char
661 isChar (ConsClosure { name = "C#", dataArgs = [ch], ptrArgs = []}) = Just (chr (fromIntegral ch))
662 isChar _ = Nothing
663
664 isCons :: GenClosure b -> Maybe (b, b)
665 isCons (ConsClosure { name = ":", dataArgs = [], ptrArgs = [h,t]}) = Just (h,t)
666 isCons _ = Nothing
667
668 isTup :: GenClosure b -> Maybe [b]
669 isTup (ConsClosure { dataArgs = [], ..}) =
670     if length name >= 3 &&
671        head name == '(' && last name == ')' &&
672        all (==',') (tail (init name))
673     then Just ptrArgs else Nothing
674 isTup _ = Nothing
675
676
677 isNil :: GenClosure b -> Bool
678 isNil (ConsClosure { name = "[]", dataArgs = [], ptrArgs = []}) = True
679 isNil _ = False
680
681 -- | A pretty-printer that tries to generate valid Haskell for evalutated data.
682 -- It assumes that for the included boxes, you already replaced them by Strings
683 -- using 'Data.Foldable.map' or, if you need to do IO, 'Data.Foldable.mapM'.
684 --
685 -- The parameter gives the precedendence, to avoid avoidable parenthesises.
686 ppClosure :: (Int -> b -> String) -> Int -> GenClosure b -> String
687 ppClosure showBox prec c = case c of
688     _ | Just ch <- isChar c -> app $
689         ["C#", show ch]
690     _ | Just (h,t) <- isCons c -> addBraces (5 <= prec) $
691         showBox 5 h ++ " : " ++ showBox 4 t
692     _ | Just vs <- isTup c ->
693         "(" ++ intercalate "," (map (showBox 0) vs) ++ ")"
694     ConsClosure {..} -> app $
695         name : map (showBox 10) ptrArgs ++ map show dataArgs
696     ThunkClosure {..} -> app $
697         "_thunk" : map (showBox 10) ptrArgs ++ map show dataArgs
698     SelectorClosure {..} -> app
699         ["_sel", showBox 10 selectee]
700     IndClosure {..} -> app
701         ["_ind", showBox 10 indirectee]
702     BlackholeClosure {..} -> app
703         ["_bh",  showBox 10 indirectee]
704     APClosure {..} -> app $ map (showBox 10) $
705         fun : payload
706     PAPClosure {..} -> app $ map (showBox 10) $
707         fun : payload
708     APStackClosure {..} -> app $ map (showBox 10) $
709         fun : payload
710     BCOClosure {..} -> app
711         ["_bco"]
712     ArrWordsClosure {..} -> app
713         ["toArray", "("++show (length arrWords) ++ " words)", intercalate "," (shorten (map show arrWords)) ]
714     MutArrClosure {..} -> app
715         ["toMutArray", "("++show (length mccPayload) ++ " ptrs)",  intercalate "," (shorten (map (showBox 10) mccPayload))]
716     MutVarClosure {..} -> app $
717         ["_mutVar", (showBox 10) var]
718     MVarClosure {..} -> app $
719         ["MVar", (showBox 10) value]
720     FunClosure {..} ->
721         "_fun" ++ braceize (map (showBox 0) ptrArgs ++ map show dataArgs)
722     BlockingQueueClosure {..} ->
723         "_blockingQueue"
724     OtherClosure {..} ->
725         "_other"
726     UnsupportedClosure {..} ->
727         "_unsupported"
728   where
729     app [a] = a  ++ "()"
730     app xs = addBraces (10 <= prec) (intercalate " " xs)
731
732     shorten xs = if length xs > 20 then take 20 xs ++ ["(and more)"] else xs
733
734 {- $heapmap
735
736    For more global views of the heap, you can use heap maps. These come in
737    variations, either a trees or as graphs, depending on
738    whether you want to detect cycles and sharing or not.
739
740    The entries of a 'HeapGraph' can be annotated with arbitrary values. Most
741    operations expect this to be in the 'Monoid' class: They use 'mempty' to
742    annotate closures added because the passed values reference them, and they
743    use 'mappend' to combine the annotations when two values conincide, e.g.
744    during 'updateHeapGraph'.
745 -}
746
747 -- | Heap maps as tree, i.e. no sharing, no cycles.
748 data HeapTree = HeapTree Box (GenClosure HeapTree) | EndOfHeapTree
749
750 heapTreeClosure :: HeapTree -> Maybe (GenClosure HeapTree)
751 heapTreeClosure (HeapTree _ c) = Just c
752 heapTreeClosure EndOfHeapTree = Nothing
753
754 -- | Constructing an 'HeapTree' from a boxed value. It takes a depth parameter
755 -- that prevents it from running ad infinitum for cyclic or infinite
756 -- structures.
757 buildHeapTree :: Int -> Box -> IO HeapTree
758 buildHeapTree 0 _ = do
759     return $ EndOfHeapTree
760 buildHeapTree n b = do
761     c <- getBoxedClosureData b
762     c' <- T.mapM (buildHeapTree (n-1)) c
763     return $ HeapTree b c'
764
765 -- | Pretty-Printing a heap Tree
766 --
767 -- Example output for @[Just 4, Nothing, *something*]@, where *something* is an
768 -- unevaluated expression depending on the command line argument.
769 --
770 -- >[Just (I# 4),Nothing,Just (_thunk ["arg1","arg2"])]
771 ppHeapTree :: HeapTree -> String
772 ppHeapTree = go 0
773   where
774     go _ EndOfHeapTree = "..."
775     go prec t@(HeapTree _ c')
776         | Just s <- isHeapTreeString t = show s
777         | Just l <- isHeapTreeList t   = "[" ++ intercalate "," (map ppHeapTree l) ++ "]"
778         | Just bc <- disassembleBCO heapTreeClosure c'
779                                        = app ("_bco" : map (go 10) (concatMap F.toList bc))
780         | otherwise                    = ppClosure go prec c'
781       where
782         app [a] = a ++ "()"
783         app xs = addBraces (10 <= prec) (intercalate " " xs)
784
785 isHeapTreeList :: HeapTree -> Maybe ([HeapTree])
786 isHeapTreeList tree = do
787     c <- heapTreeClosure tree
788     if isNil c
789       then return []
790       else do
791         (h,t) <- isCons c
792         t' <- isHeapTreeList t
793         return $ (:) h t'
794
795 isHeapTreeString :: HeapTree -> Maybe String
796 isHeapTreeString t = do
797     list <- isHeapTreeList t
798     -- We do not want to print empty lists as "" as we do not know that they
799     -- are really strings.
800     if (null list)
801         then Nothing
802         else mapM (isChar <=< heapTreeClosure) list
803
804 -- | For heap graphs, i.e. data structures that also represent sharing and
805 -- cyclic structures, these are the entries. If the referenced value is
806 -- @Nothing@, then we do not have that value in the map, most likely due to
807 -- exceeding the recursion bound passed to 'buildHeapGraph'.
808 --
809 -- Besides a pointer to the stored value and the closure representation we
810 -- also keep track of whether the value was still alive at the last update of the
811 -- heap graph. In addition we have a slot for arbitrary data, for the user's convenience.
812 data HeapGraphEntry a = HeapGraphEntry {
813         hgeBox :: Box,
814         hgeClosure :: GenClosure (Maybe HeapGraphIndex),
815         hgeLive :: Bool,
816         hgeData :: a}
817     deriving (Show, Functor)
818 type HeapGraphIndex = Int
819
820 -- | The whole graph. The suggested interface is to only use 'lookupHeapGraph',
821 -- as the internal representation may change. Nevertheless, we export it here:
822 -- Sometimes the user knows better what he needs than we do.
823 newtype HeapGraph a = HeapGraph (M.IntMap (HeapGraphEntry a))
824     deriving (Show)
825
826 lookupHeapGraph :: HeapGraphIndex -> (HeapGraph a) -> Maybe (HeapGraphEntry a)
827 lookupHeapGraph i (HeapGraph m) = M.lookup i m
828
829 heapGraphRoot :: HeapGraphIndex
830 heapGraphRoot = 0
831
832 -- | Creates a 'HeapGraph' for the value in the box, but not recursing further
833 -- than the given limit. The initial value has index 'heapGraphRoot'.
834 buildHeapGraph
835    :: Monoid a
836    => Int -- ^ Search limit
837    -> a -- ^ Data value for the root
838    -> Box -- ^ The value to start with
839    -> IO (HeapGraph a)
840 buildHeapGraph limit rootD initialBox =
841     fst <$> multiBuildHeapGraph limit [(rootD, initialBox)]
842
843 -- | Creates a 'HeapGraph' for the values in multiple boxes, but not recursing
844 --   further than the given limit.
845 --
846 --   Returns the 'HeapGraph' and the indices of initial values. The arbitrary
847 --   type @a@ can be used to make the connection between the input and the
848 --   resulting list of indices, and to store additional data.
849 multiBuildHeapGraph
850     :: Monoid a
851     => Int -- ^ Search limit
852     -> [(a, Box)] -- ^ Starting values with associated data entry
853     -> IO (HeapGraph a, [(a, HeapGraphIndex)])
854 multiBuildHeapGraph limit = generalBuildHeapGraph limit (HeapGraph M.empty)
855
856 -- | Adds an entry to an existing 'HeapGraph'.
857 --
858 --   Returns the updated 'HeapGraph' and the index of the added value.
859 addHeapGraph
860     :: Monoid a
861     => Int -- ^ Search limit
862     -> a -- ^ Data to be stored with the added value
863     -> Box -- ^ Value to add to the graph
864     -> HeapGraph a -- ^ Graph to extend
865     -> IO (HeapGraphIndex, HeapGraph a)
866 addHeapGraph limit d box hg = do
867     (hg', [(_,i)]) <- generalBuildHeapGraph limit hg [(d,box)]
868     return (i, hg')
869
870 -- | Adds the given annotation to the entry at the given index, using the
871 -- 'mappend' operation of its 'Monoid' instance.
872 annotateHeapGraph :: Monoid a => a -> HeapGraphIndex -> HeapGraph a -> HeapGraph a
873 annotateHeapGraph d i (HeapGraph hg) = HeapGraph $ M.update go i hg
874   where
875     go hge = Just $ hge { hgeData = hgeData hge <> d }
876
877 generalBuildHeapGraph
878     :: Monoid a
879     => Int
880     -> HeapGraph a
881     -> [(a,Box)]
882     -> IO (HeapGraph a, [(a, HeapGraphIndex)])
883 generalBuildHeapGraph limit _ _ | limit <= 0 = error "buildHeapGraph: limit has to be positive"
884 generalBuildHeapGraph limit (HeapGraph hg) addBoxes = do
885     -- First collect all boxes from the existing heap graph
886     let boxList = [ (hgeBox hge, i) | (i, hge) <- M.toList hg ]
887         indices | M.null hg = [0..]
888                 | otherwise = [1 + fst (M.findMax hg)..]
889
890         initialState = (boxList, indices, [])
891     -- It is ok to use the Monoid (IntMap a) instance here, because
892     -- we will, besides the first time, use 'tell' only to add singletons not
893     -- already there
894     (is, hg') <- runWriterT (evalStateT run initialState)
895     -- Now add the annotations of the root values
896     let hg'' = foldl' (flip (uncurry annotateHeapGraph)) (HeapGraph hg') is
897     return (hg'', is)
898   where
899     run = do
900         lift $ tell hg -- Start with the initial map
901         forM addBoxes $ \(d, b) -> do
902             -- Cannot fail, as limit is not zero here
903             Just i <- add limit b
904             return (d, i)
905
906     add 0  _ = return Nothing
907     add n b = do
908         -- If the box is in the map, return the index
909         (existing,_,_) <- get
910         mbI <- liftIO $ findM (areBoxesEqual b . fst) existing
911         case mbI of
912             Just (_,i) -> return $ Just i
913             Nothing -> do
914                 -- Otherwise, allocate a new index
915                 i <- nextI
916                 -- And register it
917                 modify (\(x,y,z) -> ((b,i):x, y, z))
918                 -- Look up the closure
919                 c <- liftIO $ getBoxedClosureData b
920                 -- Find indicies for all boxes contained in the map
921                 c' <- T.mapM (add (n-1)) c
922                 -- Add add the resulting closure to the map
923                 lift $ tell (M.singleton i (HeapGraphEntry b c' True mempty))
924                 return $ Just i
925     nextI = do
926         i <- gets (head . (\(_,b,_) -> b))
927         modify (\(a,b,c) -> (a, tail b, c))
928         return i
929
930 -- | This function updates a heap graph to reflect the current state of
931 -- closures on the heap, conforming to the following specification.
932 --
933 --  * Every entry whose value has been garbage collected by now is marked as
934 --    dead by setting 'hgeLive' to @False@
935 --  * Every entry whose value is still live gets the 'hgeClosure' field updated
936 --    and newly referenced closures are, up to the given depth, added to the graph.
937 --  * A map mapping previous indicies to the corresponding new indicies is returned as well.
938 --  * The closure at 'heapGraphRoot' stays at 'heapGraphRoot'
939 updateHeapGraph :: Monoid a => Int -> HeapGraph a -> IO (HeapGraph a, HeapGraphIndex -> HeapGraphIndex)
940 updateHeapGraph limit (HeapGraph startHG) = do
941     (hg', indexMap) <- runWriterT $ foldM go (HeapGraph M.empty) (M.toList startHG)
942     return (hg', (M.!) indexMap)
943   where
944     go hg (i, hge) = do
945         (j, hg') <- liftIO $ addHeapGraph limit (hgeData hge) (hgeBox hge) hg
946         tell (M.singleton i j)
947         return hg'
948
949 -- | Pretty-prints a HeapGraph. The resulting string contains newlines. Example
950 -- for @let s = \"Ki\" in (s, s, cycle \"Ho\")@:
951 --
952 -- >let x1 = "Ki"
953 -- >    x6 = C# 'H' : C# 'o' : x6
954 -- >in (x1,x1,x6)
955 ppHeapGraph :: HeapGraph a -> String
956 ppHeapGraph (HeapGraph m) = letWrapper ++ ppRef 0 (Just heapGraphRoot)
957   where
958     -- All variables occuring more than once
959     bindings = boundMultipleTimes (HeapGraph m) [heapGraphRoot]
960
961     letWrapper =
962         if null bindings
963         then ""
964         else "let " ++ intercalate "\n    " (map ppBinding bindings) ++ "\nin "
965
966     bindingLetter i = case hgeClosure (iToE i) of
967         ThunkClosure {..} -> 't'
968         SelectorClosure {..} -> 't'
969         APClosure {..} -> 't'
970         PAPClosure {..} -> 'f'
971         BCOClosure {..} -> 't'
972         FunClosure {..} -> 'f'
973         _ -> 'x'
974
975     ppBindingMap = M.fromList $
976         concat $
977         map (zipWith (\j (i,c) -> (i, [c] ++ show j)) [(1::Int)..]) $
978         groupBy ((==) `on` snd) $
979         sortBy (compare `on` snd)
980         [ (i, bindingLetter i) | i <- bindings ]
981
982     ppVar i = ppBindingMap M.! i
983     ppBinding i = ppVar i ++ " = " ++ ppEntry 0 (iToE i)
984
985     ppEntry prec hge
986         | Just s <- isString hge = show s
987         | Just l <- isList hge   = "[" ++ intercalate "," (map (ppRef 0) l) ++ "]"
988         | Just bc <- disassembleBCO (fmap (hgeClosure . iToE)) (hgeClosure hge)
989                                        = app ("_bco" : map (ppRef 10) (concatMap F.toList bc))
990         | otherwise = ppClosure ppRef prec (hgeClosure hge)
991       where
992         app [a] = a  ++ "()"
993         app xs = addBraces (10 <= prec) (intercalate " " xs)
994
995     ppRef _ Nothing = "..."
996     ppRef prec (Just i) | i `elem` bindings = ppVar i
997                         | otherwise = ppEntry prec (iToE i)
998     iToE i = m M.! i
999
1000     iToUnboundE i = if i `elem` bindings then Nothing else M.lookup i m
1001
1002     isList :: HeapGraphEntry a -> Maybe ([Maybe HeapGraphIndex])
1003     isList hge =
1004         if isNil (hgeClosure hge)
1005           then return []
1006           else do
1007             (h,t) <- isCons (hgeClosure hge)
1008             ti <- t
1009             e <- iToUnboundE ti
1010             t' <- isList e
1011             return $ (:) h t'
1012
1013     isString :: HeapGraphEntry a -> Maybe String
1014     isString e = do
1015         list <- isList e
1016         -- We do not want to print empty lists as "" as we do not know that they
1017         -- are really strings.
1018         if (null list)
1019             then Nothing
1020             else mapM (isChar . hgeClosure <=< iToUnboundE <=< id) list
1021
1022
1023 -- | In the given HeapMap, list all indices that are used more than once. The
1024 -- second parameter adds external references, commonly @[heapGraphRoot]@.
1025 boundMultipleTimes :: HeapGraph a -> [HeapGraphIndex] -> [HeapGraphIndex]
1026 boundMultipleTimes (HeapGraph m) roots = map head $ filter (not.null) $ map tail $ group $ sort $
1027      roots ++ concatMap (catMaybes . allPtrs . hgeClosure) (M.elems m)
1028
1029 -- | This function integrates the disassembler in "GHC.Disassembler". The first
1030 -- argument should a function that dereferences the pointer in the closure to a
1031 -- closure.
1032 --
1033 -- If any of these return 'Nothing', then 'disassembleBCO' returns Nothing
1034 disassembleBCO :: (a -> Maybe (GenClosure b)) -> GenClosure a -> Maybe [BCI b]
1035 disassembleBCO deref (BCOClosure {..}) = do
1036     opsC <- deref instrs
1037     litsC <- deref literals
1038     ptrsC  <- deref bcoptrs
1039     return $ disassemble (mccPayload ptrsC) (arrWords litsC) (toBytes (bytes opsC) (arrWords opsC))
1040 disassembleBCO _ _ = Nothing
1041
1042 -- Utilities
1043
1044 findM :: (a -> IO Bool) -> [a] -> IO (Maybe a)
1045 findM _p [] = return Nothing
1046 findM p (x:xs) = do
1047     b <- p x
1048     if b then return (Just x) else findM p xs
1049
1050 addBraces :: Bool -> String -> String
1051 addBraces True t = "(" ++ t ++ ")"
1052 addBraces False t = t
1053
1054 braceize :: [String] -> String
1055 braceize [] = ""
1056 braceize xs = "{" ++ intercalate "," xs ++ "}"
1057
1058 -- This used to be available via GHC.Constants
1059 #include "MachDeps.h"
1060 wORD_SIZE, tAG_MASK, wORD_SIZE_IN_BITS :: Int
1061 wORD_SIZE = SIZEOF_HSWORD
1062 tAG_MASK = (1 `shift` TAG_BITS) - 1
1063 wORD_SIZE_IN_BITS = WORD_SIZE_IN_BITS
1064